dx_todepot_add_new.asp

功能介绍： 1、产品入库

<!--#include file="../Inc/Config.asp"-->
<!--#include file="inc/Dx_admin_check.asp"-->
<%
if request.Form.Count>0 then
dx_product_class=request.Form("dx_product_class")		'分类
dx_product_brand=request.Form("dx_product_brand")		'品牌
dx_product_model=request.Form("dx_product_model")		'型号
dx_ToDepot_buy_count=request.Form("dx_ToDepot_buy_count")	'入库数量
dx_ToDepot_buy_price=request.Form("dx_ToDepot_buy_price")	'进价
dx_ToDepot_sell_price=request.Form("dx_ToDepot_sell_price")	'售价
dx_ToList_business=request.Form("dx_ToList_business")		'供应商
dx_product_depot=request.Form("dx_product_depot")			'仓库
dx_product_parameter=request.Form("dx_product_parameter")	'参数
dx_product_about=request.Form("dx_product_about")			'介绍
dx_product_user=request.Form("dx_product_user")				'经办人
dx_ToDepot_debt=request.Form("dx_ToDepot_debt_new")				'是否欠债

'================检查新商品入库的资金情况=========================
	dx_debt_money=0
'计算商品总价
	dx_debt_money=Cdbl(dx_debt_money)+Cdbl(dx_ToDepot_buy_count)*Cdbl(dx_ToDepot_buy_price)			
	
	sql="select * from [dx_site]"
	rs.open sql,conn,1,1
	dx_site_money=Cdbl(rs("dx_site_money"))
	rs.close
'比较	,资金不足则返回参数
	if dx_ToDepot_debt=0 then
		if Cdbl(dx_site_money)<Cdbl(dx_debt_money) then
			response.Write("2")
			response.End()
		end if
	end if


'===============开始入库==================
'新产品添加到商品列表
sql="select * from [dx_product]"
rs.open sql,conn,1,3
rs.addnew
	rs("dx_product_class")=dx_product_class
	rs("dx_product_brand")=dx_product_brand
	rs("dx_product_model")=dx_product_model
	rs("dx_product_parameter")=dx_product_parameter
	rs("dx_product_about")=dx_product_about
	rs("dx_product_depot")=dx_product_depot
	rs("dx_product_user")=dx_product_user
rs.update
rs.close
'读取商品ID
set rs=conn.execute("select MAX(dx_product_id) as product_id_max from [dx_product]")
dx_product_id=rs("product_id_max")			'新商品编号
rs.close
'添加入库单
sql="select * from [dx_ToList]"
rs.open sql,conn,1,3
rs.addnew
	rs("dx_ToList_business")=dx_ToList_business
	rs("dx_ToList_user")=dx_product_user
rs.update
rs.close
'读取入库单ID
set rs=conn.execute("select MAX(dx_ToList_id) as ToList_id_max from [dx_ToList]")
dx_ToList_id=rs("ToList_id_max")			'入库单编号
rs.close

'添加入库信息
sql="select * from [dx_ToDepot]"
rs.open sql,conn,1,3
rs.addnew
	rs("dx_ToDepot_list")=dx_ToList_id
	rs("dx_ToDepot_product")=dx_product_id
	rs("dx_ToDepot_buy_price")=dx_ToDepot_buy_price
	rs("dx_ToDepot_sell_price")=dx_ToDepot_sell_price
	rs("dx_ToDepot_buy_count")=dx_ToDepot_buy_count
	rs("dx_ToDepot_now_count")=dx_ToDepot_buy_count
	rs("dx_ToDepot_user")=dx_product_user
	rs("dx_ToDepot_debt")=dx_ToDepot_debt
rs.update
rs.close

'欠债或直接付款
if dx_ToDepot_debt<>0 then
	sql="select * from [dx_debt]"
	rs.open sql,conn,1,3
	rs.addnew
		rs("dx_debt_type")=0
		rs("dx_debt_TypeId")=dx_ToList_id
		rs("dx_debt_money")=dx_debt_money
		rs("dx_debt_user")=dx_product_user
	rs.update
	rs.close
else
	sql="select * from [dx_site]"
	rs.open sql,conn,1,3
	rs("dx_site_money")=Cdbl(rs("dx_site_money"))-Cdbl(dx_debt_money)
	rs.update
	rs.close
end if
'返回参数
response.Write("1")
end if
%>