ex4-1.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

FINI
/CLE
/FILNAME,PRESTRESS PROBLEM
/TITLE,EXAMPLE OF PRESTRESS PROBLEM
L=6	!钢筋长度
T=0.05
B=0.25
H=0.4
ARE=3.14E-4	!钢筋横截面积
EAL=2E11
P=1.0E-5	!线膨胀系数
YYL=2000	!钢筋的预加力大小
/PREP7
!定义单元、实常数及材料属性
ET,1,65
ET,2,45
ET,3,8
MP,EX,1,3.3E10
MP,PRXY,1,0.3
TB,CONCR,1	!定义混凝土材料
TBTEMP,0
TBDATA,,0.9,1,3.46E6,-1
R,1
MP,EX,2,2.06E11
MP,PRXY,2,0.3
TB,BKIN,2	!定义为双线性随动硬化模型
TBTEMP,0
TBDATA,,215E6,0
R,2
MP,EX,3,EAL
MP,PRXY,3,0.3
MP,ALPX,3,P	!定义热膨胀系数
TB,BKIN,3
TBTEMP,0
TBDATA,,215E6,0
R,3,ARE
!建模
K,1		!创建关键点
K,2,,T,0	
K,3,,T,T
K,4,,,T
K,5,,H+T,0
K,6,,H+2*T,0
K,7,,H+2*T,T
K,8,,H+T,T
K,9,,,B+T
K,10,,T,B+T
K,11,,T,B+2*T
K,12,,,B+2*T
K,13,,H+T,B+T
K,14,,H+2*T,B+T
K,15,,H+2*T,B+2*T
K,16,,H+T,B+2*T
A,1,2,3,4	!由关键点生成面
A,2,5,8,3
A,5,6,7,8
A,4,3,10,9
A,3,8,13,10
A,8,7,14,13
A,9,10,11,12
A,10,13,16,11
A,13,14,15,16
VEXT,ALL,,,L!将面延伸成体
K,40,,H/2,B/2+T
K,41,L,H/2,B/2+T
L,40,41	!创建力筋线
LSEL,S,,,65
LATT,3,3,3
LESIZE,ALL,,,20
LMESH,ALL	!划分力筋网格
ALLS
VSEL,S,,,1,4
VSEL,A,,,6,9
VATT,2,2,2
VSEL,S,,,5
VATT,1,1,1
LSEL,S,,,52,59,7
LSEL,A,,,62,63
LSEL,A,,,38,39
LSEL,A,,,34,40,6
LSEL,A,,,44,55,11
LSEL,A,,,54,56,2
LSEL,A,,,25,28
LESIZE,ALL,,,1
LSEL,S,,,43,45,2
LSEL,A,,,48,51,3
LESIZE,ALL,,,4
LSEL,S,,,33,35,2
LSEL,A,,,49,60,11
LESIZE,ALL,,,6
LSEL,S,,,31,37,6
LSEL,S,,,46,50,4
LESIZE,ALL,,,20
ALLSEL,ALL
MSHAPE,0,3D
MSHKEY,1
VMESH,ALL	!划分混凝土网格
/SOLU
!施加约束和荷载
LSEL,S,,,4,13,9
LSEL,A,,,20
DL,ALL,,UY,0
DL,ALL,,UZ,0
LSEL,S,,,28,45,17
LSEL,A,,,56
DL,ALL,,UY,0
DK,1,UX,0
DK,17,UX,0
ASEL,S,,,21,41,10
SFA,ALL,1,PRES,10000	!在混凝土上部施加压力
BFL,65,TEMP,-YYL/(EAL*ARE*P)!对钢绞线施加温度
!耦合自由度
ALLS	!全选
LSEL,S,,,65	!选择力筋线
NSLL,S,1	!选择力筋线上的所有节点
CM,CM1JNOD,NODE	!将力筋线上的节点命名为CM1JNOD
*GET,MAX1,NODE,0,COUNT	!获取所选节点的数目并赋给参数MAX1
*DIM,OJD,,MAX1	!定义长度为MAX1的数组OJD
*DIM,JD,,MAX1!定义长度为MAX1的数组JD
*GET,NOD1,NODE,0,NUM,MIN	!获取力筋线上的最低节点编号并赋给参数NOD1
OJD(1)=NOD1	!将NOD1赋值给OJD数组的第一个值
*DO,I,2,MAX1
OJD(I)=NDNEXT(OJD(I-1))	!将力筋线的节点编号按升序依次赋给OJD数组
*ENDDO
ALLS	!全选
NSEL,ALL	!选择全部节点
CMSEL,U,CM1JNOD	!不选择属于力筋的节点
*DO,I,1,MAX1
NOD1=OJD(I)	!将力筋线的节点编号赋给NOD1
J=NNEAR(NOD1)	!返回最靠近力筋线节点的节点编号
JD(I)=J		!将所得的节点编号赋给数组JD
*ENDDO
NSEL,ALL	!选择全部节点
JI=1	
*DO,I,1,MAX1
CP,JI,UX,OJD(I),JD(I)	!耦合力筋线上的节点及与其最近节点的X方向的自由度
CP,JI+1,UY,OJD(I),JD(I) !耦合力筋线上的节点及与其最近节点的Y方向的自由度
CP,JI+2,UZ,OJD(I),JD(I) !耦合力筋线上的节点及与其最近节点的Z方向的自由度
JI=JI+3 
*ENDDO
CNVTOL,F,,,,-1	!设置力收敛准则
TIME,1		!设置时间
NSUBST,100,,,1	!设置100个载荷子步
AUTOTS,ON	!打开自动时间步长
LNSRCH,1	!打开线性搜索
NEQIT,50	!设置最大平衡迭代次数为50
PRED,ON		!打开非线性预测
NLGEOM,ON	!打开大变形效应
OUTPR,ALL,ALL	!设置打印输出选项
OUTRES,ALL,ALL	!输出所有结果
ALLS		!全选
SOLVE		!求解
FINI
/POST1
PLNSOL, U,X	!显示X方向位移
PATH,PATH,2	!定义路径
PPATH,1,1 !通过节点编号来定义路径 
PPATH,2,2 !通过节点编号来定义路径 
PDEF,STRESS_X,S,X,AVG	!将X方向的应力映射到路径上
PLPATH,STRESS_X 	!显示路径绘图结果