71x_init.s79

IAR EWARM嵌入式系统编程与实践光盘源码

;文件中标号命名规则：	
;  ?xxx	仅能由汇编语言访问的外部标号。
;  __xxx    可由C 语言访问或定义的外部标号。
;  xxx	     单个模块中的局部标号(注意，本文件包含多个模块)。
;  main	 用户程序起始点。
;
;---------------------------------------------------------------
; 适用于整个文件的宏和定义
;---------------------------------------------------------------
; CPSP中模式位和中断标志(I,F)定义
Mode_USR           DEFINE   0x10
Mode_FIQ           DEFINE   0x11
Mode_IRQ           DEFINE   0x12
Mode_SVC           DEFINE   0x13
Mode_ABT           DEFINE   0x17
Mode_UNDEF         DEFINE   0x1B
Mode_SYS           DEFINE   0x1F

I_Bit              DEFINE   0x80 ;I=1时，禁止IRQ
F_Bit              DEFINE   0x40 ;F=1时，禁止FIQ

EIC_Base_addr      DEFINE   0xFFFFF800; EIC基地址
ICR_off_addr       DEFINE   0x00      ; 中断控制寄存器偏移
CIPR_off_addr      DEFINE   0x08      ; 当前中断优先级寄存器偏移
IVR_off_addr       DEFINE   0x18      ; 中断向量寄存器偏移
FIR_off_addr       DEFINE   0x1C      ; 快中断寄存器偏移
IER_off_addr       DEFINE   0x20      ; 中断允许寄存器偏移
IPR_off_addr       DEFINE   0x40      ; 中断悬挂位寄存器偏移
SIR0_off_addr      DEFINE   0x60      ; 源中断寄存器0

EMI_Base_addr      DEFINE   0x6C000000; EMI基地址
BCON0_off_addr     DEFINE   0x00      ; Bank 0 配置寄存器偏移
BCON1_off_addr     DEFINE   0x04      ; Bank 1 配置寄存器偏移
BCON2_off_addr     DEFINE   0x08      ; Bank 2 配置寄存器偏移
BCON3_off_addr     DEFINE   0x0C      ; Bank 3 配置寄存器偏移

EMI_ENABLE         DEFINE   0x8000
EMI_SIZE_16        DEFINE   0x0001

GPIO2_Base_addr    DEFINE   0xE0005000; GPIO2基地址
PC0_off_addr       DEFINE   0x00      ; Port 配置寄存器0偏移
PC1_off_addr       DEFINE   0x04      ; Port 配置寄存器1偏移
PC2_off_addr       DEFINE   0x08      ; Port 配置寄存器2偏移
PD_off_addr        DEFINE   0x0C      ; Port 数据寄存器偏移

CPM_Base_addr      DEFINE   0xA0000040; CPM基地址
BOOTCR_off_addr    DEFINE   0x10      ; CPM - Boot配置寄存器
FLASH_mask         DEFINE   0x0000    ; 将FLASH重映射到0x0
RAM_mask           DEFINE   0x0002    ; 将RAM重映射到0x0

;----------------------------------------------------------------------------------
; APB桥 (系统外设)
;----------------------------------------------------------------------------------
APB1_base_addr     DEFINE   0xC0000000          ; APB桥1基地址
APB2_base_addr     DEFINE   0xE0000000          ; APB桥2基地址
CKDIS_off_addr     DEFINE   0x10                ; APB桥1 - 时钟禁止寄存器
SWRES_off_addr     DEFINE   0x14                ; APB桥1 - 软件复位寄存器
CKDIS1_config_all  DEFINE   0x27FB              ; 允许/禁止所有APB1的外设时钟
SWRES1_config_all  DEFINE   0x27FB              ; 复位所有APB1的外设
CKDIS2_config_all  DEFINE   0x7FDD              ; 允许/禁止所有APB2的外设时钟
SWRES2_config_all  DEFINE   0x7FDD              ; 复位所有APB1的外设

;---------------------------------------------------------------
; ?program_start
;---------------------------------------------------------------
		MODULE	?program_start
		RSEG	IRQ_STACK:DATA(2)
		RSEG	FIQ_STACK:DATA(2)
		RSEG	UND_STACK:DATA(2)
		RSEG	ABT_STACK:DATA(2)		
		RSEG	SVC_STACK:DATA(2)
		RSEG	CSTACK:DATA(2)
		RSEG	ICODE:CODE:NOROOT(2)
		PUBLIC	__program_start
		EXTERN	?main
                CODE32

;*******************************************************************************
;                               -- MACROS --
;*******************************************************************************

