12-5-2.mp

需要通过验证才能下载！希望大家多多合作！否则不能下载！请谅解！

% 12-5-2.mp 用 mp -tex=latex 7-6-2 处理
verbatimtex \documentclass{article}
\usepackage{CJK}
\begin{document}
\begin{CJK}{GBK}{song}
etex

beginfig(12);
numeric ux, uy;
120ux=60mm; 4uy=40mm;
draw (0,4uy)--(0,0)--(120ux,0);
pickup pencircle scaled 1pt;
draw (0,uy){right}
  for ix=1 upto 24:
    ..(5ix*ux, uy*2/(1+cosd 5ix))
  endfor;
label.bot(btex $x$ 轴 etex, (60ux,0));
label.lft(btex $y$ 轴 etex rotated 90,
          (0,2uy));
label.lft(
  btex $\displaystyle y=\frac{2}{1+\cos x}$ etex,
  (120ux, 4uy));
endfig;

beginfig(15);
z0 = (0,0);
z1 = (2in-2bp,0);
for i=1 upto 4:
  z[2i-2]-z[2i] = z[2i-1]-z[2i+1] = (0,14pt);
endfor
draw z0..z1 dashed evenly;
label.rt(btex \texttt{\small dashed evenly} etex, z1);
draw z2..z3 dashed evenly scaled 2;
label.rt(btex \texttt{\small dashed evenly scaled 2} etex, z3);
draw z4..z5 dashed withdots;
label.rt(btex \texttt{\small dashed withdots} etex, z5);
draw z6..z7 dashed withdots scaled 2;
label.rt(btex \texttt{\small dashed withdots scaled 2} etex, z7);
draw z8..z9 dashed dashpattern(on 20 off 2 on 1 off 2);
label.rt(btex \texttt{\small dashed dashpattern(on 20 off 2 on 1 off 2)} etex, z9);
endfig;

input graph

beginfig(17);
u:=1mm;
draw begingraph(60u,40u);
  pickup pencircle scaled 1pt;
  path p;
  for x = -20 step 0.2 until -0.2:
    augment.p (x*u, sind(x*180/3.14159)/x*u);
  endfor
  augment.p (0, u);
  for x = 0.2 step 0.2 until 20:
    augment.p (x*u, sind(x*180/3.14159)/x*u);
  endfor
  glabel.lrt(btex $\displaystyle\frac{\sin(x)}{x}$ etex, (-20u,u));
  gdraw p;
endgraph;
endfig;

beginfig(18);
u:=1mm;
draw begingraph(60u,40u);
  pi = 3.14159; beta0 = 11 - 2/3*4;
  lambda1 = 0.15; lambda2 = 0.25;
  setcoords (log,linear);
  pickup pencircle scaled 1pt;
  path p[];
  for x = 0.5 step 0.1 until 10:
    augment.p1 (x*u, 4*pi/(beta0*2mlog(x/lambda1)/256)*u);
    augment.p2 (x*u, 4*pi/(beta0*2mlog(x/lambda2)/256)*u);
  endfor
  gfill p1--(reverse p2)--cycle withcolor .5white;
  glabel.lft(btex $\alpha_s(Q^2)$ etex rotated 90, OUT);
  glabel.bot(btex $Q^2/\textrm{GeV}$ etex, OUT);
  frame.llft;
endgraph;
endfig;

verbatimtex
\end{CJK}
\end{document}
etex
end