menu.asp

来自「《SQL Server 2000课程设计案例精编》-李昆-源代码-3436」· ASP 代码 · 共 63 行

ASP

63 行

	<!--#include file="Include/ADOdata.asp" -->

<%
'产生menu资料
Dim strQry
Dim conDB
Dim cmdCategories
Dim strmQuery
Dim strmResult

'范本中的根元素以及namespace
Const XML_HEADER = "<categorylist xmlns:sql='urn:schemas-microsoft-com:xml-sql'>"
Const XML_FOOTER = "</categorylist>"


'范本中的查询内容
strQry = XML_HEADER
strQry = strQry & "<sql:query>"
strQry = strQry & "SELECT CategoryID, CategoryName FROM Categories"
strQry = strQry & " FOR XML AUTO, elements"
strQry = strQry & "</sql:query>"
strQry = strQry & XML_FOOTER

'数据库连接与command对象设置
Set conDB = CreateObject("ADODB.Connection")
conDB.ConnectionString = strCon
conDB.Open
Set cmdCategories = CreateObject("ADODB.Command")
Set cmdCategories.ActiveConnection = conDB

'产生Query stream
Set strmQuery = CreateObject("ADODB.Stream")
strmQuery.Open
strmQuery.WriteText strQry, adWriteChar
strmQuery.Position = 0
Set cmdCategories.CommandStream = strmQuery

'指定style sheet
cmdCategories.Properties("XSL") = Server.MapPath("AppFiles\menu.xsl")

'产生result stream
Set strmResult = CreateObject("ADODB.Stream")
'strmResult.Charset="big5"
strmResult.Open
cmdCategories.Properties("Output Stream") = strmResult

'执行query
cmdCategories.Execute , , adExecuteStream

Response.Write strmResult.ReadText
Set strmResult = Nothing
Set strmQuery = Nothing
Set cmdCategories = Nothing
Set conDB = Nothing

%>


<head>
<base target="Products">
</head>

menu.asp - 源码说明

本页面展示了「《SQL Server 2000课程设计案例精编》-李昆-源代码-3436」中的 menu.asp 源码文件，采用 ASP 编程语言编写，共 63 行代码。您可以在线阅读完整代码内容，也可以返回资源详情页下载完整源码包进行本地学习和开发。

虫虫开发者社区收录了大量与SQL Server相关的技术资源，包括源代码、技术文档、电路图等，是电子工程师和嵌入式开发者的专业学习平台。

⌨️ 快捷键说明

复制代码Ctrl + C

搜索代码Ctrl + F

全屏模式F11

增大字号Ctrl + =

减小字号Ctrl + -

显示快捷键?