createautobackupjob.sql

出租车管理企业

/*if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[createAutoBackupJob]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
	drop procedure [dbo].[createAutoBackupJob]
--GO

--SET QUOTED_IDENTIFIER ON 
--GO
--SET ANSI_NULLS ON 
--GO
*/

--用法： Exec createAutoBackupJob 'Easter2', 'D:\SysData\Backup\', 'Easter2自动备份_海宏软件创建的自动备份', 8
create Procedure createAutoBackupJob( @sDataBase varChar(100), @sPath varChar(999), @sJobName varChar(128)='', @nHours int=8 ) 
As		--8小时自动备份，建一个自动备份，然后修改自动生成的SQL脚本。
Begin	--作者：海宏软件。周承昊。2007-4-20
		--注意：路径参数必须带“\”
	-- 2007-4-25/10_28 上生成的脚本。
	-- 由MOVEBABY\Administrator
	-- 服务器 (local)
	BEGIN TRANSACTION
	--
	Declare @s varChar(999), @sInfo varChar(999), @sCommandScript nVarChar(4000) 
		--@sJobName varChar(254), @sPath varChar(999), @sDataBase varChar(100) 
	--Select @sJobName='Easter3M自动备份', @sPath='D_\SysData\Backup\', @sDataBase='Easter3M'
	Select @sCommandScript=
'
	Declare @s varchar(50)
	Select @s= Convert(VarChar(50),GetDate(),120)		--ODBC标准格式
	Select @s=Replace( Replace( Replace(@s,''-'',''_''), '' '',''''), '':'',''_'')
	Select @s='''+@sPath+@sDataBase+'''+@s
	BACKUP DATABASE ['+@sDataBase+'] TO	DISK = @s WITH	INIT ,	NOUNLOAD ,	NAME = '''+@sJobName+''',	NOSKIP ,	STATS = 10,	NOFORMAT 
'
	--
	DECLARE @JobID BINARY(16)
	DECLARE @ReturnCode INT		
	SELECT @ReturnCode = 0
	IF (SELECT COUNT(*) FROM msdb.dbo.syscategories WHERE name = N'[Uncategorized (Local)]') < 1 
		EXECUTE msdb.dbo.sp_add_category @name = N'[Uncategorized (Local)]'
	
	-- 删除同名的警报（如果有的话）。
	SELECT @JobID = job_id FROM msdb.dbo.sysjobs WHERE (name = @sJobName)
	IF (@JobID IS NOT NULL)		
	BEGIN	
		-- 检查此作业是否为多重服务器作业	
		IF (EXISTS (SELECT * FROM msdb.dbo.sysjobservers WHERE (job_id = @JobID) AND (server_id <> 0))) 
		BEGIN 
		-- 已经存在，因而终止脚本 
			Select @sInfo='无法导入作业'+@sJobName+'，因为已经有相同名称的多重服务器作业。'
			RAISERROR (@sInfo, 16, 1) 
			GOTO QuitWithRollback	
		END 
		ELSE 
			-- 删除［本地］作业 
			EXECUTE msdb.dbo.sp_delete_job @job_name = @sJobName
		SELECT @JobID = NULL
	END 

  BEGIN	---------从此向下为主要部分
	
	-- 添加作业
	EXECUTE @ReturnCode = msdb.dbo.sp_add_job @job_id = @JobID OUTPUT , @job_name = @sJobName, @owner_login_name = N'sa', @description = N'海宏软件创建的数据库自动备份。', @category_name = N'[Uncategorized (Local)]', @enabled = 1, @notify_level_email = 0, @notify_level_page = 0, @notify_level_netsend = 0, @notify_level_eventlog = 2, @delete_level= 0
	IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
	
	-- 添加作业步骤
	EXECUTE @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID, @step_id = 1, @step_name = N'第 1 步', 
		@command = @sCommandScript, @database_name = N'master', @server = N'', @database_user_name = N'', @subsystem = N'TSQL', @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0, @retry_interval = 0, @output_file_name = N'', @on_success_step_id = 0, @on_success_action = 1, @on_fail_step_id = 0, @on_fail_action = 2
	--
	IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 
	EXECUTE @ReturnCode = msdb.dbo.sp_update_job @job_id = @JobID, @start_step_id = 1 
	
	IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
	
	-- 添加作业调度
	EXECUTE @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id = @JobID, @name = N'第 1 调度', @enabled = 1, 
		@freq_type = 4, @active_start_date = 20050426, @active_start_time = 0, @freq_interval = 1, @freq_subday_type = 8, 
		@freq_subday_interval = @nHours, @freq_relative_interval = 0, @freq_recurrence_factor = 0, 
		@active_end_date = 99991231, @active_end_time = 235959
	IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
	
	-- 添加目标服务器
	EXECUTE @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @JobID, @server_name = N'(local)' 
	IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 

  END  ----------------主要部分结束
	---提交事务
	COMMIT TRANSACTION
	GOTO	 EndSave
QuitWithRollback:
	IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION 
EndSave: 

End


--GO
--SET QUOTED_IDENTIFIER OFF 
--GO
--SET ANSI_NULLS ON 
--GO