ex3-7.txt

《ANSYS工程分析进阶实例》-王呼佳-源代码 看文件吧.不多说了.

!参数设置
FINI
/CLE
/FILNAME,SOLID
*AFUN,DEG			!使用角度
*SET,LL,100			!梁长度
*SET,BB,6			!梁宽度
*SET,HH,6			!梁高度
*SET,NN,20			!划分份数
*SET,SP,1000			!分布载荷
!建立模型
/PREP7
ET,1,SOLID45
MP,EX,1,29E9
MP,NUXY,1,0.3
MP,DENS,1,2500
BLOCK,,LL,,BB,,HH
LESIZE,2,,,NN
LESIZE,1,,,2
LESIZE,9,,,2
VMESH,ALL
SAVE
FINI
!加载与求解
/SOLU
ANTYPE,0
NSEL,S,LOC,X,0
D,ALL,ALL
ALLS
ACEL,0,9.8,0
ASEL,S,LOC,Y,HH
SFA,ALL,1,PRES,SP
SOLVE
FINI
!后处理
/POST1
PLNSOL,S,EQV,0,1.0		!等效应力
!通过工作平面查看截面云图
WPAVE,LL/2			!移动工作平面至梁的中点
WPROTA,,,90			!旋转工作平面
/TYPE,1,1			!定义显示类型为截面
/CPLANE,1			!指定为工作平面切割截面
PLNSOL,S,X,0,1.0		!X向应力
!通过定义截面查看云图
!WPAVE,LL/2			!移动工作平面至梁的中点
!WPROTA,,,90			!旋转工作平面
!/CPLANE,1			!指定为工作平面切割截面
SUCR,MIDSEC,CPLANE		!截面名为MIDSEC
SUMAP,MIDPLOT,S,X		!显示物理量
SUPL,MIDSEC,MIDPLOT		!显示云图
!通过路径定义查看云图
N1=NODE(LL/2,0,0)		!定义节点
N2=NODE(LL/2,0,BB)		!定义节点
N3=NODE(LL/2,HH,BB)		!定义节点
N4=NODE(LL/2,HH,0)		!定义节点
N5=NODE(LL/2,0,0)		!定义节点
PATH,MID,5
PPATH,1,N1
PPATH,2,N2
PPATH,3,N3
PPATH,4,N4
PPATH,5,N5
PDEF,MPATH,S,X,AVG		!将应力映射至路径
/PBC,PATH,,1                         
/REPLOT				!显示路径
PLPATH,MPATH			!应力分布画图
PRPATH,MPATH			!屏幕输出接触应力。
PLPAGM,MPATH			!绘制云图