ssdec.asm

PIC单片机的汇编源码合集,应用比较广泛,设计程序时可做子程序来用

;********************SSDEC********************
;本程序实现对单字节有符号数据块进行降序排列。
;入口参数：数据块首址在SADR中,数据个数在W中。
;出口参数：排好序的数据仍在原数据块中。
;占用资源：W,STATUS,FSR,020H,023H,028H,029H,02AH,02BH,一重堆栈。

           IFNDEF       SSDEC1
            #DEFINE     SSDEC1

SSDEC       ADDLW       0FFH        ;字节数减1是比较次数
            MOVWF       TEMP3       ;TEMP3暂存内循环计数值
LOOP75      MOVF        TEMP3,W
            MOVWF       CNT         ;循环计数器减1
            BCF         TEMP1,0     ;TEMP1:0作为交换标志位
            MOVF        SADR,W
            MOVWF       FSR
LOOP74      MOVF        INDF,W
            INCF        FSR,F
            XORWF       INDF,W
            MOVWF       TEMP4       ;TEMP4:7存放符号异同标志
            XORWF       INDF,W      ;恢复W
            BTFSC       TEMP4,7
            GOTO        DIFF2       
            SUBWF       INDF,W
            BTFSC       STATUS,Z
            GOTO        NEXT39
            BTFSS       STATUS,C
            GOTO        NEXT39
            SUBWF       INDF,W
SWITCH2     MOVWF       TEMP2       ;TEMP2暂存将要交换的数
            MOVF        INDF,W
            DECF        FSR,F
            MOVWF       INDF
            MOVF        TEMP2,W
            INCF        FSR,F
            MOVWF       INDF        ;完成交换
            BSF         TEMP1,0     ;置交换标志
NEXT39      DECFSZ      CNT,F
            GOTO        LOOP74
            BTFSS       TEMP1,0
            RETLW       0
            DECFSZ      TEMP3,F
            GOTO        LOOP75
            RETLW       0
DIFF2       BTFSS       INDF,7
            GOTO        SWITCH2
            GOTO        NEXT39
           ENDIF