ex2-3-1_2d.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!命令流：
fini
/cle

/FILNAME,rebound_2D
/PREP7  
*SET,exx_p,7e4
*SET,exx_t,7e10  
*SET,rp,65 
*SET,rt,5  
*SET,h,6.5  
*SET,sts1,55
*SET,stn1,sts1/exx_p  
*SET,sts2,112   
*SET,stn2,0.00575   
*SET,sts3,172   
*SET,stn3,0.02925   
*SET,sts4,241     
*SET,stn4,0.1   
*SET,net,8
*SET,nex,52

ET,1,PLANE42,,,1
et,2,targe169   $et,3,conta172
MP,EX,1,exx_p
MP,PRXY,1,0.325
MP,EX,2,exx_t
MP,PRXY,2,0.3
TB,KINH,1,1,4,0 
TBPT,,stn1,sts1 
TBPT,,stn2,sts2 
TBPT,,stn3,sts3 
TBPT,,stn4,sts4

N,1,rp  $N,2   
N,3,,h/2   $n,4,,h/2+0.1
K,1,,-(h/2)  $K,2,rt,-(h/2)  
K,3,rp,-(h/2)
KGEN,2,all, , , ,h, ,3
k,7,,h/2+0.1 $k,8,rt,h/2+0.1
KGEN,2,7,8,1, ,h, ,2
L,1,2  $L,4,5  $L,2,3  
L,5,6  $L,7,8  $L,9,10
A,1,2,5,4   $a,2,3,6,5   $a,7,8,10,9

lsel,u,line,,3,4,1
LESIZE,all, , ,net   
lsel,s,line,,3,4,1
LESIZE,all, , ,nex,2.5
MSHKEY,1
ASEL,s,LOC,y,-h/2,h/2
AMESH,all
ASEL,s,LOC,y,h/2,100
mat,2
AMESH,all
NUMMRG,NODE, , , ,LOW   
NUMCMP,NODE

MP,MU,1,0.35
MAT,1   
R,3 
REAL,3  
R,3,,,1.0,0.1,0,
LSEL,S,,,5  
TYPE,2  
NSLL,S,1
ESLN,S,0
ESURF,all   
LSEL,S,,,2
TYPE,3  
NSLL,S,1
ESLN,S,0
ESURF,all
ALLSEL,all

nsel,s,node,,1
D,all,uy
D,all,ux
nsel,s,loc,x,0
D,all,ux
ALLSEL,all
fini

/sol
antype,0
OUTRES,ALL,all
nlgeom,on
autots,1
time,1       
nsubst,100
nsel,s,loc,y,h/2+0.1,100 
d,all,uy,-4
allsel,all
solve
*get,def1,node,3,u,y

time,2
nsubst,100
nsel,s,loc,y,h/2+0.1,100
d,all,uy,0
allsel,all
solve
*get,def2,node,3,u,y
disp_2d=def2-def1
fini

/post1
! 冲压完毕
set,1,last
PLNSOL, S,EQV
PLNSOL, NL,EPEQ		!等效塑性应变


! 卸载完毕
set,2,last
PLNSOL, S,EQV
PLNSOL, NL,EPEQ		!等效塑性应变

!找到最大应力的节点编号，75号节点
NSORT,S,EQV 
*GET,n_max_2d,SORT,0,IMAX

/post26
ANSOL,2,n_max_2d,S,EQV,eqv_2d
plvar,2