;*******************************************************************************
;说明：EIC_INIT宏，按以下方式初始化EIC:
;                 - 禁止IRQ
;                 - 禁止FIQ
;                 - IVR中包含加载PC操作码(0xF59FF00)
;                 - 当前中断优先级为0
;                 - 禁止所有通道
;                 - 所有通道优先级为0
;                 - 所有SIR寄存器包含到相关IRQ入口表的偏移
;入口：无
;出口：无
;*******************************************************************************
EIC_INIT   MACRO
        LDR     r3, =EIC_Base_addr
        LDR     r4, =0xE59F0000
        STR     r4, [r3, #IVR_off_addr]; 在IVR[31:16]中写入 LDR pc,[pc,#offset]指令代码
        LDR     r2, =32                ; 初始化32通道
        LDR     r0, =T0TIMI_Addr       ; 读1取IRQ入口表地址
        LDR     r1, =0x00000FFF
        AND     r0,r0,r1
        LDR     r5, =SIR0_off_addr     ; 读取SIR0地址
        SUB     r4,r0,#8               ; 减8，作为预取
        LDR     r1, =0xF7E8            ; 加偏移地址(IVR地址 + 7E8 = 0x00000000)
                                       ; 0xF7E8用于完成LDR pc,[pc,#offset]指令代码
        ADD     r1,r4,r1               ; 计算跳转偏移
EIC_INI MOV     r4, r1, LSL #16        ; 结果左移
        STR     r4, [r3, r5]           ; 结果存储到SIRx寄存器
        ADD     r1, r1, #4             ; 下一个IRQ地址
        ADD     r5, r5, #4             ; 下一个SIR
        SUBS    r2, r2, #1             ; SIR寄存器号减1
        BNE     EIC_INI
        ENDM
;*******************************************************************************
;说明：PERIPHERAL_INIT宏，复位所有器件外设
;入口：无
;出口：无
;*******************************************************************************
PERIPHERAL_INIT MACRO
        LDR     r1, =APB1_base_addr      ; r0= APB1基地址
        LDR     r2, =APB2_base_addr      ; r0= APB2基地址
        LDR     r0, =CKDIS1_config_all
        STRH    r0, [r1, #CKDIS_off_addr]; 禁止所有APB1外设时钟
        LDR     r0, =CKDIS2_config_all
        STRH    r0, [r2, #CKDIS_off_addr]; 禁止所有APB2外设时钟
        LDR     r0, =SWRES1_config_all
        STRH    r0, [r1, #SWRES_off_addr]; 保持所有APB1外设复位状态
        LDR     r0, =SWRES2_config_all
        STRH    r0, [r2, #SWRES_off_addr]; 保持所有APB2外设复位状态
        MOV     r7, #10                  ; 等待所选宏单元退出复位
        loop1   SUBS    r7, r7, #1
        BNE     loop1
        MOV     r0, #0
        STRH    r0, [r1, #SWRES_off_addr]; 允许所有APB1外设
        STRH    r0, [r2, #SWRES_off_addr]; 允许所有APB2外设
        STRH    r0, [r1, #CKDIS_off_addr]; 允许所有APB1外设时钟
        STRH    r0, [r2, #CKDIS_off_addr]; 允许所有APB2外设时钟
        MOV     r7, #10                  ; 等待所选宏单元退出复位
loop2   SUBS    r7, r7, #1
        BNE     loop2
        ENDM

;********************************************************************************************
; 定义重映射。如果需要在进入主程序之前进行重映射，请去掉下面语句前面的注释：
;            #define   remapping
; 然后定义重映射到地址0x00000000的存储器。
; 重映射RAM时，请去掉下面语句前面的注释：
;         #define  remap_ram
; 重映射FLASH时，请去掉下面语句前面的注释：
;         #define remap_flash

        IMPORT  T0TIMI_Addr
__program_start
         LDR     pc, =NextInst
NextInst
		NOP		; 等待OSC稳定
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP
        MSR     CPSR_c, #Mode_ABT|F_Bit|I_Bit
        ldr      sp,=SFE(ABT_STACK) & 0xFFFFFFF8     ; ABT_STACK中止堆栈结束
        MSR     CPSR_c, #Mode_UNDEF|F_Bit|I_Bit
        ldr      sp,=SFE(UND_STACK) & 0xFFFFFFF8     ; UND_STACK未定义堆栈结束
        MSR     CPSR_c, #Mode_SVC|F_Bit|I_Bit
        ldr      sp,=SFE(SVC_STACK) & 0xFFFFFFF8      ; SVC_STACK管理堆栈结束
; 如果需要复位所有器件外设，请去掉下面语句前面的注释：
;       PERIPHERAL_INIT           ; 复位所有器件外设
; 如果需要初始化EIC，请去掉下面语句前面的注释：
        EIC_INIT                  ; Initialize EIC

;******************************************************************************
;重映射
;******************************************************************************
#ifdef remapping
    #ifdef remap_flash
        MOV     r0, #FLASH_mask
    #endif
    #ifdef remap_ram
        MOV     r0, #RAM_mask
    #endif
        LDR     r1, =CPM_Base_addr
        LDRH    r2, [r1, #BOOTCR_off_addr]; 读取BOOTCR寄存器
        BIC     r2, r2, #0x03             ; 复位BOOTCR的最低2位
        ORR     r2, r2, r0                ; 改变BOOTCR的最低2位
        STRH    r2, [r1, #BOOTCR_off_addr]; 写入BOOTCR寄存器
#endif
       	MSR     CPSR_c, #Mode_FIQ|I_Bit   ; 切换到FIQ模式
        ldr      sp,=SFE(FIQ_STACK) & 0xFFFFFFF8     ; FIQ_STACK堆栈结束
       	MSR     CPSR_c, #Mode_IRQ|I_Bit; Change to IRQ mode
        ldr      sp,=SFE(IRQ_STACK) & 0xFFFFFFF8     ; IRQ_STACK堆栈结束
        MSR     CPSR_c, #Mode_USR         ; Change to User mode, Enable IRQ and FIQ
        ldr     sp,=SFE(CSTACK) & 0xFFFFFFF8         ; CSTACK(用户)堆栈结束

; 跳转到C库函数
        b ?main   ; Note : use B not BL, because an application will
                         ; never return this way
        LTORG
        END