📄 mybox.asm
字号:
;************************************************************************
.386
.model flat, stdcall
option casemap : none
;************************************************************************
include windows.inc
include user32.inc
include kernel32.inc
include gdi32.inc
include Comctl32.inc
includelib user32.lib
includelib kernel32.lib
includelib gdi32.lib
includelib Comctl32.lib
include StoreHouse.inc ; 导入关卡地图数据
;************************************************************************
; 宏定义数据
;------------------------------------------------------------------------
ICO_MAIN equ 1000h ; 窗口图标ID
ICO_MSG equ 1001h
IDM_CUR equ 1000h ; 窗口光标ID
IDM_MAIN equ 1000h ; 菜单ID
IDM_REFLUSH equ 1001h
IDM_PREV equ 1002h
IDM_NEXT equ 1003h
IDM_ABOUT equ 1004h
IDM_EXIT equ 1005h
ID_TOOLBAR equ 1 ; 工具栏ID
IDM_TOOLBAR equ 2000h ; 工具栏图标位图ID
ID_STATUSBAR equ 2 ; 状态栏ID
DLG_MAIN equ 3 ; 消息对话框ID
BM_MAIN equ 3000h ; 背景位图资源ID
ID_GAMETIMER equ 100 ; 关卡计时器
ID_SHOWBOMB equ 101 ; 刷新炸弹计时器
xBmBack equ 0d
xBmWall equ 30d
xBmRoad equ 60d
xBmBox1 equ 90d
xBmBox2 equ 120d
xBmObject equ 150d
xBmMan equ 180d
xBmBomb equ 210d
VK_B equ 42h ; 字母"B"的扫描码
BackStep equ 20d ; 后退的次数
;************************************************************************
; 数据段
;------------------------------------------------------------------------
.const
szClassName db 'Game', 0
szCaption db '推箱子', 0
dwStatusWidth dd 80, 160, 255, -1
NUM_BUTTONS equ 6 ;工具栏图标位图中包含的小图标个数
stToolbar equ this byte
TBBUTTON <0, IDM_REFLUSH, TBSTATE_ENABLED, TBSTYLE_BUTTON, 0, 0, -1>
TBBUTTON <1, IDM_PREV, TBSTATE_ENABLED, TBSTYLE_BUTTON, 0, 0, -1>
TBBUTTON <2, IDM_NEXT, TBSTATE_ENABLED, TBSTYLE_BUTTON, 0, 0, -1>
TBBUTTON <3, IDM_ABOUT, TBSTATE_ENABLED, TBSTYLE_BUTTON, 0, 0, -1>
TBBUTTON <0, 0, TBSTATE_ENABLED, TBSTYLE_SEP, 0, 0, -1>
TBBUTTON <4, IDM_EXIT, TBSTATE_ENABLED, TBSTYLE_BUTTON, 0, 0, -1>
;------------------------------------------------------------------------
.data
szOutOfRange db '已超出游戏关卡范围！', 0
szSuccessMsg db '您成功通过了关卡！是否继续？', 0
szGameOver db '已到达最后一关', 0
FmtGate db '—第%d关', 0
szBomb db '炸弹数量 : 1', 0
szNoBomb db '炸弹数量 : 0', 0
szStep db '移动次数 : %d', 0
szGameTime db ' %02d:%02d:%02d', 0
;------------------------------------------------------------------------
.data?
hInstance dd ? ; 实例句柄
hWinMain dd ? ; 主窗口句柄
hMenu dd ? ; 菜单句柄
hWinToolbar dd ? ; 工具栏句柄
hWinStatus dd ? ; 状态栏句柄
hBackDC dd ? ; 背景位图设备环境句柄
hBitmap dd ? ; 背景位图句柄
LocalTime dd ? ; 当前系统时间的秒数
TimeCircle dd ? ; 时间循环周期的秒数: 24 * 3600 * n
TimeFlag dd ? ; 计时标志位，1表示进行及时；0表示停止计时
GameHour dd ?
GameMinute dd ?
GameSecond dd ?
Map db 14d * 12d dup (?) ; 存放当前关卡的地图数据
ObjectLeft dd ? ; 剩余的目标地点数量
ManXPos dd ? ; 角色的列坐标
ManYPos dd ? ; 角色的行坐标
BombXPos dd ? ; 炸弹的列坐标
BombYPos dd ? ; 炸弹的行坐标
CurrentGate dd ? ; 当前的关卡号
BombCount dd ? ; 炸弹的剩余数量，初始化时为1
BombFlag dd ? ; 炸弹的存在标志，1表示存在，0表示隐藏
StepNumber dd ? ; 玩家移动次数
dwCount dd ? ; 随机数
BackBuffer dd 8 * BackStep dup (?) ; 回退坐标缓冲区
BackLength dd ? ; 当前可回退的次数
;************************************************************************
;************************************************************************
; 代码段
;------------------------------------------------------------------------
.code
;************************************************************************
_Quit proc
invoke DestroyWindow, hWinMain
invoke PostQuitMessage, NULL
ret
_Quit endp
;************************************************************************
;************************************************************************
; 加载位图资源
;------------------------------------------------------------------------
_LoadRes proc
local @hDC ; 参考句柄
invoke GetDC, hWinMain
mov @hDC, eax
invoke CreateCompatibleDC, @hDC
mov hBackDC, eax
invoke LoadBitmap, hInstance, BM_MAIN
mov hBitmap, eax
invoke ReleaseDC, hWinMain, @hDC
invoke SelectObject, hBackDC, hBitmap
ret
_LoadRes endp
;************************************************************************
;************************************************************************
; 释放资源
;------------------------------------------------------------------------
_FreeRes proc
invoke DeleteDC, hBackDC
invoke DeleteObject, hBitmap
invoke KillTimer, hWinMain, ID_GAMETIMER
; invoke KillTimer, hWinMain, ID_SHOWBOMB
ret
_FreeRes endp
;************************************************************************
;************************************************************************
; 设置当前系统时间
;------------------------------------------------------------------------
_SetLocalTime proc uses ebx
local @Hour, @Minute, @Second
local @stST:SYSTEMTIME
invoke GetLocalTime, addr @stST
movzx eax, @stST.wHour
mov @Hour, eax
movzx eax, @stST.wMinute
mov @Minute, eax
movzx eax, @stST.wSecond
mov @Second, eax
mov eax, @Hour
mov ebx, 60d
mul ebx
add eax, @Minute
mul ebx
add eax, @Second
mov LocalTime, eax
mov eax, 1
mov TimeFlag, eax ; 允许及时
ret
_SetLocalTime endp
;************************************************************************
;************************************************************************
; 在状态栏中显示游戏中当前关卡的运行时间
;------------------------------------------------------------------------
_SetGameTime proc
local @Hour, @Minute, @Second
local @stST:SYSTEMTIME
pushad
.if TimeFlag == 1
invoke GetLocalTime, addr @stST
movzx eax, @stST.wHour
mov @Hour, eax
movzx eax, @stST.wMinute
mov @Minute, eax
movzx eax, @stST.wSecond
mov @Second, eax
mov eax, @Hour
mov ebx, 60d
mul ebx
add eax, @Minute
mul ebx
add eax, @Second
mov ecx, eax
.if ( ecx == LocalTime && !TimeCircle )
inc eax
.elseif ( ecx < LocalTime || ( ecx == LocalTime && TimeCircle > 0 ) )
mov ecx, 86400d
sub ecx, LocalTime
add TimeCircle, ecx
push eax
invoke _SetLocalTime
pop eax
.endif
add eax, TimeCircle
sub eax, LocalTime
mov edx, 0
mov ebx, 3600d
div ebx
mov GameHour, eax
mov eax, edx
mov edx, 0
mov ebx, 60d
div ebx
mov GameMinute, eax
mov GameSecond, edx
.endif
popad
ret
_SetGameTime endp
;************************************************************************
;************************************************************************
; 使窗口客户区无效，使Windows向窗口过程发送WM_PAINT消息
;------------------------------------------------------------------------
_Repaint proc
local @rect:RECT
invoke GetClientRect, hWinMain, addr @rect
invoke InvalidateRect, hWinMain, addr @rect, 0
ret
_Repaint endp
;************************************************************************
;************************************************************************
; Pos = y * 14 + x, 其中( x, y )以0为起始坐标
; eax中存储着( x, y )在Map中的线性逻辑地址
; edx中存储着( x, y )在Map中线性逻辑地址对应的位图索引值相应的位图起始X坐标
;------------------------------------------------------------------------
_SearchMapLinePos proc uses ebx esi, x, y
mov esi, offset Map
mov eax, y
mov ebx, 14d
mul ebx
add eax, x
mov bl, [esi][eax]
.if bl == MAP_BACK
mov edx, xBmBack
.elseif bl == MAP_WALL
mov edx, xBmWall
.elseif bl == MAP_ROAD
mov edx, xBmRoad
.elseif bl == MAP_BOX1
mov edx, xBmBox1
.elseif bl == MAP_BOX2
mov edx, xBmBox2
.elseif bl == MAP_OBJECT
mov edx, xBmObject
.elseif bl == MAP_MAN
mov edx, xBmMan
.else
mov edx, xBmBomb
.endif
ret
_SearchMapLinePos endp
;************************************************************************
;************************************************************************
; 将"BitMapXPosition"打印到起始点为( xPosition, yPosition )的客户区中
;------------------------------------------------------------------------
_PaintOneBitmap proc xPosition, yPosition, BitmapXPosition, @hDC
local x, y
pushad
mov eax, xPosition ; xPosition为在Map中的列号
mov ebx, 30d
mul ebx
mov x, eax
mov eax, yPosition ; yPosition为在Map中的行号
mov ebx, 30d
mul ebx
add eax, 30d ; 因为工具栏亦画到客户区中，因此要画到客户区以下
mov y, eax
.if @hDC == 0
invoke GetDC, hWinMain
mov @hDC, eax
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, BitmapXPosition, 0, SRCCOPY
invoke ReleaseDC, hWinMain, @hDC
.else
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, BitmapXPosition, 0, SRCCOPY
.endif
popad
ret
_PaintOneBitmap endp
;************************************************************************
;************************************************************************
; 重新绘制客户区
;------------------------------------------------------------------------
_WMPaint proc @hDC
local i, j, x, y
mov x, 0
mov y, 30d
mov i, 1
mov j, 1
mov esi, offset Map
;--------------------------------------------------------------------------
;按照StoreHouse中相应的位图索引将BackBitMap中的位图像素复制到窗口的设备环境中
;--------------------------------------------------------------------------
@@NextRol:
mov x, 0
mov j, 1
@@NextCol:
;---Calc nPos, nPos = (i-1) * 14 + (j-1)
mov eax, i
dec eax
mov ebx, 14d
mul ebx
add eax, j
dec eax
mov al, [esi][eax]
.if al == MAP_BACK
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmBack, 0, SRCCOPY
.elseif al == MAP_WALL
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmWall, 0, SRCCOPY
.elseif al == MAP_ROAD
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmRoad, 0, SRCCOPY
.elseif al == MAP_BOX1
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmBox1, 0, SRCCOPY
.elseif al == MAP_BOX2
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmBox2, 0, SRCCOPY
.elseif al == MAP_OBJECT
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmObject, 0, SRCCOPY
.else
invoke BitBlt, @hDC, x, y, 30, 30, hBackDC, xBmMan, 0, SRCCOPY
.endif
add x, 30d
inc j
cmp j, 15d
jb @@NextCol
inc i
add y, 30d
cmp i, 13
jb @@NextRol
;------------------------------------------------------------------------
; 按照man在Map中的坐标，将他对应的像素复制到相应位置
;------------------------------------------------------------------------
invoke _PaintOneBitmap, ManXPos, ManYPos, xBmMan, @hDC
ret
_WMPaint endp
;************************************************************************
;************************************************************************
; 选择参数@Gate指定的关卡
;------------------------------------------------------------------------
_SelectGate proc @Gate
local szTmp1[10] : byte
local szTmp2[20] : byte
mov eax, @Gate
.if ( eax > MAX_GATES || eax < 1 )
xor eax, eax
mov TimeFlag, eax
invoke MessageBox, hWinMain, addr szOutOfRange, \
addr szCaption, MB_ICONINFORMATION or MB_OKCANCEL
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -