ex2-4-2.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!COD计算
!COD激励频率为40HZ,质量为1E-4T

FINI
/CLE
/FILENAME,COD 
/TITLE,COD ANLYSIS
*AFUN,RAD
!设置参数
*SET,LL,23.6		!COD脚长度MM
*SET,BB,10.3		!COD脚宽度
*SET,TT,0.75		!COD脚厚度
*SET,EE,210E3		!COD脚弹性模量
*SET,DL,10		!COD两脚间距
*SET,LC,25.6		!电子元件长度
*SET,BC,16.8		!电子元件宽度
*SET,HC,29.1		!电子元件高度
*SET,EC,100E3		!电子元件弹性模量
*SET,NN,2		!COD脚单元层数
*SET,NB,6		!COD脚宽度方向单元数
*SET,NC,12		!COD脚长度方向份数
*SET,NL,12		!电子元件长度方向份数

!建模
/PREP7
!单元类型
ET,1,MESH200		!平面网格
KEYOPT,1,1,6		!四边形网格
ET,2,SOLID45
MP,EX,1,EE		!COD脚
MP,PRXY,1,0.3
MP,DENS,1,2.8E-6
MP,EX,2,EC		!电子元件
MP,PRXY,2,0.3
MP,DENS,2,2E-6

/PNUM,KP,1
/PNUM,LINE,1
/PNUM,NODE,0
/VIEW,1,1,1,1
/ESHAPE,1

!平面模型
!关键控制点
K,1
K,2,,,BC
K,3,,HC
K,4,,HC,BC
K,5,,(HC-2*TT-DL)/2,BC
K,6,,(HC-DL)/2,BC
K,7,,(HC-2*TT+DL)/2,BC
K,8,,(HC+DL)/2,BC
K,9,,(HC-2*TT-DL)/2,(BC+BB)/2
K,10,,(HC-DL)/2,(BC+BB)/2
K,11,,(HC-2*TT+DL)/2,(BC+BB)/2
K,12,,(HC+DL)/2,(BC+BB)/2
K,13,,(HC-2*TT-DL)/2,(BC-BB)/2
K,14,,(HC-DL)/2,(BC-BB)/2
K,15,,(HC-2*TT+DL)/2,(BC-BB)/2
K,16,,(HC+DL)/2,(BC-BB)/2
K,17,,(HC-2*TT-DL)/2
K,18,,(HC-DL)/2
K,19,,(HC-2*TT+DL)/2
K,20,,(HC+DL)/2
K,21,,,(BC+BB)/2
K,22,,,(BC-BB)/2
K,23,,HC,(BC+BB)/2
K,24,,HC,(BC-BB)/2
!平面模型
A,1,17,13,22
A,17,18,14,13
A,18,19,15,14
A,19,20,16,15
A,20,3,24,16
A,22,13,9,21
A,13,14,10,9
A,14,15,11,10
A,15,16,12,11
A,16,24,23,12
A,21,9,5,2
A,9,10,6,5
A,10,11,7,6
A,11,12,8,7
A,12,23,4,8
!设置划分份数
LSEL,S,LOC,Y,(HC-2*TT-DL)/2+0.5,(HC-DL)/2-0.5
LSEL,A,LOC,Y,(HC-2*TT+DL)/2+0.5,(HC+DL)/2-0.5
LESIZE,ALL,,,NN			!COD脚厚度方向
LSEL,S,LOC,Z,0.5,(BC-BB)/2-0.5
LSEL,A,LOC,Z,(BC+BB)/2+0.5,BC-0.5
LESIZE,ALL,,,NN			!电子元件两边
LSEL,S,LOC,Y,0.5,(HC-2*TT-DL)/2-0.5
LSEL,A,LOC,Y,(HC-DL)/2+0.5,(HC-2*TT+DL)/2-0.5
LSEL,A,LOC,Y,(HC+DL)/2+0.5,HC-0.5
LESIZE,ALL,,,NB			!COD脚宽度方向
LSEL,S,LOC,Z,(BC-BB)/2+0.5,(BC+BB)/2-0.5
LESIZE,ALL,,,NB			!电子元件上中下
!划分COD脚平面网格
TYPE,1
MAT,1
ASEL,S,AREA,,7,9,2
AMESH,ALL
!拉伸成体网格
TYPE,2
MAT,1
EXTOPT,ESIZE,NC
VEXT,ALL,,,LL
!划分电子元件平面网格
TYPE,1
MAT,2
ALLS
ASEL,U,AREA,,7,9,2
AMESH,ALL
!拉伸成体网格
ASEL,S,LOC,X,0
TYPE,2
MAT,2
EXTOPT,ACLEAR,1
EXTOPT,ESIZE,NL
ESEL,ALL
VEXT,ALL,,,-LC
NUMMRG,ALL,ALL
NUMCMP,ALL,ALL
SAVE
FINI

/SOL
ANTYPE,0
NSEL,S,LOC,X,LL
NSEL,R,LOC,Y,(HC+DL)/2			!上脚
D,ALL,UX,,,,,UZ
D,ALL,UY,-1.5
ALLS
NSEL,S,LOC,Y,(HC-2*TT-DL)/2		!下脚
NSEL,R,LOC,X,LL
D,ALL,UX,,,,,UZ
D,ALL,UY,+1.5
ALLS
ACEL,0,9.8,0				!设置重力加速度
SOLVE
SAVE

fini
/post1
FINISH  
/POST1  
PLNSOL, U,SUM, 0,1.0
PLNSOL, S,EQV, 0,1.0
PLNSOL, S,X, 0,1.0 
PLESOL, S,X, 0,1.0