抗震分析.mac

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!参数定义
FINI								!退出
/CLE
/FILNAM,DUCAO,1
/TITLE,DIZHEN ANALYSIS OF DUCAO
!建立模型
!"MODEL"宏文件应放在工作目录下。
MODEL								!运行宏生成模型
!加载及求解
!将已建好的地震波文件放在工作目录下，按前述地震波输入方法输入地震波。
!读入地震波文件
!************读入地震波数据************
*DIM,tjx,ARRAY,2,190,0, , ,  		!定义数组
*DIM,tjy,ARRAY,2,190,0, , ,  		!定义数组
*CREATE,ansuitmp					!读入数据
*VREAD,tjx(1,1),'ACELX','txt',' ',190, , , , , , 
(e9.3,e11.3)
*END
/INPUT,ansuitmp 
*CREATE,ansuitmp					!读入数据
*VREAD,tjy(1,1),'ACELY','txt',' ',190, , , , , , 
(e9.3,e11.3)
*END
/INPUT,ansuitmp 
!****************求解****************
!设置求解选项
FINI
/SOLU
ANTYPE,4							!指定分析类型为瞬态动力学分析
TRNOPT,FULL						!瞬态动力学分析采用FULL法
OUTRES,ALL,NONE					!不输出任何结果
OUTRES,NSOL						!只输出节点自由度结果
OUTRES,STRS						!输出单元节点应力
*DO,T,1,190,1						!循环读入地震数据并求解
TIME,0.1*T							!设置时间步
KBC,0								!指定载荷为递增载荷
NSUB,1								!设定子步数为1
ALPHAD,ALPHA					!设定质量阻尼ALPHA为0.05
BETAD,BETA						!设定刚度阻尼BETA为0.01
ACEL,TJX(2,T),TJY(2,T)				!设定x，y方向加速度
ALLS								!选中所有元素
SOLVE								!求解
*ENDDO
SAVE								!保存
!结果后处理
!通用后处理
/POST1
SET,LAST						!从结果文件读入最后一个子步数据
PLNSOL, U,SUM, 0,1.0    	 	!显示合位移云图
PLNSOL, U,X, 0,1.0	     		!显示X方向位移云图
PLNSOL, U,Y, 0,1.0	     		!显示Y方向位移云图
PLNSOL, S,X, 0,1.0    			!显示X方向应力
PLNSOL, S,Y, 0,1.0   		 	!显示Y方向应力
PLNSOL, S,Z, 0,1.0    			!显示Z方向应力
PLNSOL, S,1, 0,1.0    		 	!显示第一主应力
PLNSOL, S,2, 0,1.0    			!显示第二主应力
PLNSOL, S,3, 0,1.0    			!显示第三主应力
PLNSOL, S,EQV, 0,1.0    		!显示等效应力
PLNSOL, EPTO,X, 0,1.0    		!显示X方向应变
PLNSOL, EPTO,Y, 0,1.0    		!显示Y方向应变
PLNSOL, EPTO,Z, 0,1.0    		!显示Z方向应变
PLNSOL, EPTO,1, 0,1.0			!显示第一主应变
PLNSOL, EPTO,2, 0,1.0			!显示第二主应变
PLNSOL, EPTO,3, 0,1.0			!显示第三主应变
PLNSOL, EPTO,EQV, 0,1.0    	!显示等效应变
PLESOL, EPTO,EQV, 0,1.0		!显示单元解等效应变
!时间历程后处理
ALLS
FINI
/POST26
NUMVAR,20					!指定允许的变量数
NSOL,2,505,U,X, UX_ZHIZUO  	!取出盆式支座上一节点的X向位移数据
NSOL,3,505,U,Y, UY_ZHIZUO  	!取出盆式支座上一节点的Y向位移数据
NSOL,4,1235,U,X, UX_DOWN  	!取出槽底中间节点的X向位移数据
NSOL,5,1235,U,Y, UY_DOWN   	!取出槽底中间节点的Y向位移数据
NSOL,6,1283,U,X, UX_UP  		!取出槽体顶部中间节点的X向位移数据
NSOL,7,1283,U,Y, UY_UP  		!取出槽体顶部中间节点的Y向位移数据
DERIV,8,2,1,,VX_ZHIZUO	!对顶点节点的X向位移微分运算，得到X向速度
DERIV,9,3,1,,VY_ZHIZUO	!对顶点节点的Y向位移微分运算，得到Y向速度
DERIV,10,4,1,,VX_DOWN 	!对墩中间节点的X向位移微分运算，得到X向速度
DERIV,11,5,1,,VY_DOWN 	!对墩中间节点的Y向位移微分运算，得到Y向速度
DERIV,12,6,1,,VX_UP		!对墩下面节点的X向位移微分运算，得到X向速度
DERIV,13,7,1,,VY_UP		!对墩下面节点的Y向位移微分运算，得到Y向速度
PLVAR,2,4,6					!显示上中下三节点的X向位移随时间变化曲线
PLVAR,3,5,7					!显示三个节点的Y向位移随时间变化曲线
PLVAR,8,10,12					!显示三个节点的X向速度随时间变化曲线
PLVAR,9,11,13					!显示三个节点的Y向速度随时间变化曲线