mtp_2.6.11.bb

These are the kernel patches against the 2.6.11_rc5 kernel from linux-mips.org for the AMD Alchemy

# MTP .bb build file
# Copyright (C) 2005, Advanced Micro Devices, Inc.  All Rights Reserved
# Released under the MIT license (see /COPYING)

DESCRIPTION="The Media Transfer Protocol (MTP) is a protocol specified by Microsoft (primarily) to allow synching of media files between a PC and a portable device"

PR = "r000040"
AMD_DRIVER_VERSION = "00.00.40"
AMD_DRIVER_LABEL = "Travis1.0_Linux2.6_MTP_${AMD_DRIVER_VERSION}"

KV = ${PV}

DEPENDS = "virtual/kernel sqlite3 amdms2"
RDEPENDS = "sqlite3"

DEPENDS_append_linux-uclibc = " libaio-oracle "
RDEPENDS_append_linux-uclibc = " libaio-oracle "

inherit kernel-arch

KERNEL_SOURCE="${STAGING_DIR}/${TARGET_SYS}/kernel"

SRC_URI="file://${TOPDIR}/files/mtp-1.0-src-${PV}-${PR}.tar.gz"

S="${WORKDIR}/${AMD_DRIVER_LABEL}"

PACKAGES="${PN}"
FILES_${PN} = "/usr/bin /Mtp /usr/lib"

#These are the default LDFLAGS minus the -Wl locations
#This is to workaround the error:
#mipsel-linux-ld: unrecognized option '-Wl,-rpath-link,/path/to/staging/mipsel-linux/lib'
export TARGET_LDFLAGS = "-L${STAGING_DIR}/${TARGET_SYS}/lib -L${S}"

#These are the default CFLAGS minus the STAGING include path.  
#This is to workaround the error:
#./../linux/mtpwin2linux.h:127:4: #error "Cannot define an Int64"
export TARGET_CFLAGS = "${SELECTED_OPTIMIZATION} -I${S}"
#Because this include path is now missing, we must copy in libaio-oracle.h
#for UCLIBC builds.
do_configure_append_linux-uclibc() {

	test -f ${STAGING_INCDIR}/libaio-oracle.h && install -m 0644 ${STAGING_INCDIR}/libaio-oracle.h ${S}/common/

}

EXTRA_OEMAKE=" TARGET_PREFIX=${TARGET_PREFIX} BUILD_MODE=release KERNEL_INCLUDE_DIR=${KERNEL_SOURCE}/include SQLITE_LIB_DIR=${STAGING_DIR}/${TARGET_SYS}/lib "

EXTRA_OEMAKE_append_linux-uclibc=" UCLIBCBUILD=yes"

do_configure () {
	cp ${STAGING_INCDIR}/secure_serial.h ${S}
	cp ${STAGING_INCDIR}/secure_serial_priv.h ${S}
	cp ${STAGING_LIBDIR}/libserialpriv* ${S}
}
	    
do_compile() {
	oe_runmake all 
}

do_install () {
	oe_runmake install DESTDIR=${D}
}