double-arch tunnel fini.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!公路双连拱隧道开挖有限元模拟
FINI
/CLE

/FILNAME,EX5-5
/TITLE,THE ANALYSIS OF THE DOUBLE-ARCH TUNNEL

!几何参数设定，单位M
W=50		!模型右边界X坐标
L1=23.11	!开挖宽度
L2=3.5		!锚杆长
D1=5.78		!隧道轴线X坐标
D2=1		!中墙底部X坐标

H1=2.9241	!中墙顶部Y坐标
H2=3.06		!中墙底部Y坐标
H3=2.06		!中墙底部Y坐标2
H4=40		!模型下边界Y坐标
H5=26		!模型上边界Y坐标

T1=1.6		!中墙厚
T2=0.25		!初衬厚
T3=0.55		!仰拱厚
T4=0.25		!初期支护厚

R1=5.775	!衬砌半径
R2=10.34	!仰拱半径
R3=4		!中导洞支护半径
R4=25E-3	!锚杆直径
NUM=20		!每边锚杆数
!材料参数设定
!围岩
E_R=1.4E9	!弹性模量，PA
U_R=0.4		!泊松比
DENS_R=1826.5	!密度，KG/M^-3
C_R=0.16E6	!凝聚力，PA
FI_R=28		!内摩擦角

!C25混凝土
E_C=28.5E9	!弹性模量，PA
U_C=0.2		!泊松比
DENS_C=2449	!密度，KG/M^-3

!C20混凝土
E_C20=26E9	!弹性模量，PA
U_C20=0.2	!泊松比
DENS_C20=2349	!密度，KG/M^-3

!Φ25锚杆，ANCHOR ROD
E_A=170E9	!弹性模量，PA
U_A=0.3		!泊松比
DENS_A=7959	!密度，KG/M^-3

!======================
!========前处理========
!======================
/PREP7
!=====定义单元类型=====
ET,1,42			!定义PLANE42单元
KEYOPT,1,3,2		!定义为平面应变问题

ET,2,3			!定义BEAM3单元
KEYOPT,2,6,1		!打开输出内力选项

ET,3,1			!定义LINK1单元

!=====定义材料属性=====
!围岩1~7号
*DO,I,1,7,1
  MP,EX,I,E_R        	!围岩弹性模量
  MP,PRXY,I,U_R      	!围岩泊松比
  MP,DENS,I,DENS_R   	!围岩密度
  TB,DP,I
  TBDATA,1,C_R,FI_R
*ENDDO

!衬砌8~11号
*DO,I,8,11,1
  MP,EX,I,E_C        	!混凝土弹性模量
  MP,PRXY,I,U_C      	!混凝土泊松比
  MP,DENS,I,DENS_C   	!混凝土密度
*ENDDO

!锚杆12~13号
*DO,I,12,13,1
  MP,EX,I,E_A        	!锚杆弹性模量
  MP,PRXY,I,U_A      	!锚杆泊松比
  MP,DENS,I,DENS_A   	!锚杆密度
*ENDDO

!中隔墙14号
MP,EX,14,E_C20        	!混凝土弹性模量
MP,PRXY,14,U_C20      	!混凝土泊松比
MP,DENS,14,DENS_C20   	!混凝土密度

!=====定义实常数=====
R,1,T2,T2/12,T2		!衬砌
R,2,T3,T3/12,T3		!仰拱
R,3,T4,T4/12,T4		!初期支护
R,4,3.14*(R4/2)**2	!锚杆

!=====实体建模=====
!中墙、中导洞
RECTNG,-T1/2,T1/2,-H2,H1	!建立中墙矩形面
WPOFFS,,-H3			!工作平面Y向偏移-H3距离
WPROTA,,90			!工作平面绕X轴旋转90度
LSBW,ALL			!用工作平面切割选择集中所有线

K,7,T1/2+D2,-H2			!建立7号关键点
K,8,-T1/2-D2,-H2		!建立8号关键点
L,1,8				!连接1、8号关键点生成线
L,2,7				!连接2、7号关键点生成线

