ex3-4.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!应用实例3-4
!===圆壳受风载===
FINI
/CLE

/FILNAME,EX3-4
/TITLE,EX3-4
*AFUN,DEG  
!======================
!========前处理========
!======================
/PREP7
ET,1,93              		!SHELL93

R,1,44              		!球壳、连接板

MP,EX,1,2.094E5          	!球壳材料模量
MP,PRXY,1,0.262        		!球壳材料泊松比
MP,DENS,1,7.83E-6     		!球壳材料密度

CSYS,1               		!激活整体柱坐标
K,1,7850,90            		!建立关键点1
K,2,7850,0            		!建立关键点2
K,3,7850,-30           		!建立关键点3
K,100				!建立关键点100
L,1,2		     		!连接关键点2,1，生成圆弧线1
L,2,3		     		!连接关键点1,3，生成圆弧线2
AROTAT,1,2,,,,,1,100,360	!旋转360度生成圆弧面

AESIZE,ALL,1000			!设定面上单元尺寸为1000
CSYS
MSHAPE,0
MSHKEY,1
AMESH,ALL

OMEGA=2
!GUI定义函数边界条件WIND,并加载，定义为WIND表参数
SFA,ALL,,PRES,%WIND%		!施加面载荷
ALLS				!选中所有元素
!======================
!=======加载求解=======
!======================
NSEL,S,LOC,Y,7850*SIN(-30)	!选择下部圆边上所有节点
D,ALL,UX
D,ALL,UY
D,ALL,UZ
ALLS

/SOLU		
ANTYPE,4			!指定分析类型为瞬态动力学分析
TRNOPT,FULL			!瞬态动力学分析采用FULL法

KBC,0
TIME,3*2*3.14/OMEGA
NSUB,3*12
OUTRES,BASIC,ALL		!输出基本项，每一步都输出

ALLS
SOLVE
SAVE

!-------------------
!----通用后处理-----
!-------------------
FINI
/POST1
SET,LAST			!从结果文件读入最后一个子步数据
PLNSOL, U,SUM, 0,1.0     	!显示合位移云图
PLNSOL, U,X, 0,1.0	     	!显示X方向位移云图
PLNSOL, U,Y, 0,1.0	     	!显示Y方向位移云图

!球壳部分后处理
PLNSOL, S,EQV, 0,1.0     	!显示EQUIVALENT STRESS
ETABLE,Q_MX, SMISC, 4    	!定义球壳X向弯矩单元表
ETABLE,Q_MY, SMISC, 5    	!球壳Y向弯矩
ETABLE,Q_TX, SMISC, 1    	!球壳X向张力
ETABLE,Q_TY, SMISC, 2    	!球壳Y向张力

PLETAB,Q_MX,NOAV         	!显示球壳X向弯矩云图
PLETAB,Q_MY,NOAV         	!显示球壳Y向弯矩云图
PLETAB,Q_TX              	!显示球壳X向张力云图
PLETAB,Q_TY              	!显示球壳Y向张力云图

!-------------------
!--时间历程后处理---
!-------------------
FINI
/POST26
NSEL,S,LOC,X,0			!选择圆壳最顶部的节点
NSEL,R,LOC,Z,0
TOP_N=NODE(0,7850,0)		!提取其节点编号

NSOL,2,TOP_N,U,X,UX_UP  	!取出顶点节点的X向位移数据
NSOL,3,TOP_N,U,Y,UY_UP  	!取出顶点节点的Y向位移数据
NSOL,4,TOP_N,U,Z,UZ_UP  	!取出顶点节点的Z向位移数据

DERIV,5,2,1,,VX_UP		!对顶点节点的X向位移微分运算，得到X向速度
DERIV,6,3,1,,VY_UP		!对顶点节点的Y向位移微分运算，得到Y向速度
DERIV,7,4,1,,VZ_UP		!对顶点节点的Z向位移微分运算，得到Z向速度

PLVAR,2,5			!显示上下两节点的X向位移随时间变化曲线
PLVAR,3,6			!显示上下两节点的Y向位移随时间变化曲线
PLVAR,4,7			!显示上下两节点的Z向位移随时间变化曲线