basket.asp

来自「《SQL Server 2000课程设计案例精编》-李昆-源代码-3436」· ASP 代码 · 共 73 行

	<!--#include file="Include/ADOdata.asp" -->

<%
'*  Written by Microsoft Corporation
'*  Copyright (C) 2001 Microsoft Corporation. All rights reserved.
'*


Dim strUser
Dim objShopping

'Check for authentication cookie
strUser = Request.Cookies("userauthid")
If struser = "" Then
  server.transfer "Login.htm"
End If

Response.Write ViewBasket(strUser)

Function ViewBasket(strCustomer)
'Method to view the contents of the shopping basket as HTML
Dim cmdBasket
Dim strmQuery 
Dim strmResult
Dim strQry
Dim conDB

'Root element and namespace for XML query
Const XML_HEADER = "<basketcontents xmlns:sql='urn:schemas-microsoft-com:xml-sql'>"
Const XML_FOOTER = "</basketcontents>"


'Define query string
strQry = XML_HEADER
strQry = strQry & "<sql:query>"
strQry = strQry & "SELECT * FROM BasketView WHERE Customer = '" & strCustomer & "'"
strQry = strQry & " FOR XML AUTO, elements"
strQry = strQry & "</sql:query>"
strQry = strQry & XML_FOOTER

'Connect to database and configure command object
Set conDB = CreateObject("ADODB.Connection")
conDB.ConnectionString = strCon
conDB.Open
Set cmdBasket = CreateObject("ADODB.Command")
Set cmdBasket.ActiveConnection = conDB

'Create Query stream for the inbound XML query
Set strmQuery = CreateObject("ADODB.Stream")
strmQuery.Open
strmQuery.WriteText strQry, adWriteChar
strmQuery.Position = 0
Set cmdBasket.CommandStream = strmQuery

'Specify the style sheet to be used to transform the results to HTML
cmdBasket.Properties("XSL") = Server.MapPath("AppFiles\basket.xsl")

'Create result stream for the query results
Set strmResult = CreateObject("ADODB.Stream")
strmResult.Open
cmdBasket.Properties("Output Stream") = strmResult

'Execute query
cmdBasket.Execute , , adExecuteStream

ViewBasket = strmResult.ReadText
Set strmResult = Nothing
Set strmQuery = Nothing
Set cmdOrders = Nothing
Set conDB = Nothing

End Function
%>