ex2-3-2.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!参数设定
FINI
/CLE
/FILNAME,GEAR
/UNITS,SI
*AFUN,DEG		!角度输入为DEG
*SET,RI,0.4		!齿内径
*SET,RE,0.5		!齿外径，轮内径
*SET,RL,0.58		!轮外径
*SET,RH,0.04		!孔内径
*SET,THE,0.16		!齿厚度
*SET,THI,0.08		!轮厚度
!前处理
/PREP7
/PNUM,KP,1
/PNUM,LINE,1
ET,1,SOLID185
MP,EX,207E9
MP,NUXY,0.3
CSYS,1         
!几何模型
K,1,RI,3
K,2,RI,7
K,3,RI+0.02,8
K,4,RI+0.06,6
K,5,RE,6
K,6,RE,-6
K,7,RI+0.06,-6
K,8,RI+0.03
KGEN,30,1,8,1,,12,,8		!复制关键点
!平面模型
*DO,I,1,240,8			!生成线和面    
L,I,I+1
SPLINE,I+1,I+2,I+3
L,I+3,I+4
L,I+4,I+5
L,I+5,I+6
SPLINE,I+6,I+7,I
AL,I,I+1,I+2,I+3,I+4,I+5,I+6,I+7
*ENDDO
!实体模型
VEXT,1,30,1,,,-THE		!面生成体
/VIEW,1,1,1,1
/PNUM,KP,0
/PNUM,LINE,0
CYLIND,RE,RL,-(THE-THI)/2,-(THE+THI)/2,0,360	!建立外轮
NUMMRG,KP			!合并关键点
VADD,ALL			!体相加
CSYS,1
LOCAL,11,1,RE			!定义局部坐标系
LOCAL,12,1,-RE
WPCSYS,-1,11			!移动工作面至11号坐标系
CYLIND,,RH,,-(THE-THI)/2,0,360		!建立小孔
CYLIND,,RH,-(THE+THI)/2,-THE,0,360
WPCSYS,-2,12			!移动工作面至12号坐标系
CYLIND,,RH,,-(THE-THI)/2,0,360		!建立小孔
CYLIND,,RH,-(THE+THI)/2,-THE,0,360
VSBV,32,1			!体相减
VSBV,5,2
VSBV,1,3
VSBV,2,4
/PNUM,VOLU,1
VPLOT
!划分网格
MSHKEY,0
MSHAPE,1
SMRTSIZE,8
VMESH,ALL