📄 3d-qfp-定稿.txt
字号:
FINI
/CLE
/UNITS,SI !国际单位制
/FILNAME,QFP !制定文件名为QFP
/TITLE,3D THERMAL SIMULATION OF QFP !制定标题
!定义结构参数
!定义PCB的尺寸
*SET,PCB_L,40E-3 !PCB长度
*SET,PCB_W,40E-3 !PCB宽度
*SET,PCB_H,2E-3 !PCB高度
!定义芯片尺寸
*SET,C_L,15E-3 !芯片长度
*SET,C_W,15E-3 !芯片宽度
*SET,C_H,2.5E-3 !芯片高度
!定义引线上下部分尺寸
*SET,LES_L,1.5E-3 !引线两端长度
*SET,LEM_H,1.2E-3 !引线中间长度
*SET,LE_W,0.3E-3 !引线宽度
*SET,LE_T,0.4E-3 !引线厚度
*SET,LE_NB,12 !芯片一侧引脚数
*SET,LE_DIST,1E-3 !引线间距
!定义焊料尺寸
*SET,SO_L,1.5E-3 !焊点长度
*SET,SO_H,0.15E-3 !焊点高度
*SET,SO_T,0.4E-3 !焊点厚度
!定义热介质材料的尺寸
*SET,TIM_H,0.15E-3 !热介质厚度
!定义热扩展面的尺寸
*SET,HS_L,25E-3 !热扩展面长度
*SET,HS_W,25E-3 !热扩展面宽度
*SET,HS_H,1.5E-3 !热扩展面厚度
!定义粘结剂的尺寸
*SET,SA_H,0.15E-3 !粘结剂厚度
!定义热沉基座的尺寸
*SET,SINK_L,28E-3 !热沉基座长度
*SET,SINK_W,28E-3 !热沉基座宽度
*SET,SINK_H,1.5E-3 !热沉基座厚度
*SET,FIN_NB,10 !散热片数量
*SET,FIN_H,4E-3 !散热片高度
*SET,FIN_T,1E-3 !散热片厚度
*SET,FIN_DIST,2.8E-3 !散热片间距
!************************
!*******前处理***********
!************************
/PREP7 !进入前处理
ET,1,SOLID70 !定义单元类型
MP,KXX,1,82 !定义芯片的导热系数
MP,KXX,2,390 !定义引线材料(Cu)的导热系数
MP,KXX,3,50 !定义焊料(63Sn37Pb)的导热系数
MP,KXX,4,8.37 !定义PCB的导热系数（各项异性）
MP,KYY,4,8.37
MP,KZZ,4,0.32
MP,KXX,5,1.1 !定义粘结剂的导热系数
MP,KXX,6,1 !定义热介质材料的导热系数
MP,KXX,7,240 !定义热沉(Al)的导热系数
MP,KXX,8,390 !定义热扩展面(Cu)的导热系数
!实体建模
BLOCK,0,PCB_L/2,0,PCB_W/2,0,PCB_H !建立PCB板
WPOFF,0,0,PCB_H+SO_H+LEM_H+2*LE_W-C_H/2 !偏移坐标系
CSWPLA,11,0 !定义编号为11的局部坐标系
BLOCK,0,C_L/2,0,C_W/2,0,C_H !建立芯片
BLOCK,0,C_L*3/8,0,C_W*3/8,0,C_H
VSEL,S,LOC,Z,0,C_H !选择芯片部分
VOVLAP,ALL !叠分选择的部分
WPOFF,C_L/2,(LE_DIST-LE_T)/2,C_H/2 !偏移坐标系
BLOCK,0,LES_L,0,LE_T,0,-LE_W !建立引线上端
WPOFF,LES_L,0,-LE_W !偏移坐标系
BLOCK,0,-LE_W,0,LE_T,0,-LEM_H !建立引线中端
WPOFF,-LE_W,0,-LEM_H !偏移坐标系
BLOCK,0,LES_L,0,LE_T,0,-LE_W !建立引线下端
BLOCK,0,LES_L,0,LE_T,-LE_W,-LE_W-SO_H !建立钎焊部分
CSYS !激活初始笛卡尔坐标系
WPCSYS !工作坐标系和当前坐标系重合
VSEL,S,LOC,X,C_L/2,C_L/2+2*LES_L !选择引线和焊料实体
VSEL,R,LOC,Z,PCB_H,PCB_H*5
VGEN,LE_NB/2,ALL,,,,LE_DIST,,,0 !对所选实体沿Y向复制
VSEL,S,LOC,X,C_L/2,C_L/2+2*LES_L !选择复制得到的引线和焊料实体
VSEL,R,LOC,Z,PCB_H,PCB_H*5
WPROTA,-45,0,0 !工作平面绕Z轴旋转－45度
CSWPLA,12,0 !定义编号为12的局部坐标系
VSYMM,X,ALL,,,,0,0 !对引线和焊料进行镜像复制
CSYS,11 !激活编号为11的局部坐标系
WPCSYS !工作坐标系和当前坐标系重合
BLOCK,0,C_L/2,0,C_W/2,C_H,C_H+TIM_H !建立热介质材料部分
WPOFF,0,0,C_H+TIM_H !偏移坐标系
CSWPLA,13,0 !建立编号为13的局部坐标系
*SET,HS_H1,TIM_H+C_H/2+2*LE_W+SO_H+LEM_H-SA_H !定义热扩展面相关的一个参量
BLOCK,0,HS_L/2,0,HS_W/2,0,HS_H !建立热扩展面
BLOCK,HS_L/2,HS_L/2-HS_H,0,HS_W/2,0,-HS_H1 !建立热扩展面
BLOCK,HS_L/2,HS_L/2-HS_H,0,HS_W/2,-HS_H1,-HS_H1-SA_H !建立热扩展面和PCB间的粘结剂部分
BLOCK,0,HS_L/2-HS_H,HS_W/2,HS_W/2-HS_H,0,-HS_H1 !建立热扩展面
BLOCK,0,HS_L/2-HS_H,HS_W/2,HS_W/2-HS_H,-HS_H1,-HS_H1-SA_H!建立热扩展面和PCB间的粘结剂
BLOCK,0,HS_L/2,0,HS_W/2,HS_H,HS_H+SA_H !建立热扩展面和热沉间的热介质材料
BLOCK,0,SINK_L/2,0,SINK_W/2,HS_H+SA_H,HS_H+SA_H+SINK_H !建立热沉部分
WPOFF,0,0,HS_H+SA_H+SINK_H !偏移坐标系
CSWPLA,14,0 !建立编号为14的局部坐标系
*SET,FIN_DT, (FIN_DIST-FIN_T)/2
BLOCK,FIN_DT,FIN_DT+FIN_T,0,SINK_W/2,0,FIN_H !建立热沉的散热片
VSEL,S,LOC,Z,0,FIN_H !选择建立的散热片
VGEN,FIN_NB/2,ALL,,,FIN_DIST,,,,0 !沿X向复制散热片
!将PCB分为三部分，便于对结构规则部分进行SWEEP进行网格划分
CSYS !激活初始笛卡尔坐标系
WPCSYS !工作坐标系和当前坐标系重合
BLOCK,0,HS_L/2,0,HS_W/2,0,PCB_H !建立热扩展面大小的一个实体
BLOCK,0,C_L/2,0,C_W/2,0,PCB_H !建立芯片大小的一个实体
VSEL,S,LOC,Z,0,PCB_H !选择整个PCB板部分
VOVLAP,ALL !叠分选择的部分
ALLSEL,ALL !选择所有组元
VGLUE,ALL !粘接所有实体
NUMCMP,ALL !压缩所有组元编号
!赋材料属性
CSYS
VSEL,S,LOC,Z,0,PCB_H !选择PCB板
VATT,4,,1,0 !定义PCB材料属性
VSEL,S,LOC,Z,PCB_H,PCB_H+SO_H !选择一侧的焊料部分
VSEL,R,LOC,X,C_L/2,HS_L/2-HS_H
VATT,3,,1,0 !定义焊料材料属性
VSEL,S,LOC,Z,PCB_H,PCB_H+SO_H !选择另一侧的焊料部分
VSEL,R,LOC,Y,C_L/2,HS_L/2-HS_H
VATT,3,,1,0 !定义焊料材料属性
VSEL,S,LOC,Z,PCB_H,PCB_H+SA_H !选择PCB和热扩展面间一侧的粘结剂
VSEL,R,LOC,X,HS_L/2-HS_H,HS_L/2
VATT,5,,1,0 !定义粘结剂材料属性
VSEL,S,LOC,Z,PCB_H,PCB_H+SA_H !选择PCB和热扩展面间另一侧的粘结剂
VSEL,R,LOC,Y,HS_L/2-HS_H,HS_L/2
VATT,5,,1,0 !定义粘结剂材料属性
CSYS,11 !激活编号为11的局部坐标系
VSEL,S,LOC,Z,0,C_H !选择芯片
VSEL,R,LOC,X,0,C_L/2
VSEL,R,LOC,Y,0,C_W/2
VATT,1,,1,0 !定义芯片材料属性
VSEL,S,LOC,Z,C_H,C_H+TIM_H !选择热介质材料
VSEL,R,LOC,X,0,C_L/2
VSEL,R,LOC,Y,0,C_W/2
VATT,6,,1,0 !定义热介质材料属性
VSEL,S,LOC,Z,C_H/2-2*LE_W-LEM_H,C_H/2 !选择一侧引线
VSEL,R,LOC,X,C_L/2,HS_L/2-HS_H
VATT,2,,1,0 !定义引线材料属性
VSEL,S,LOC,Z,C_H/2-2*LE_W-LEM_H,C_H/2 !选择另一侧引线
VSEL,R,LOC,Y,C_L/2,HS_L/2-HS_H
VATT,2,,1,0 !定义引线材料属性
CSYS,13 !激活编号为13的局部坐标系
VSEL,S,LOC,Z,0,HS_H !选择芯片上的热扩展面
VATT,8,,1,0 !定义热扩展面材料属性
VSEL,S,LOC,Z,-HS_H1,0 !选择芯片一侧的热扩展面
VSEL,R,LOC,X,HS_L/2-HS_H,HS_L/2
VATT,8,,1,0 !定义热扩展面材料属性
VSEL,S,LOC,Z,-HS_H1,0 !选择芯片另一侧的热扩展面
VSEL,R,LOC,Y,HS_L/2-HS_H,HS_L/2
VATT,8,,1,0 !定义热扩展面材料属性
VSEL,S,LOC,Z,HS_H,HS_H+SA_H !选择热沉与热扩展面间的热介质材料部分
VATT,6,,1,0 !定义热介质材料属性
VSEL,S,LOC,Z,HS_H+SA_H,5*FIN_H !选择热沉部分
VATT,7,,1,0 !定义热沉材料属性
!划分网格
VSEL,S,VOLU,,65,66,1
VSEL,INVE !在整个实体中选择未选择的部分
VSWEEP,ALL !对选择的实体进行映射网格划分
LSEL,S,LINE,,14,15,1
LESIZE,ALL,,,8
LSEL,S,LINE,,20,22,2
LSEL,A,LINE,,39,41,2
LESIZE,ALL,,,3
LSEL,S,LINE,,704,705,1
LESIZE,ALL,,,5
LSEL,S,LINE,,495,496,1
LESIZE,ALL,,,6
VSEL,S,VOLU,,65,66,1
MSHAPE,1,3D !定义单元类型
VMESH,ALL !进行自由网格划分
!定义加载条件
!并施加PCB对流和辐射边界条件
ASEL,S,,,4 !选择3号面
ASEL,A,,,6 !添加4号面
ASEL,A,,,366 !添加392号面
SFA,ALL,1,CONV,10,25 !定义热对流
SFA,ALL,,RDSF,0.9,1 !定义热辐射
!施加热扩展面对流边界条件
ASEL,S,AREA,,115,254,139 !选择115,254号面
ASEL,A,AREA,,347,348,1 !添加347,348号面
ASEL,A,AREA,,367 !添加367号面
SFA,ALL,1,CONV,10,25 !定义热对流
!施加热沉对流边界条件
VSEL,S,MAT,,7 !选择材料编号为7(热沉)的实体
ASLV,S !选择该实体的全部面
ASEL,U,,,117 !不选择117号面
ASEL,U,,,119,143,6 !不选择119,125,131,137,143号面
SFA,ALL,1,CONV,10,25 !定义热对流
!设置辐射计算的参数
STEF,5.67E-8 !定义玻尔兹曼常数（黑体辐射常数）
TOFFST,273 !摄氏温度和开氏温度的差值
RADOPT,0.5,0.01,0 !辐射求解设置
SPCTEMP,1,25 !环境温度
TUNIF,25 !设定初始温度
!======================
!======加载求解========
!======================
!施加芯片的热源
VSEL,S,MAT,,1 !选择材料编号为1(芯片)的实体
BFV,ALL,HGEN,1.778E6 !加载热源(热流密度)此时功率为1W
ALLSEL,ALL !选择所有组元
!求解过程
/SOLU
ANTYPE,STATIC
TIME,1 !设置时间为1
DELTIM,0.5,0.5,0.5 !定义载荷的时间步长
NEQIT,1000 !定义非线性分析中的最大平衡迭代次数
SOLVE !求解
SAVE !保存
!======================
!=======通用后处理=======
!======================
FINISH
/POST1
!查看总体温度分布图
PLNSOL,TEMP,,0
!查看芯片温度分布图
ESEL,S,MAT,,1
PLNSOL,TEMP,,0
!查看引线的温度分布图
ESEL,S,MAT,,2
PLNSOL,TEMP,,0
!查看焊料的温度分布图
ESEL,S,MAT,,3
PLNSOL,TEMP,,0
!查看PCB温度分布图
ESEL,S,MAT,,4
PLNSOL,TEMP,,0
!查看热介质材料的温度分布图
ESEL,S,MAT,,6
PLNSOL,TEMP,,0
!查看热沉的温度分布图
ESEL,S,MAT,,7
PLNSOL,TEMP,,0
!查看热扩展面温度分布图
ESEL,S,MAT,,8
PLNSOL,TEMP,,0
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -