cboss2.cls

Visual Basic 6 大学教程的代码

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CBoss2"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
' CBoss2 definition
Option Explicit
Implements IEmployee2

Private mEmployee As IEmployee2
Private mWeeklySalary As Currency

Private Sub Class_Initialize()
   Set mEmployee = New IEmployee2
End Sub

Public Property Let WeeklySalary(ByVal w As Currency)
   mWeeklySalary = IIf(w > 0, w, 0)
End Property

Public Property Get WeeklySalary() As Currency
   WeeklySalary = mWeeklySalary
End Property

Private Function IEmployee2_Earnings() As Double
   IEmployee2_Earnings = mWeeklySalary
End Function

Private Property Let IEmployee2_FirstName(ByVal fName _
                                          As String)
   mEmployee.FirstName = fName
End Property

Private Property Get IEmployee2_FirstName() As String
   IEmployee2_FirstName = mEmployee.FirstName
End Property

Private Property Let IEmployee2_LastName(ByVal name As String)
   mEmployee.LastName = name
End Property

Private Property Get IEmployee2_LastName() As String
   IEmployee2_LastName = mEmployee.LastName
End Property

Private Function IEmployee2_ToString() As String
   IEmployee2_ToString = "Boss: " & mEmployee.FirstName & " " & _
                         mEmployee.LastName
End Function

Private Sub Class_Terminate()
   Set mEmployee = Nothing
End Sub