lab-07-2013_spi_m.s43

MSP430F2013是TI的U盘开发工具对SPI进行读写的工程源程序包

;******************************************************************************
;   MSP430F20x2/3 Demo - SPI full-Duplex 3-wire Master
;
;   Description: SPI Master communicates full-duplex with SPI Slave using
;   3-wire mode. The level on P1.4 is TX'ed and RX'ed to P1.0.
;   Master will pulse slave P1.2 which resets USICNT counter for synch start.
;   ACLK = n/a, MCLK = SMCLK = Default DCO
;
;                 Slave                      Master
;                MSP430F20x2/3              MSP430F20x2/3
;              -----------------          -----------------
;             |              XIN|-    /|\|              XIN|-
;             |                 |      | |                 |
;             |             XOUT|-     --|RST          XOUT|-
;             |                 | /|\    |                 |
;             |          RST/NMI|--+<----|P1.2             |
;       LED <-|P1.0             |        |             P1.4|<-
;           ->|P1.4             |        |             P1.0|-> LED
;             |         SDI/P1.7|<-------|P1.6/SDO         |
;             |         SDO/P1.6|------->|P1.7/SDI         |
;             |        SCLK/P1.5|<-------|P1.5/SCLK        |
;
;  M. Buccini
;  Texas Instruments, Inc
;  October 2005
;******************************************************************************
#include  "msp430x20x3.h"
;-----------------------------------------------------------------------------
            ORG     0F800h                  ;  
;-----------------------------------------------------------------------------
RESET       mov.w   #0280h,SP               ; 初始化堆栈
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; 关看门狗
SetupP1     mov.b   #010h,&P1OUT            ; P1.4 输出
            bis.b   #010h,&P1REN            ; P1.4 上拉电阻
            bis.b   #001h,&P1DIR            ;
SetupUSI    bis.b   #USIPE7+USIPE6+USIPE5+USIMST+USIOE,&USICTL0; SPI 主机
            bis.b   #USIIE,&USICTL1         ; 中断使能
            mov.b   #USIDIV_4+USISSEL_2,&USICKCTL    ; SMCLK/16 
            bic.b   #USISWRST,&USICTL0      ; 使能 USI 模块
            mov.b   &P1IN,&USISRL           ;  
ResetSlave  bis.b   #004h,&P1DIR            ; 复位 从机
            bic.b   #004h,&P1DIR            ;
            clr.w   R4                      ; 延时
Delay       dec.w   R4                      ;
            jnz     Delay                   ;
            mov.b   #08h,&USICNT            ; 清标志位
                                            ;
Mainloop    bis.b   #LPM0+GIE,SR            ; 进入低功耗
            nop                             ;  
                                            ;
;------------------------------------------------------------------------------
USI_ISR;
;------------------------------------------------------------------------------
            mov.b   &USISRL,R4              ; 存数据
            mov.b   &P1IN,&USISRL           ;
            bic.b   #01h,&P1OUT             ;
            bit.b   #010h,R4                ; 
            jnc     L2                      ;
L1          bis.b   #01h,&P1OUT             ;
L2          mov.b   #08h,&USICNT            ; 清标志位
            reti                            ; 返回
                                            ;
;------------------------------------------------------------------------------
;           中断向量
;------------------------------------------------------------------------------
            ORG     0FFFEh                  ;  
            DW      RESET                   ;
            ORG     0FFE8h                  ; USICNT中断向量
            DW      USI_ISR                 ;
            END