dsdec.asm

PIC单片机的汇编源码合集,应用比较广泛,设计程序时可做子程序来用

;********************DSDEC********************
;本程序实现对双字节有符号数据块进行降序排列。
;入口参数：数据块首址在SADR中,数据个数在W中。
;出口参数：排好序的数据仍在原数据块中。
;占用资源：W,STATUS,FSR,020H,023H,028H,029H,02AH,02BH,一重堆栈。

           IFNDEF       DSDEC1
            #DEFINE     DSDEC1

DSDEC       MOVWF       TEMP3       ;TEMP3暂存内循环计数值
            DECF        TEMP3,F     ;数据个数减1是比较次数
LOOP77      MOVF        TEMP3,W
            MOVWF       CNT         ;循环计数器减1
            BCF         TEMP1,0     ;TEMP1:0作为交换标志位
            MOVF        SADR,W
            MOVWF       FSR
            INCF        FSR,F
LOOP76      MOVF        INDF,W
            INCF        FSR,F
            INCF        FSR,F
            XORWF       INDF,W
            MOVWF       TEMP4       ;TEMP4:7存放符号异同标志
            XORWF       INDF,W      ;恢复W
            BTFSC       TEMP4,7
            GOTO        DIFF3       
            SUBWF       INDF,W
            BTFSS       STATUS,C
            GOTO        NEXT41
            BTFSS       STATUS,Z
            GOTO        NEXT40
            MOVLW       3
            SUBWF       FSR,F
            MOVF        INDF,W
            INCF        FSR,F
            INCF        FSR,F
            SUBWF       INDF,W
            INCF        FSR,F
            BTFSC       STATUS,C
            GOTO        SWLOW3
            GOTO        NEXT41
NEXT40      SUBWF       INDF,W
SWITCH3     MOVWF       TEMP2       ;TEMP2暂存将要交换的数
            MOVF        INDF,W
            DECF        FSR,F
            DECF        FSR,F
            MOVWF       INDF
            MOVF        TEMP2,W
            INCF        FSR,F
            INCF        FSR,F
            MOVWF       INDF
SWLOW3      MOVLW       3
            SUBWF       FSR,F
            MOVF        INDF,W
            MOVWF       TEMP2
            INCF        FSR,F
            INCF        FSR,F
            MOVF        INDF,W
            DECF        FSR,F
            DECF        FSR,F
            MOVWF       INDF
            INCF        FSR,F
            INCF        FSR,F
            MOVF        TEMP2,W
            MOVWF       INDF        ;完成交换
            INCF        FSR,F
            BSF         TEMP1,0     ;置交换标志
NEXT41      DECFSZ      CNT,F
            GOTO        LOOP76
            BTFSS       TEMP1,0
            RETLW       0
            DECFSZ      TEMP3,F
            GOTO        LOOP77
            RETLW       0
DIFF3       BTFSS       INDF,7
            GOTO        SWITCH3
            GOTO        NEXT41
           ENDIF