configure.in

xmms-1.2.10.tar.gz学习使用的就下吧

AC_ARG_ENABLE(oss, [  --disable-oss           disable the OSS output plugin],
	      have_oss=$enableval, have_oss=yes)
         
if test "$have_oss" = "auto"; then
    AC_MSG_CHECKING(for OSS include dir)
    OSS_CFLAGS=""
    if test -f "/etc/oss.conf"
    then
        for i in `cat /etc/oss.conf`; 
        do
            t=`echo $i | sed -e 's/OSSLIBDIR=//'`
            if test "x$i" != "x$t"
            then
                if test -f "$t/include/sys/soundcard.h"
                then
                    OSS_CFLAGS="-I$t/include"
                fi
            fi
        done
    fi
    if test -n "$OSS_CFLAGS"
    then
        AC_MSG_RESULT([$OSS_CFLAGS])
    else
        AC_MSG_RESULT([not found])
    fi
    CPPFLAGS_save=$CPPFLAGS
    CPPFLAGS="$CPPFLAGS $OSS_CFLAGS"
    AC_CHECK_HEADERS(sys/soundcard.h)
    AC_CHECK_HEADERS(machine/soundcard.h)
    CPPFLAGS=$CPPFLAGS_save

    if test "${ac_cv_header_sys_soundcard_h}" = "yes" || test "${ac_cv_header_machine_soundcard_h}" = "yes"; then
        have_oss=yes
    fi
fi

if test "$have_oss" = "yes"; then
    AC_DEFINE(HAVE_OSS, 1, [Define if the OSS output plugin should be built])
else
    have_oss=no
fi
AM_CONDITIONAL(HAVE_OSS, test "$have_oss" = "yes")
    

LIBS_save=$LIBS
CFLAGS_save=$CFLAGS
LDFLAGS_save=$LDFLAGS
AM_PATH_ALSA(0.9.0, have_alsa=yes, have_alsa=no)
AM_CONDITIONAL(HAVE_ALSA, test "${have_alsa}" = "yes")
LIBS=$LIBS_save
CFLAGS=$CFLAGS_save
LDFLAGS=$LDFLAGS_save

dnl FreeBSD newpcm driver detection
AC_CACHE_CHECK(for FreeBSD newpcm driver, xmms_cv_newpcm_driver,
  if test -r "/dev/sndstat"; then
    grep 'newpcm' /dev/sndstat 2>/dev/null 1>/dev/null
    if test "x$?" = "x0"; then
      xmms_cv_newpcm_driver="yes"
    else
      xmms_cv_newpcm_driver="no"
    fi
  else
    xmms_cv_newpcm_driver="no"
  fi)
if test "x$xmms_cv_newpcm_driver" = "xyes"; then
  AC_DEFINE(HAVE_NEWPCM, 1, [Define if you have the FreeBSD newpcm driver])
fi


AC_CHECK_HEADERS(linux/cdrom.h)
AC_CHECK_HEADERS(sys/cdrio.h)
AC_CHECK_HEADERS(sys/cdio.h)
AC_CHECK_HEADERS(linux/joystick.h)
AC_CHECK_HEADERS(unistd.h)
AC_CHECK_HEADERS(fcntl.h)
AC_CHECK_HEADERS(sys/ioctl.h)
AC_CHECK_HEADERS(fnmatch.h)
AC_CHECK_HEADERS(limits.h)
AC_CHECK_HEADERS(sched.h)
AC_CHECK_HEADERS(sys/sched.h)
AC_CHECK_HEADERS(wchar.h)
AC_CHECK_HEADERS(fts.h)

XMMS_FUNC_POSIX(sched_setscheduler)

AC_CHECK_FUNCS(mkdtemp)
AC_CHECK_FUNCS(getmntinfo)
AC_CHECK_FUNCS(sched_get_priority_max)
AC_CHECK_FUNCS(srandomdev)

