arifile.asm

PIC单片机的汇编源码合集,应用比较广泛,设计程序时可做子程序来用

;********************ARIFILE********************
;本程序实现算术平均值滤波（采样值为8位，连续采样数目小于256）。
;入口参数：采样值数据块首地址在SADR中，连续采样数在W中。
;出口参数：滤波值在SOU中.
;占用资源：W,STATUS,FSR,020H,023H,024H,028H,029H,02AH,一重堆栈。
;说    明: 
           IFNDEF       ARIFILE1
            #DEFINE     ARIFILE1

ARIFILE     MOVWF       CNT
            MOVWF       TEMP3
            CLRF        TEMP2       ;TEMP2:TEMP1存放和
            MOVF        SADR,W
            MOVWF       FSR
            CLRW
NEXT49      ADDWF       INDF,W
            BTFSC       STATUS,C
            INCF        TEMP2,F
            INCF        FSR,F
            DECFSZ      CNT,F
            GOTO        NEXT49
            MOVWF       TEMP1
            CLRF        SOU         ;存放平均值
            MOVLW       8
            MOVWF       CNT         ;循环8次
LOOP91      RLF         TEMP1,F
            RLF         TEMP2,F
            BTFSC       STATUS,C
            GOTO        NEXT50
            MOVF        TEMP3,W     ;移出位为0,继续
            SUBWF       TEMP2,W
            BTFSC       STATUS,C
            MOVWF       TEMP2       ;没有借位,继续
NEXT50      RLF         SOU,F
            DECFSZ      CNT,F
            GOTO        LOOP91
            RETURN      
           ENDIF