csr1335.asm

PIC单片机的汇编源码合集,应用比较广泛,设计程序时可做子程序来用

;********************CSR1335********************
;本程序实现液晶显示控制器SED1335块状光标的显示。
;入口参数：光标左上角的X坐标在SOU中，Y坐标在SOUH中。
;出口参数：无。
;占用资源：W,STATUS,RB0~RB2,RC,023H,024H,025H,028H,029H,二重堆栈。
;说    明：1.显示屏为320*240点阵。
;          2.光标的Y坐标以象素点为单位，X坐标以8象素点为单位。
;          3.与光标重合的汉字将反色显示,光标闪动。
           
           IFNDEF       CSR13351
            #DEFINE     CSR13351
                     
WWR         EQU         0
RRD         EQU         1
A0          EQU         2
                 
            INCLUDE     "INIT1335.ASM"
             
;***********显示块状光标************
SEND2       MOVLW       46H         ;CSRW
            CALL        CMDIN
            MOVF        SOU,W
            CALL        DATAIN
            MOVF        SOUH,W
            CALL        DATAIN     

            MOVLW       .16
            MOVWF       CNT
            MOVLW       42H         ;MWRITE
            CALL        CMDIN
LOOP101     MOVLW       0FFH                  
            CALL        DATAIN
            DECFSZ      CNT,F  
            GOTO        LOOP101
            RETURN            
;*************第一个字***********
CSR1335     MOVLW       5BH         ;OYLAY（合成方式）
            CALL        CMDIN
            MOVLW       05H         ;P（1区与2区异或显示）
            CALL        DATAIN

            MOVLW       59H         ;DISP ON
            CALL        CMDIN
            MOVLW       64H         ;2区闪烁
            CALL        DATAIN

            MOVLW       01001111B   ;CSRDIR
            CALL        CMDIN       ;设置光标移动方向为纵向

            CLRF        TEMP1       ;TEMP1暂存移出位
            BCF         STATUS,C
            RLF         SOUH,F
            RLF         TEMP1,F
            RLF         SOUH,F
            RLF         TEMP1,F
            RLF         SOUH,F
            RLF         TEMP1,F
            RLF         SOUH,F
            RLF         TEMP1,F
            MOVF        TEMP1,W
            MOVWF       TEMP2
            MOVF        SOUH,W
            RLF         SOUH,F
            RLF         TEMP1,F
            ADDWF       SOUH,W
            BTFSC       STATUS,C
            INCF        TEMP1,F     ;TEMP1:SOUH=SOUH*48
            ADDWF       SOU,F
            BTFSC       STATUS,C
            INCF        TEMP1,F
            MOVF        TEMP2,W
            ADDWF       TEMP1,W           
            ADDLW       50H
            MOVWF       SOUH        ;SOUH:SOU=5000H+(SOUH*48+SOU)
            CALL        SEND2
            INCF        SOU,F
            CALL        SEND2
            RETURN
           ENDIF