AC_CACHE_CHECK([for nl_langinfo(CODESET)], xmms_cv_func_langinfo, [
AC_TRY_COMPILE([#include <langinfo.h>],
        [char *codeset = nl_langinfo (CODESET);],
   xmms_cv_func_langinfo=yes,
   xmms_cv_func_langinfo=no)])
if test "x$xmms_cv_func_langinfo" = "xyes"; then
  AC_DEFINE(HAVE_CODESET,,[Define if nl_langinfo(CODESET) is available.])
fi

if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes"
then
    case "$host" in 
	*-*-sunos* | *-*-solaris* | *-*-linux*)
	    AC_DEFINE(XMMS_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
	;;
	*-*-freebsd*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	;;
	*-*-netbsd* | *-*-openbsd*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	    AC_DEFINE(XMMS_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
	;;
	*-*darwin*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	    AC_DEFINE(XMMS_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
	;;
    esac
fi


AM_CONDITIONAL(HAVE_CDROM, test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes")
AM_CONDITIONAL(HAVE_LINUX_JOYSTICK,test "${ac_cv_header_linux_joystick_h}" = "yes")

AC_CHECK_SIZEOF(long)

if test -n "$GCC"
then
  CFLAGS="$CFLAGS -Wall -Wpointer-arith -finline-functions"
  case "$CFLAGS" in
    -g*) ;;
    *\ -g*) ;;
    *) CFLAGS="$CFLAGS -fomit-frame-pointer" ;;
  esac
  case "$host" in
    alpha*-*-freebsd*)
	;;
    *-*-freebsd*)
	CFLAGS="$CFLAGS -ffast-math"
	;;
    *)
	CFLAGS="$CFLAGS -ffast-math -funroll-all-loops"
	;;
  esac
fi

AC_MSG_CHECKING(if __ELF__ is defined)
AC_EGREP_CPP(yes,
[#ifdef __ELF__
  yes
#endif
], is_elf=yes, is_elf=no)
AC_MSG_RESULT([${is_elf}])


have_solaris=no
have_sun=no
ARCH_DEFINES=""
case "$host" in 
	*-*-openbsd* | *-*-netbsd*)
		have_sun=yes
		if test "${is_elf}" = "no" 
		then
			AC_DEFINE(SYMBOL_PREFIX, "_", [Define to symbol prefix, if any])
		fi
	;;
	*-*-darwin*)
		AC_DEFINE(SYMBOL_PREFIX, "_", [Define to symbol prefix, if any])
	;;
	*-hpux-*)
		ARCH_DEFINES="-DHPUX"
	;;
	*-*-solaris* | *-*-sunos*)
		have_solaris=yes
	;;
esac

arch_type=other
x86_asm=no
case "$host" in 
	i386-*-* | i486-*-* | i586-*-* | i686-*-* | i86pc-*-*)
		arch_type=ix86
		case "$host" in
		        *-*-netbsd* | *-*openbsd*)
			;;
			*)
				ARCH_DEFINES="-DI386_ASSEM"
				x86_asm=yes
			;;
		esac
	;;
esac


AC_SUBST(ARCH_DEFINES)
AM_CONDITIONAL(ARCH_X86, test "x$arch_type" = "xix86")
AM_CONDITIONAL(USE_X86ASM, test "x$x86_asm" = xyes)
AM_CONDITIONAL(HAVE_SOLARIS, test "x$have_solaris" = xyes)
AM_CONDITIONAL(HAVE_SUN, test "x$have_sun" = xyes)

plugindir=$libdir/xmms
AC_SUBST(plugindir)

if test "x$enable_one_plugin_dir" = "xyes"; then
  pluginsubs="\\\"Plugins\\\""
  INPUT_PLUGIN_DIR=Plugins
  OUTPUT_PLUGIN_DIR=Plugins
  EFFECT_PLUGIN_DIR=Plugins
  GENERAL_PLUGIN_DIR=Plugins
  VISUALIZATION_PLUGIN_DIR=Plugins
else
  pluginsubs="\\\"Output\\\",\\\"Input\\\",\\\"Effect\\\",\\\"General\\\",\\\"Visualization\\\""
  INPUT_PLUGIN_DIR=Input
  OUTPUT_PLUGIN_DIR=Output
  EFFECT_PLUGIN_DIR=Effect
  GENERAL_PLUGIN_DIR=General
  VISUALIZATION_PLUGIN_DIR=Visualization