LARC,7,3,6,R3			!生成圆弧线
LARC,4,8,5,R3			!生成圆弧线

WPCSYS				!工作平面与当前坐标系重合
WPROTA,,90			!工作平面绕X轴旋转90度
LSBW,ALL			!用工作平面切割选择集中所有线
L,11,12				!连接11、12号关键点生成线

!初衬
WPCSYS				!工作平面与当前坐标系重合
WPOFFS,D1			!工作平面X向偏移D1距离
CSWPLA,11,1			!在工作平面处建立11号局部柱坐标系
K,13,R1				!建立关键点
L,13,3				!生成线
K,100,R1+L2			!建立关键点
K,101,R1+L2,160			!建立关键点
L,100,101			!生成线

CSYS				!激活总体笛卡尔坐标系
WPCSYS				!工作平面与当前坐标系重合
WPOFFS,-D1			!工作平面X向偏移-D1距离
CSWPLA,12,1			!在工作平面处建立12号局部柱坐标系
K,16,R1,180			!建立关键点
L,4,16				!生成线
K,200,R1+L2,180			!建立关键点
K,201,R1+L2,20			!建立关键点
L,200,201			!生成线

LSEL,S,LINE,,8,10,1		!选择线8、9、10及19号线
LSEL,A,LINE,,19
LCSL,ALL			!交线在交点处打断
LDEL,25,27,2,1			!删除线

L,13,100			!生成线
L,16,200			!生成线

!仰拱
CSYS				!激活总体笛卡尔坐标系
WPCSYS				!工作平面与当前坐标系重合
K,,L1/2,-H3			!建立关键点
K,,-L1/2,-H3			!建立关键点
L,18,13				!生成线
L,19,16				!生成线
LARC,6,18,10,R2			!生成圆弧线
LARC,19,5,11,R2			!生成圆弧线

ALLS				!选择所有元素
LCSL,18,27			!交线在交点处打断
LCSL,17,25			!交线在交点处打断

ALLS				!选择所有元素
NUMCMP,ALL			!压缩所有元素编号

!模型边界
RECTNG,-W,W,-H4,H5		!建立模型矩形面
LSEL,U,LINE,,34,37,1		!从当前线选择集中排除四条边界线
ASBL,2,ALL			!用当前选择集中所有线分割2号面

!锚杆
CSYS,11				!激活11号局部坐标系				
WPCSYS				!工作平面与当前坐标系重合
WPROTA,,-90			!工作平面绕X轴旋转-90度
ASEL,S,AREA,,7,9,2		!选择7、9号面
*DO,I,1,NUM-1,1			!循环控制
  WPROTA,,,-7.3			!工作平面绕Y轴旋转-7.3度
  ASBW,ALL			!用工作平面切割选择集中所有面
*ENDDO				!循环结束

CSYS,12				!激活11号局部坐标系
WPCSYS				!工作平面与当前坐标系重合
WPROTA,,-90			!工作平面绕X轴旋转-90度
ASEL,S,AREA,,7,9,1		!选择7、8、9、32号面
ASEL,A,AREA,,32
*DO,I,1,NUM-1,1			!循环控制
  WPROTA,,,7.3			!工作平面绕Y轴旋转7.3度
  ASBW,ALL			!用工作平面切割选择集中所有面
*ENDDO				!循环结束

ALLS				!选择所有元素
NUMCMP,ALL			!压缩所有元素编号
!=====划分单元=====
!切割开挖边界用于划分网格
CSYS				!激活总体笛卡尔坐标系
WPCSYS				!工作平面与当前坐标系重合
WPROTA,,-90			!工作平面绕X轴旋转-90度

WPROTA,,,90			!工作平面绕Y轴旋转90度
WPOFFS,,,4*L1/5			!工作平面Z向偏移4*L1/5距离
ASBW,ALL			!用工作平面切割选择集中所有面
WPOFFS,,,-8*L1/5		!工作平面Z向偏移-8*L1/5距离
ASBW,ALL			!用工作平面切割选择集中所有面

