ex4-6.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

FINISH
/CLEAR
/FILN,E46
/TITLE,RELIABILTY
!定义参数
*SET,LENGTH,200                       ! 扳手长度
*SET,WIDTH,30                         ! 扳手宽度
*SET,LOAD,500                         ! 施加于扳手上的载荷
*SET,SIGMA,200                        ! 许用应力值
*SET,DETSS,0                          ! 设定初值
*SET,HALFWIDTH,WIDTH*0.5              ! 定义半宽度
/PREP7  
!创建实体
K,1,180,15,0                          ! 创建关键点1
PCIRC,25,,0,360                       ! 创建圆环
RECTNG,0,LENGTH,HALFWIDTH,-HALFWIDTH  ! 创建矩形
WPOFF,LENGTH,0,0                      ! 平移关键点至位置(LENGTH,0,0)
PCIRC,HALFWIDTH,,0,360                ! 创建圆环 
ET,1,SHELL63                          ! 定义单元
R,1,5                                 ! 定义实常数
MP,EX,1,2.1E8                         ! 定义弹性模量  
MP,PRXY,1,0.3                         ! 定义泊松比
MP,DENS,1,7.8E-6                      ! 定义密度
RPR4,6,-LENGTH,0,HALFWIDTH,360        ! 创建六变形
AADD,1,2,3                            ! 面相加
ASBA,5,4                              ! 面相减

!划分网格
ESIZE,3,0                             ! 设定单元大小
MSHAPE,0,2D                           ! 激活网格类型
MSHKEY,0                              ! 设定自由划分方式
AMESH,ALL                             ! 划分网格
FINISH 

!加载与求解 
/SOLU 
CSYS,1                                ! 激活极坐标
NSEL,S,LOC,Y,60                      
NSEL,A,LOC,Y,120
NSEL,A,LOC,Y,180
NSEL,A,LOC,Y,240
NSEL,A,LOC,Y,300
NSEL,A,LOC,Y,360  
NSEL,R,LOC,X,HALFWIDTH
D,ALL,ALL,0                           ! 对六边形内部节点施加全约束
CSYS,0                                ! 激活笛卡尔坐标
NSEL,S,LOC,X,LENGTH
NSEL,R,LOC,Y,HALFWIDTH                ! 选中扳手握部圆弧顶点
F,ALL,FY,-LOAD                        ! 施加载荷
ALLSEL                                ! 全选择
SOLVE                                 ! 求解

!后处理  
/POST1
NSORT,S,EQV                           ! 按照节点等效应力大小对节点进行排序
*GET,MAXSTR,SORT,,MAX                 ! 提取最大应力值，赋予MAXSTR
DETSS=SIGMA-MAXSTR                    ! 定义失效函数
LGWRITE,RELIAB_BANSHOU,TXT            ! 创建可靠性分析文件
FINISH 
!可靠性分析
/PDS                                  ! 进入概率分析模块 
PDANL,'RELIAB_BANSHOU','TXT',' '      ! 选定分析文件 
PDVAR,LENGTH,WEIB,2,250,100           ! LENGTH为WEIBULL分布
PDVAR,WIDTH,UNIF,29,31                ! WIDTH为UNIF分布
PDVAR,LOAD,BETA,1,3,0,600             ! LOAD为BETA分布
PDVAR,SIGMA,GAUS,200,4,0,0            ! SIGMA为GAUS分布
PDVAR,DETSS,RESP                      ! 定义输出变量
PDMETH,MCS,LHS                        ! 选择分析方法为M.C.方法 
PDLHS,100,1,RAND, ,'ALL ', , , ,INIT  ! 设定分析选项
PDEXE                                 ! 执行可靠性分析
!察看可靠性分析结果
PDSHIS,SOLU01,DETSS,SAMP,0.95,        ! 图形显示随机输出变量DELTS采样历史
PDSHIS,SOLU01,DETSS,MEAN,0.95,        ! 图形显示随机输出变量DELTS样本均值的历史
PDSHIS,SOLU01,DETSS,STDV,0.95,        ! 图形显示随机输出变量DELTS样本方差的历史
PDHIST,SOLU01,DETSS, ,REL             ! 显示随机输出变量DELTS的出现的频度的直方图
PDCDF,SOLU01,DETSS,EMP,0.95,100,      ! 显示随机输出变量DELTS的分布函数图
PDPROB,SOLU01,DETSS,GT, ,'    ',0.95, ! 查看DETSS小于0、置信度为95%时的概率
PDSENS,SOLU01,DETSS,BOTH,RANK,0.025,  ! 显示随机输出变量对随机输入变量的灵敏度
PDSCAT,SOLU01,LENGTH,DETSS,POLY,1, ,  ! 随机输入变量LENGTH对随机输出变量DELTS的敏感度
PDWRITE,REPORT                        ! 生成可靠性分析报告