fi

AC_SUBST(INPUT_PLUGIN_DIR)
AC_SUBST(OUTPUT_PLUGIN_DIR)
AC_SUBST(EFFECT_PLUGIN_DIR)
AC_SUBST(GENERAL_PLUGIN_DIR)
AC_SUBST(VISUALIZATION_PLUGIN_DIR)
AC_SUBST(pluginsubs)

XMMS_DEFINES="$CFLAGS -DDATA_DIR=\\\"$datadir/xmms\\\" -DPLUGIN_DIR=\\\"$plugindir\\\" -DPLUGINSUBS=$pluginsubs -DLOCALEDIR=\\\"$localedir\\\""

if test "x$enable_user_plugin_dir" = "xno"; then
	AC_DEFINE(DISABLE_USER_PLUGIN_DIR,, [Define to disable per user plugin directory])
fi

AC_SUBST(XMMS_DEFINES)

PLUGIN_LDFLAGS='-module -avoid-version -export-symbols-regex "get_.plugin_info"'
AC_SUBST(PLUGIN_LDFLAGS)

AC_CONFIG_SUBDIRS(libxmms)

AC_SUBST(xmmsdir)
AC_SUBST(plugindir)

AC_OUTPUT([
Makefile
xmms.1
wmxmms.1
xmms.spec
xmms-config
xmms/Makefile
xmms/defskin/Makefile
Output/Makefile
Output/OSS/Makefile
Output/esd/Makefile
Output/disk_writer/Makefile
Output/solaris/Makefile
Output/sun/Makefile
Output/alsa/Makefile
Input/Makefile
Input/wav/Makefile
Input/mpg123/Makefile
Input/mikmod/Makefile
Input/cdaudio/Makefile
Input/tonegen/Makefile
Input/vorbis/Makefile
Effect/Makefile
Effect/voice/Makefile
Effect/echo_plugin/Makefile
Effect/stereo_plugin/Makefile
General/Makefile
General/ir/Makefile
General/joystick/Makefile
General/song_change/Makefile
Visualization/Makefile
Visualization/blur_scope/Makefile
Visualization/sanalyzer/Makefile
Visualization/opengl_spectrum/Makefile
wmxmms/Makefile
po/Makefile.in
intl/Makefile],
[chmod +x xmms-config])

echo ""
echo "Configuration:"
echo "  Install path:               ${prefix}"
if test "$XMMS_PATH" != "no"; then
echo "  Current xmms                $XMMS_PATH"
fi

echo "  Build OSS plugin:           $have_oss"
echo "  Build esd plugin:           $have_esd"
echo "  Build Solaris plugin:       $have_solaris"
echo "  Build BSD Sun plugin:       $have_sun"
echo "  Build ALSA plugin:          $have_alsa"
echo "  Build mikmod plugin:        $have_mikmod"
echo "  Build Ogg Vorbis plugin:    $have_oggvorbis"
echo "  Build OpenGL plugins:       $have_opengl"
echo "  Pthread flag:               $PTHREAD_LIBS"
echo "  Use one plugin dir:         $enable_one_plugin_dir"
echo "  Allow user plugin dir:      $enable_user_plugin_dir"
echo ""

echo ""
if test "$xmms_cv_lib_xlibs_threadsafe" = "no"; then
  echo "Note: You need to have thread-safe xlibs to use xmms."
  echo "If you are using libc5 thread aware Xlibs just skip this." 
  echo ""
  echo "If you don't have those libs and you are on a libc5 system get them at:"
  echo "ftp://ftp.dent.med.uni-muenchen.de/pub/wmglo/"
fi

if test "$XMMS_PATH" != "no" && test "$prefix/bin/xmms" != "$XMMS_PATH" ; then
  echo ""
  echo "Note: Configure has discovered that you already have xmms installed"
  echo "and it do not match with the given --prefix. You have xmms installed "
  echo "in $XMMS_PATH and you chose $prefix/bin/xmms."
  echo "If you don't want two copies of XMMS installed, rerun configure with"
  echo "the --prefix option set to the location of the old xmms, or uninstall"
  echo "the old xmms."
fi