chourlyworker.cls

Visual Basic 6 大学教程的代码

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CHourlyWorker"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
' CHourlyWorker definition
Option Explicit
Implements IEmployee

Private mFirstName As String
Private mLastName As String
Private mWage As Currency
Private mHours As Integer
Private Const mHoursInAWeek As Integer = 168

Public Property Let FirstName(ByVal fName As String)
   mFirstName = fName
End Property

Public Property Get FirstName() As String
   FirstName = mFirstName
End Property

Public Property Let LastName(ByVal name As String)
   mLastName = name
End Property

Public Property Get LastName() As String
   LastName = mLastName
End Property

Public Property Let Wage(ByVal wg As Currency)
   mWage = IIf(wg > 0, wg, 0)
End Property

Public Property Get Wage() As Currency
   Wage = mWage
End Property

Public Property Let Hours(ByVal hrs As Integer)
   mHours = IIf((hrs >= 0 And hrs < mHoursInAWeek), hrs, 0)
End Property

Public Property Get Hours() As Integer
   Hours = mHours
End Property

Private Function IEmployee_Earnings() As Double

   If mHours > 40 Then
      Dim otHours As Integer
      
      otHours = mHours - 40
      IEmployee_Earnings = otHours * 1.5 * mWage + mWage * 40
   Else
      IEmployee_Earnings = mWage * mHours
   End If
   
End Function

Private Function IEmployee_ToString() As String
   IEmployee_ToString = "Hourly worker: " & mFirstName & " " & _
                        mLastName
End Function