lab-03-flash.s43

MSP430F2013是TI的U盘开发工具对Flash进行读写的源程序包

;*******************************************************************************
;   MSP430F20xx Demo - Flash In-System Programming, Copy SegC to SegD
;
;   Description: This program first erases flash seg C, then it increments all
;   values in seg C, then it erases seg C, then copies seg C to seg D.
;   Assumed MCLK 771kHz - 1428kHz.
;   //* Set Breakpoint in the Mainloop to avoid Stressing Flash *//
;
;                MSP430F20xx
;             -----------------
;         /|\|              XIN|-
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;
;
;   M. Buccini / L. Westlund
;   Texas Instruments Inc.
;   December 2005
;   Built with IAR Embedded Workbench Version: 3.40A
;*******************************************************************************
#include  <msp430x20x3.h>
#define     value   R4
;-------------------------------------------------------------------------------
            ORG     0F800h                  ;  
;-------------------------------------------------------------------------------
RESET       mov.w   #0280h,SP               ; 初始化堆栈
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; 关看门狗
            mov.b   &CALBC1_1MHZ,&BCSCTL1   ; 设置DCO
            mov.b   &CALDCO_1MHZ,&DCOCTL
            clr.b   value                   ;  
                                            ;				          							
Mainloop    call    #Write_SegC             ; 写C段
            inc.b   value                   ; value 加1
            call    #CopyC2D                ; 复制C段到D段
            jmp     Mainloop                ; 循环
                                            ;
;-------------------------------------------------------------------------------
Write_SegC  
;-------------------------------------------------------------------------------
            mov.w   #01040h,R5              ;
Timing      mov.w   #FWKEY+FSSEL0+FN1,&FCTL2 ; flash 时钟MCLK/3
Erase_SegC  mov.w   #FWKEY,&FCTL3           ; Lock = 0
            mov.w   #FWKEY+ERASE,&FCTL1     ; Erase  = 1 
            mov.w   #0,&01040h              ; 空写
Prog_SegC   mov.w   #FWKEY+WRT,&FCTL1       ; Write = 1 
            mov.w   #FWKEY,&FCTL3           ; Lock = 0
Prog_L1     mov.b   value,0(R5)             ;
            inc.w   R5                      ;
            cmp.w   #01080h,R5              ;
            jne     Prog_L1                 ;
            mov.w   #FWKEY+LOCK,&FCTL3      ; Lock = 1;
            ret                             ;
                                            ;
;-------------------------------------------------------------------------------
CopyC2D    ; 
;-------------------------------------------------------------------------------
            mov.w   #FWKEY+FSSEL0+FN1,&FCTL2  ;flash 时钟MCLK/3
Erase_SegD  mov.w   #FWKEY,&FCTL3           ; Lock = 0
            mov.w   #FWKEY+ERASE,&FCTL1     ; Erase  = 1
            mov.w   #0,&01000h              ; 擦除D段
            mov.w   #01040h,R5              ;  
Prog_SegD   mov.w   #FWKEY+WRT,&FCTL1       ; Write = 1
            mov.w   #FWKEY,&FCTL3           ; Lock = 0
Prog_L2     mov.b   @R5+,-65(R5)            ; 复制 C 段到 D段
            cmp.w   #01080h,R5              ;
            jne     Prog_L2                 ;
            mov.w   #FWKEY+LOCK,&FCTL3      ; Lock = 1
            ret

;-------------------------------------------------------------------------------
;           中断向量
;-------------------------------------------------------------------------------
            ORG     0FFFEh                  ;  
            DW      RESET                   ;
            END