catalogimport.vbs

《SQL Server 2000课程设计案例精编》-李昆-源代码-3436

'**************主程序**********************************************************

	Dim AppPath
	Dim strCatalog

	AppPath = GetAppPath

	strCatalog = DownloadCatalog

	WriteFile strCatalog, AppPath & "\Catalog.xml"

	LoadCatalog AppPath & "\catalog.xml", AppPath & "\CatalogSchema.xml", AppPath & "\LoadErrors.log"

	msgBox "产品类别已导入!", 0, "数据已经完成导入"


'------------- 取得现在目录路径--------------------------------------------------
Function GetAppPath()

	Dim strScriptPath
	Dim strScriptName

	strScriptPath=WScript.ScriptFullName
	strScriptName=WScript.ScriptName
	GetAppPath = Left(strScriptPath, Len(strScriptPath)-Len(strScriptName))

End Function


'------------ 使用范例与注释schema捕获产品类别------------------------------------
Function DownloadCatalog()

	Dim objHTTP
	Dim strXML

	Set objHTTP = CreateObject("Microsoft.XMLHTTP")
	objHTTP.Open "GET", "http://localhost/supplierExtranetXML/Schemas/CatalogSchema.xml/Catalog/Category?root=Catalog", False
	objHTTP.Send
	strXML = objHTTP.responseText
	strXML = Replace(strXML, "encoding=""utf-8""", "encoding=""gb2312""") '删除不需要的编码与属性
	DownloadCatalog= strXML
	Set objHTTP = Nothing

End Function


'----------- 写入文件 ----------------------------------------------------------
Sub WriteFile(strData, strFileName)

	Dim FSO
	Dim TxtStrm

	Set FSO = CreateObject("Scripting.FileSystemObject")
	Set TxtStrm = FSO.CreateTextFile (strFileName, True)
	TxtStrm.Write strData
	TxtStrm.Close

End Sub


'-----------导入产品类别xml到Retailer数据库----------------------------------------

Sub LoadCatalog(strXMLFile, strSchemaFile, strErrLog)

	Dim objBL

	Set objBL = CreateObject("SQLXMLBulkLoad.SQLXMLBulkLoad")
	objBL.ConnectionString = "provider=SQLOLEDB.1;data source=localhost;database=Retailer;Integrated Security=SSPI;"
	objBL.ErrorLogFile = strErrLog

	objBL.CheckConstraints=true
	objBL.SchemaGen = True
	objBL.SGDropTables = True

	objBL.Execute strSchemaFile, strXMLFile
	Set objBL = Nothing

End Sub