main.ls

M16C单片机功率控制源码

MEMORY
{
  ram (rw) : o = 0x0000400, l = 31k
  rom (rx) : o = 0x00C0000, l = 384k
}
SECTIONS
{

	.text 0x00C0000 :
	{
		*(.text)
		*(.text.*)
		etext = .;
	} > rom

	.init :
	{
		*(.init)
	} > rom

	.fini :
	{
		*(.fini)
	} > rom

	.got :
	{
		*(.got)
		*(.got.plt)
	} > rom
	
	.eh_frame_hdr :
	{
		*(.eh_frame_hdr)
	} > rom

	.eh_frame :
	{
		*(.eh_frame)
	} > rom

	.jcr :
	{
		*(.jcr)
	} > rom

	.tors :
	{
		__CTOR_LIST__ = .;
		___ctors = .;
		*(.ctors)
		___ctors_end = .;
		__CTOR_END__ = .;
		__DTOR_LIST__ = .;
		___dtors = .;
		*(.dtors)
		___dtors_end = .;
		__DTOR_END__ = .;
		_mdata = .;
	} > rom
	
	.data 0x00000400 : AT (_mdata)
	{
		_data = .;
		*(.data)
		_edata = .;
	} > ram

	.rodata : AT (_mdata + SIZEOF(.data))
	{
		_rodata = .;
		*(.rodata)
		*(.rodata.*)
		*(.plt)
		_erodata = .;
	} > ram
		
	.gcc_exc :
	{
		*(.gcc_exc)
	} > ram
	
	.bss :
	{
		_bss = .;
		*(.bss)
		*(COMMON)
		_ebss = .;
		_end = .;
	} > ram
	
	/* User Stack Pointer */
	.ustack 0x00001000 :
	{
		_ustack = .;
	} > ram
	
	/* Interrupt Stack Pointer */
	.istack 0x000013E8 :
	{
		_istack = .;
	} > ram
	
	/* Variable Vector Section */
	.var_vects 0x000FA000 :	
	{
		KEEP(*( .var_vects))
	} > rom
		
	/* Fixed Vector Section */
	.vects 0x000FFFDC :	
	{
		KEEP(*( .vects))
	} > rom

}