📄 csp-2d-定.txt
字号:
FINI
/CLE
/UNITS,SI !国际单位制
/FILNAME,CSP !制定文件名为CSP
/TITLE,2D THERMAL SIMULATION OF CSP !制定标题
!定义结构参数
!定义塑封体的尺寸
*SET,MC_HEIGHT,1.5E-3 !塑封体高度
*SET,MC_SLENGTH,16E-3 !塑封体上端长度
*SET,MC_XLENGTH,18E-3 !塑封体下端长度
!定义芯片尺寸(硅)
*SET,CHIP_LENGTH,14E-3 !芯片长度
*SET,CHIP_HEIGHT,0.4E-3 !芯片宽度
!定义粘结剂尺寸
*SET,DA_HEIGHT,0.15E-3 !粘结剂高度
!定义铜印制线尺寸
*SET,CP_HEIGHT,0.05E-3 !铜印制线高度
*SET,CP_LENGTH,1E-3 !铜印制线长度
!定义基板的尺寸
*SET,PS_LENGTH,20E-3 !基板长度
*SET,PS_HEIGHT,0.15E-3 !基板高度
!定义基板下焊料球的尺寸和数量
*SET,SB_RADIUS,0.5E-3 !焊球半径
*SET,SB_DIST,2.2E-3 !焊球间距
*SET,SB_NB,8 !单排焊球数量
*SET,SB_HEIGHT,0.8E-3 !焊球高度
*SET,SB_JL,2*SQRT(SB_RADIUS**2-SB_HEIGHT**2/4)
!定义PCB的尺寸
*SET,PCB_LENGTH,30E-3 !PCB长度
*SET,PCB_HEIGHT,1.5E-3 !PCB高度
/PREP7 !进入前处理
!定义单元类型
ET,1,PLANE82 !定义单元类型1为平面单元82
KEYOPT,1,3,2 !设定为平面应变问题
ET,2,VISCO108 !定义单元类型2为平面单元108
!定义材料特性
!定义PCB的材料属性
MP,EX,1,22E9 !PCB的弹性模量
MP,PRXY,1,0.28 !PCB的泊松比
MP,ALPX,1,18E-6 !PCB的热膨胀系数
!焊点材料特性
MP,ALPX,2,21E-6
MPTEMP,1,-55,-35,-15,5,20,50 !焊点材料的弹性模量、泊松比
MPTEMP,7,75,100,125
MPDATA,EX,2,1,47.97E9,46.89E9,45.79E9,44.38E9,43.25E9,41.33E9
MPDATA,EX,2,7,39.45E9,36.85E9,34.59E9
MPDATA,PRXY,2,1,0.352,0.354,0.357,0.36,0.363,0.365
MPDATA,PRXY,2,7,0.37,0.377,0.38
TB,ANAN,2,,,0 !焊点ANAND模型材料参数
TBDATA,1,56.33E6,10830,1.49E7,11,0.303,2640E6
TBDATA,7,80.415E6,0.0231,1.34
!定义基板材料属性
MP,EX,3,22E9 !基板的弹性模量
MP,PRXY,3,0.28 !基板的泊松比
MP,ALPX,3,18E-6 !基板的热膨胀系数
!定义铜印制线材料属性
MP,EX,4,120.658E9 !铜的弹性模量
MP,PRXY,4,0.345 !铜的泊松比
MP,ALPX,4,17E-6 !铜的热膨胀系数
!定义粘结剂材料属性
MP,EX,5,5.2E9 !粘结剂的弹性模量
MP,PRXY,5,0.3 !粘结剂的泊松比
MP,ALPX,5,40E-6 !粘结剂的热膨胀系数
!定义芯片材料属性
MP,EX,6,131E9 !芯片材料的弹性模量
MP,PRXY,6,0.3 !芯片材料的泊松比
MP,ALPX,6,2.8E-6 !芯片材料的热膨胀系数
!定义塑封体材料属性
MP,EX,7,26E9 !塑封体的弹性模量
MP,PRXY,7,0.3 !塑封体的泊松比
MP,ALPX,7,7E-6 !塑封体的热膨胀系数
!建模
!建塑封体结构
K,1,0,0 !建关键点1
K,2,0,MC_HEIGHT !建关键点2
K,3,MC_SLENGTH/2,MC_HEIGHT !建关键点3
K,4,MC_XLENGTH/2,0 !建关键点4
A,1,2,3,4 !通过关键点建面
!建立粘结剂模型
RECTNG,0,CHIP_LENGTH/2,0,DA_HEIGHT
!建立芯片模型
RECTNG,0,CHIP_LENGTH/2,DA_HEIGHT,DA_HEIGHT+CHIP_HEIGHT
!建基板
RECTNG,0,PS_LENGTH/2,0,-PS_HEIGHT
!建立焊球
WPOFF,SB_DIST/2,-PS_HEIGHT-SB_HEIGHT/2
CSWPLA,11,0
PCIRC,SB_RADIUS, ,0,360
ASEL,S,LOC,Y,0,SB_HEIGHT/2+PS_HEIGHT
AOVLAP,ALL !叠分基板和焊球模型
ASEL,S,LOC,Y,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT !选择基板
AADD,ALL !生成一个单一面
RECTNG,-SB_JL/2,SB_JL/2,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT
ASEL,S,LOC,Y,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT
ASEL,R,LOC,X,-SB_JL/2,SB_JL/2
ASEL,A,LOC,Y,-SB_RADIUS,SB_HEIGHT/2
AGEN,SB_NB/2,ALL,,,SB_DIST,0,0,0
!建铜印制线
WPOFF,-CP_LENGTH/2,SB_HEIGHT/2+PS_HEIGHT
RECTNG,0,CP_LENGTH,0,CP_HEIGHT
CSYS !激活初始笛卡尔坐标系
WPCSYS !工作坐标系和当前坐标系重合
ASEL,S,LOC,Y,0,CP_HEIGHT
ASEL,R,LOC,X,SB_DIST/2-CP_LENGTH/2,SB_DIST/2+CP_LENGTH/2
AGEN,SB_NB/2,ALL,,,SB_DIST,0,0,0
!建PCB板
WPOFF,0,-PS_HEIGHT-SB_HEIGHT
CSWPLA,12,0
RECTNG,0,PCB_LENGTH/2,0,-PCB_HEIGHT
ALLSEL,ALL
AOVLAP,ALL !叠分模型
ASEL,S,LOC,Y,-PCB_HEIGHT,0
AADD,ALL
NUMCMP,ALL !压缩编号
ALLSEL,ALL
!网格划分设置
!对PCB板进行工作平面切割
CSYS,12
ASEL,S,LOC,Y,-PCB_HEIGHT,0
*DO,I,0,1,1
*DO,J,0,3,1
WPROTA,0,0,90 !工作平面绕Y轴旋转90度
WPOFF,,,SB_DIST/2-SB_JL/2+J*SB_DIST+I*SB_JL
ASBW,ALL
WPCSYS
*ENDDO
*ENDDO
CSYS
WPCSYS
WPOFF,,DA_HEIGHT
WPROTA,0,90,0 !工作平面绕X轴旋转90度
ASEL,S,AREA,,20
ASBW,ALL
WPCSYS
WPOFF,CHIP_LENGTH/2,0,0
WPROTA,0,0,90
ASEL,S,AREA,,24
ASBW,ALL
!赋材料属性
ASEL,S,AREA,,3,6
CSYS,11
WPCSYS
ASEL,A,LOC,Y,-SB_HEIGHT/2,SB_HEIGHT/2
AATT,2,,2 !焊点
CSYS
ASEL,R,AREA,,3,6
ASEL,INVE
ASEL,R,LOC,Y,-PS_HEIGHT,0
AATT,3,,1 !基板
ASEL,S,LOC,Y,0,CP_HEIGHT
AATT,4,,1 !铜印制线
ASEL,S,AREA,,20
ASEL,A,AREA,,31,32,1
AATT,7,,1 !塑封体
ASEL,S,LOC,Y,PS_HEIGHT,PS_HEIGHT+CHIP_HEIGHT !芯片
AATT,6,,1
CSYS,12
ASEL,S,LOC,Y,-PCB_HEIGHT,0
AATT,1,,1 !PCB板
ASEL,S,AREA,,21
AATT,5,,1 !粘结剂
ALLSEL,ALL
!网格划分
CSYS
WPCSYS
ASEL,S,LOC,Y,-PS_HEIGHT,DA_HEIGHT
AESIZE,ALL,0.2E-3 !选取已选平面上的全部线
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
ALLSEL,ALL
MSHKEY,1
AMAP,15,14,16,58,57 !焊球
AMAP,16,19,20,60,59
AMAP,17,25,26,62,61
AMAP,18,31,32,64,63
LSEL,S,LINE,,31,89,58 !PCB板
LSEL,A,LINE,,90,95,5
LESIZE,ALL,,,5
LSEL,S,LINE,,85,87,1
LESIZE,ALL,,,5
LSEL,S,LINE,,83
LESIZE,ALL,,,10
ASEL,S,MAT,,1
AMESH,ALL
ASEL,S,MAT,,6 !芯片
AMESH,ALL
ASEL,S,AREA,,20 !塑封体
AMESH,ALL
ALLSEL,ALL
AMAP,32,6,73,3,74
!施加约束条件
CSYS,12
WPCSYS
LSEL,S,LOC,X,0,0
DL,ALL,,SYMM
LSEL,S,LOC,Y,-PCB_HEIGHT,-PCB_HEIGHT
DL,ALL,,ALL
ALLSEL,ALL
!设置求解选项
!======================
!=======加载求解=======
!======================
/SOLU
/SOLU !进入求解器
ANTYPE,4 !设定为瞬态分析
TRNOPT,FULL !定义瞬态分析类型
NLGEOM,1 !设定为大变形分析
NROPT,FULL !设定全N-R求解
TREF,25 !设定参考温度
TOFFST,273 !设定摄氏温度与开氏温度之间的差值
OUTRES,ALL,ALL !输出每个子步的所有值
TUNIF,25 !定义节点温度为25度
TIME,1E-5 !定义时间为1E-5
SOLVE !求解
!施加载荷并进行计算
NSUBST,5 !设定载荷子步数为5
KBC,0 !定义载荷为斜坡载荷
*DO,N,0,7,1 !施加温度循环载荷，循环圈数为8圈
TUNIF,125 !升温阶段
TIME,5*60+68*60*N !升温结束时间
SOLVE !求解
TIME,30*60+68*60*N !保温结束时间
SOLVE !求解
TUNIF,-55 !降温结束时间
TIME,39*60+68*60*N
SOLVE !求解
TIME,64*60+68*60*N !保温结束时间
SOLVE !求解
TUNIF,25 !升温阶段
TIME,68*60+68*60*N !升温结束时间
SOLVE !求解
*ENDDO
SAVE
!======================
!=======通用后处理=======
!======================
/POST1
PLNSOL,U,SUM,0,1 !查看总体变形分布图
PLNSOL,S,EQV,0,1 !查看等效应力分布图
PLNSOL,EPPL,EQV,0,1 !查看等效塑性应变分布图
FINISH
/POST26
!时间历程后处理（单元结果）
X向
ESOL,2,7,37,S,X,X_2
XVAR,1
PLVAR,2 !绘制危险点的X向应力随时间变化图
ESOL,3,7,37,EPPL,X,EPPLX_3
XVAR,1
PLVAR,3 !绘制危险点的X向塑性变形随时间变化图
ESOL,4,7,37,EPEL,X,EPELX_4
XVAR,1
PLVAR,4 !绘制危险点的X向弹性应变随时间变化图
ADD,5,3,4,,T_STRAIN,,,1,1,1
XVAR,1
PLVAR,5 !绘制危险点的总X向应变随时间变化图
XVAR,5
PLVAR,2 !绘制危险点的X向应力－X向应变环
/AXLAB,X,X STRAIN
/AXLAB,Y,X STRESS\PA
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -