dx_todepot_add.asp

功能介绍： 1、产品入库

<!--#include file="../Inc/Config.asp"-->
<!--#include file="inc/Dx_admin_check.asp"-->
<%	
if request.QueryString.Count>0 then	

'添加多条记录时使用	
	dx_ToDepot_product=request.QueryString("dx_ToDepot_product") 		'已有商品的编号
	dx_product_model=request.QueryString("dx_product_model") 			'商品型号
	dx_ToDepot_buy_count=request.QueryString("dx_ToDepot_buy_count")		'数量
	dx_ToDepot_buy_price=request.QueryString("dx_ToDepot_buy_price")		'进价
	dx_ToDepot_sell_price=request.QueryString("dx_ToDepot_sell_price")	'售价
	dx_product_depot=request.QueryString("dx_product_depot")				'仓库
'先注释,临时入库单
'	sql="select * from [dx_temp1]"
'	rs.open sql,conn,1,3
'	
'		rs.addnew
'		rs("dx_temp1_product")=dx_ToDepot_product
'		rs("dx_temp1_buy_price")=dx_ToDepot_buy_price
'		rs("dx_temp1_sell_price")=dx_ToDepot_sell_price
'		rs("dx_temp1_count")=dx_ToDepot_buy_count
'		rs.update
'
'	rs.close
	sql="select * from [dx_depot] order by dx_depot_id desc"
	rs.open sql,conn,1,1
	while not rs.eof
	if Cint(dx_product_depot)=rs("dx_depot_id") then	
		Qu="selected=""selected"""
	else
		Qu="" 
	end if
	Query=Query&"<option "&Qu&" value="&rs("dx_depot_id")&">"&rs("dx_depot_name")&"</option>"&vbCrlf
	rs.movenext
	wend
	rs.close
	
	
	response.Write("<div id='a"&dx_ToDepot_product&"'><input name='dx_ToDepot_product1' type='hidden' value='"&dx_ToDepot_product&"' /><input name='dx_product_model1' readonly='true' style='width:80px;' value='"&dx_product_model&"'>")&vbCrlf
	response.Write("数量:<input type='text' name='dx_ToDepot_buy_count1' style='width:30px' value='"&dx_ToDepot_buy_count&"'>")&vbCrlf
	response.Write("进价:<input type='text' name='dx_ToDepot_buy_price1' style='width:30px' value='"&dx_ToDepot_buy_price&"'>")	&vbCrlf
	response.Write("售价:<input type='text' name='dx_ToDepot_sell_price1' style='width:30px' value='"&dx_ToDepot_sell_price&"'>")&vbCrlf
	response.Write("仓库:<select name='dx_product_depot1'>")&vbCrlf

	response.Write(Query)
	response.Write("</select>")&vbCrlf
	response.Write("<span style='color:#FF0000; font-weight:bold; cursor:hand;' onclick=""a"&dx_ToDepot_product&".innerHTML=''; a"&dx_ToDepot_product&".style.display='none';"">×</span></div>")&vbCrlf
	
elseif request.Form.Count>0 then


	dx_product_depot=request.Form("dx_product_depot")				'仓库
	dx_ToList_business=request.Form("dx_ToList_business")			'进货商
	dx_ToList_user=request.Form("dx_ToList_user")					'经办人
	
	dx_ToDepot_product=request.Form("dx_ToDepot_product") 			'已有商品的编号
	dx_product_model=request.Form("dx_product_model") 				'商品型号
	dx_ToDepot_buy_count=request.Form("dx_ToDepot_buy_count")		'数量
	dx_ToDepot_buy_price=request.Form("dx_ToDepot_buy_price")		'进价
	dx_ToDepot_sell_price=request.Form("dx_ToDepot_sell_price")		'售价
	dx_ToDepot_debt=request.Form("dx_ToDepot_debt")					'是否欠债	
		
	dx_ToDepot_product1=request.Form("dx_ToDepot_product1")			'已有商品的编号
	
	dx_ToDepot_product1=split(dx_ToDepot_product1)
'=================统计入库所需的资金=======================

	dx_debt_money=0
	
	for i = 1 to Ubound(dx_ToDepot_product1)+1	
	dx_ToDepot_buy_count1=request.Form("dx_ToDepot_buy_count1")(i)		'数量
	dx_ToDepot_buy_price1=request.Form("dx_ToDepot_buy_price1")(i)		'进价
	dx_debt_money=Cdbl(dx_debt_money)+Cdbl(dx_ToDepot_buy_count1)*Cdbl(dx_ToDepot_buy_price1)
	next

	dx_debt_money=Cdbl(dx_debt_money)+Cdbl(dx_ToDepot_buy_count)*Cdbl(dx_ToDepot_buy_price)
'=================如果直接付款,就和现有资金比较==============
	sql="select * from [dx_site]"
	rs.open sql,conn,1,3
	dx_site_money=Cdbl(rs("dx_site_money"))
	rs.close
	
	if dx_ToDepot_debt=0 then
		if Cdbl(dx_site_money)<Cdbl(dx_debt_money) then
			response.Write("2")
			response.End()
		end if
	end if


'=====================如果资金充足,就开始添加数据===========================
'入库单		
	sql="select * from [dx_ToList]"
	rs.open sql,conn,1,3
	rs.addnew
	rs("dx_ToList_business")=dx_ToList_business
	rs("dx_ToList_user")=dx_ToList_user
	rs.update
	rs.close
'读取入库单编号
	set rs=conn.execute("select Max(dx_ToList_id) as max_id from [dx_ToList]")
	dx_ToDepot_list=rs("max_id")
	rs.close

'多个商品添加
	for i = 1 to Ubound(dx_ToDepot_product1)+1
	
	dx_product_model1=request.Form("dx_product_model1")(i) 				'商品型号
	dx_ToDepot_buy_count1=request.Form("dx_ToDepot_buy_count1")(i)		'数量
	dx_ToDepot_buy_price1=request.Form("dx_ToDepot_buy_price1")(i)		'进价
	dx_ToDepot_sell_price1=request.Form("dx_ToDepot_sell_price1")(i)	'售价
	dx_product_depot1=request.Form("dx_product_depot1")(i)
	sql="select * from [dx_ToDepot]"
	rs.open sql,conn,1,3
	rs.addnew
	rs("dx_ToDepot_list")=dx_ToDepot_list
	rs("dx_ToDepot_product")=dx_ToDepot_product1(i-1)
	rs("dx_ToDepot_buy_price")=dx_ToDepot_buy_price1
	rs("dx_ToDepot_sell_price")=dx_ToDepot_sell_price1
	rs("dx_ToDepot_buy_count")=dx_ToDepot_buy_count1
	rs("dx_ToDepot_now_count")=dx_ToDepot_buy_count1
	rs("dx_ToDepot_user")=dx_ToList_user
	rs("dx_ToDepot_debt")=dx_ToDepot_debt
	rs.update
	rs.close
	next

'单个商品添加,多个商品添加是最后一台记录执行下面
	sql="select * from [dx_ToDepot]"
	rs.open sql,conn,1,3
	rs.addnew
	rs("dx_ToDepot_list")=dx_ToDepot_list
	rs("dx_ToDepot_product")=dx_ToDepot_product
	rs("dx_ToDepot_buy_price")=dx_ToDepot_buy_price
	rs("dx_ToDepot_sell_price")=dx_ToDepot_sell_price
	rs("dx_ToDepot_buy_count")=dx_ToDepot_buy_count
	rs("dx_ToDepot_now_count")=dx_ToDepot_buy_count
	rs("dx_ToDepot_user")=dx_ToList_user	
	rs("dx_ToDepot_debt")=dx_ToDepot_debt
	rs.update
	rs.close
	
'欠债或直接付款
	if dx_ToDepot_debt<>0 then				'如欠债
		sql="select * from [dx_debt]"
		rs.open sql,conn,1,3
		rs.addnew
			rs("dx_debt_type")=0
			rs("dx_debt_TypeId")=dx_ToDepot_list
			rs("dx_debt_money")=dx_debt_money
			rs("dx_debt_user")=dx_ToList_user
		rs.update
		rs.close
	else									'从资金里扣钱
		sql="select * from [dx_site]"
		rs.open sql,conn,1,3
		rs("dx_site_money")=Cdbl(rs("dx_site_money"))-Cdbl(dx_debt_money)
		rs.update
		rs.close
	end if
	
'返回参数
	response.Write("1")
end if
%>