product.asp

《SQL Server 2000课程设计案例精编》-李昆-源代码-3436

	<!--#include file="Include/ADOdata.asp" -->

<%

Dim objXML


'呼叫RenderProduct function,返回product ID
Response.Write RenderProduct(Request.QueryString("ProductID"))

Function RenderProduct(intProductID)
'使用范本查询并返回HTML格式资料
Dim cmdProduct
Dim strmQuery
Dim strmResult
Dim strQry
Dim conDB

'范本中的根元素以及namespace
Const XML_HEADER = "<productdetails xmlns:sql='urn:schemas-microsoft-com:xml-sql'>"
Const XML_FOOTER = "</productdetails>"

'范本中的查询内容
strQry = XML_HEADER
strQry = strQry & "<sql:query>"
strQry = strQry & "SELECT * FROM products WHERE ProductID = " & intProductID
strQry = strQry & " FOR XML AUTO, elements"
strQry = strQry & "</sql:query>"
strQry = strQry & XML_FOOTER

'数据库连接与command对象设置
Set conDB = CreateObject("ADODB.Connection")
conDB.ConnectionString = strCon
conDB.Open
Set cmdProduct = CreateObject("ADODB.Command")
Set cmdProduct.ActiveConnection = conDB

'产生Query stream
Set strmQuery = CreateObject("ADODB.Stream")
strmQuery.Open
strmQuery.WriteText strQry, adWriteChar
strmQuery.Position = 0
Set cmdProduct.CommandStream = strmQuery

'指定style sheet
cmdProduct.Properties("XSL") = Server.MapPath("AppFiles\productdetails.xsl")

'产生result stream
Set strmResult = CreateObject("ADODB.Stream")
strmResult.Open
cmdProduct.Properties("Output Stream") = strmResult

'执行query
cmdProduct.Execute , , adExecuteStream

RenderProduct = strmResult.ReadText
Set strmResult = Nothing
Set strmQuery = Nothing
Set cmdProduct = Nothing
Set conDB = Nothing
End Function

%>