ex3-5.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

FINI
/CLE
!设置参数
/CONFIG,NRES,2000
*SET,LONG,40			!梁长度
*SET,NE,20			!单元数
*SET,DL,LONG/NE			!单元长度
*SET,NN,NE+1			!节点数
*SET,FF,5000			!移动的集中力
*SET,VV,80			!移动速度
*SET,DT,DL/VV*3.6		!移动经过一个单元所需时间
!定义单元材料实常数
/PREP7
ET,1,BEAM3			!梁单元
MP,EX,1,50E9			!弹性模量
MP,DENS,1,2500			!密度
MP,NUXY,1,0.2
R,1,0.5,0.041667,1		!几何常数
!建立模型
*DO,I,1,NN,1
N,I,(I-1)*DL			!建立
*ENDDO
*DO,I,1,NE
E,I,I+1
*ENDDO
FINI
!加载与求解
/SOL
D,1,ALL
D,NN,ALL
ANTYPE,4			!瞬态分析
TRNOPT,FULL
TIMINT,OFF
OUTRES,BASIC,ALL			!输出基本项，每一步都输出
KBC,1						!指定载荷类型
TIME,1E-10				!指定载荷步结束时间
NSUB,4,8					!指定载荷子步数为4，最大子步数为8
SSTIF,ON					!打开应力刚化效应
ACEL,0,9.8,0				!施加重力加速度
ALLS						!选中所有元素
SOLVE						!求解第一个载荷步
TIMINT,ON
*DO,II,1,NN,1
	OUTRES,ALL,ALL			!输出所有加载子步的所有结果
	TIME,II*DT			!每个荷载步的求解时间
	NSUBST,5			!每个荷载步包含五个子步
	FDELE,ALL,ALL			!删除所有的集中力荷载
	NSEL,S,LOC,X,(II-1)*DL	!选择集中力作用节点
	F,ALL,FY,-FF			!施加集中荷载
	ALLSEL			!选择所有
	SOLVE
*ENDDO
SAVE
FINI
/POST1
SET,NE/2+1,LAST			!设定读取的载荷步
/ESHAPE,1			!显示梁形状
PLNSOL,U,Y,0,1.0		!Y向位移
PLNSOL,S,EQV,0,1.0		!等效应力
FINI
/POST26
NSOL,2,NE/2+1,U,Y,UY_M       !取出梁中部节点Y方向的位移
XVAR,1                   !定义时间变量为坐标横轴
PLVAR,2                  !绘制位移随时间变化的图形
DERIV,3,2,1,,,,,1        !对梁中部节点的Y向位移进行微分运算，得到Y向速度
PLVAR,3                  !绘制速度随时间变化的图形
DERIV,4,3,1,,,,,1        !对梁中部节点的Y向速度进行微分运算，得到Y向加速度
PLVAR,4                  !绘制加速度随时间变化的图形