shopdisplaycategories.asp

来自「ASP+SQL Server动态网站开发从基础到实践教程」· ASP 代码 · 共 69 行

<!--#include file="shop$db.asp"-->
<%
'****************************************************************
'显示商店购物列表
'****************************************************************
'
ShopPageHeader               ' 显示每个页面头，即导航部分
CategoryHeader               ' 显示目录的表格头
Showcategories               ' 显示具体的目录
ShopPageTrailer              ' 显示每页页尾
'
'显示具体目录的函数
Sub ShowCategories()
	'变量定义
	Dim rs
	dim lngcatid
	dim strcategory
	Dim dbc
	'调用连接数据库函数
	ShopOpenDatabase dbc
	
	'创建一个recordsett类型的数据库连接
	Set rs = Server.CreateObject ("ADODB.Recordset")
	rs.Open "categories", dbc, adOpenForwardOnly,adLockReadOnly,adCmdTable
	
	'循环显示具体的目录
	While Not rs.EOF
	   '获得目录代号
	   lngcatid=rs("categoryID")
	   '获得目录描述
	   strcategory=rs("catdescription")
	   '获得时候有自目录
	   strsubcategory=rs("HasSubcategory")
	   if isNULL(strsubcategory) then
	       strsubcategory=""
	   end if 
	   '输出该目录内容
	   FormatCategory lngcatid, strcategory
	   rs.MoveNext
	Wend

	'输出表格结束符
	response.write "</table>"
	rs.Close
	set rs=nothing
	
	'关闭数据连接
	ShopCloseDatabase dbc
end sub

'*************************************
'显示目录表格头函数
Sub CategoryHeader
%>
	<p align="center"><font size="4">以下为商品列表</font></p>
	<center>
	<table border="2" cellpadding="2" cellspacing="1" width="70%">
<%
end sub

' ***********
'格式化目录输出，以表格形式输出目录
Sub FormatCategory (id, name)
	dim mycolor
	mycolor="#C4CEE5"
	Response.write " <TR bgColor=" & mycolor & "><TD><p align=center><b><font size=4>"
	response.write "<a HREF=shopdisplayproducts.asp?id=" & id & "&amp;cat=" & Server.URLEncode(name) & ">" &  name & "</a></font></td></tr>"
	end sub 
%>