WPROTA,,,90			!工作平面绕Y轴旋转90度
WPOFFS,,,-H5/2			!工作平面Z向偏移-H5/2距离
ASBW,ALL			!用工作平面切割选择集中所有面
WPOFFS,,,H5/2+2.5*H2		!工作平面Z向偏移H5/2+2.5*H2距离
ASBW,ALL			!用工作平面切割选择集中所有面

!===梁单元划分===!M2
TYPE,2				!指定2号单元
!中导洞初期支护
REAL,3				!指定3号实常数
MAT,8				!指定8号材料号
LSEL,S,LINE,,12,32,20		!选择12、32号线
LESIZE,ALL,,,6			!指定划分数
LMESH,ALL			!划分当前选择集中所有线

MAT,9				!指定9号材料号
LSEL,S,LINE,,13,30,17		!选择13、30号线
LESIZE,ALL,,,6			!指定划分数
LMESH,ALL			!划分当前选择集中所有线

!右隧道支护
MAT,10				!指定10号材料号
!衬砌
REAL,1				!指定1号实常数
ASEL,S,AREA,,11			!选择11号面
LSLA,S				!选择包含于当前选择集中所有面的线
LSEL,U,LINE,,32,33,1		!排除32、33号线
LSEL,U,LINE,,12			!排除12号线
LMESH,ALL			!划分当前选择集中所有线
!仰拱
REAL,2				!指定2号实常数
LSEL,S,LINE,,33			!选择33号线
LMESH,ALL			!划分当前选择集中所有线

!左隧道支护
MAT,11				!指定11号材料号
!衬砌
REAL,1				!指定1号实常数
ASEL,S,AREA,,12			!选择12号面
LSLA,S				!选择包含于当前选择集中所有面的线
LSEL,U,LINE,,30,31,1		!排除30、31号线
LSEL,U,LINE,,13			!排除13号线
LMESH,ALL			!划分当前选择集中所有线
!仰拱
REAL,2				!指定2号实常数
LSEL,S,LINE,,31			!选择31号线
LMESH,ALL			!划分当前选择集中所有线

!===杆单元划分===
TYPE,3				!指定3号单元
REAL,4				!指定4号实常数
!右隧道锚杆
MAT,12				!指定12号材料号
CSYS,11				!激活11号局部柱坐标系
LSEL,S,LOC,Y,0			!选择柱坐标系下角度为0所有线
*DO,I,1,NUM-1,1			!循环控制
  LSEL,A,LOC,Y,I*7.3		!选择线
*ENDDO				!循环结束
LSEL,U,LINE,,167		!排除167号线
LMESH,ALL			!划分当前选择集中所有线
!左隧道锚杆
MAT,13				!指定13号材料号
CSYS,12				!激活12号局部柱坐标系
LSEL,S,LOC,Y,180		!选择柱坐标系下角度为180所有线
*DO,I,1,NUM-1,1			!循环控制
  LSEL,A,LOC,Y,180-I*7.3	!选择线
*ENDDO				!循环结束
LSEL,U,LINE,,167		!排除167号线
LMESH,ALL			!划分当前选择集中所有线

!===围岩单元划分===
TYPE,1				!指定1号单元
!中墙
MAT,1				!指定1号材料号
ASEL,S,AREA,,4,5,1		!选择4、5、1号面
ASEL,A,AREA,,1			
LSEL,S,LINE,,14,16,1		!选择14、15、16、11号线
LSEL,A,LINE,,11
LESIZE,ALL,,,6			!指定划分数
LSEL,S,LINE,,1,3,2		!选择1、3号线
LESIZE,ALL,,,4			!指定划分数
AMESH,ALL			!划分当前选择集中所有面
ALLS				!选择所有元素
!中导洞
MAT,2				!指定2号材料号
MSHKEY,1			!指定为映射网格划分