configure.in

xmms-1.2.10.tar.gz学习使用的就下吧

dnl Process this file with autoconf to produce a configure script.
AC_INIT(xmms/main.c)
AC_CANONICAL_HOST

cflags_set=${CFLAGS+set}
AM_CONFIG_HEADER(config.h xmms/i18n.h)

AM_INIT_AUTOMAKE(xmms, 1.2.10)

AC_ARG_ENABLE( one-plugin-dir,
[  --enable-one-plugin-dir  use a single plugin dir [default=no]],,
		enable_one_plugin_dir="no")

AC_ARG_ENABLE( user-plugin-dir,
[  --disable-user-plugin-dir disable per-user plugin dir],,
		enable_user_plugin_dir="yes")

AC_ARG_WITH(dev-dsp, 
  [  --with-dev-dsp=path     Path to OSS DSP data pipe, default is /dev/dsp.],
	dev_dsp="$withval", dev_dsp="/dev/dsp")
AC_DEFINE_UNQUOTED(DEV_DSP,"$dev_dsp", [Path to OSS DSP, really just a data pipe, default is /dev/dsp.])

AC_ARG_WITH(dev-mixer, 
  [  --with-dev-mixer=path   Path to OSS sound mixer, default is /dev/mixer.],
	dev_mixer="$withval", dev_mixer="/dev/mixer")
AC_DEFINE_UNQUOTED(DEV_MIXER,"$dev_mixer", [Path to OSS mixer, default is /dev/mixer.])

AC_ARG_WITH(cdda-device, 
  [  --with-cdda-device=path Path to default cdaudio device.],
  AC_DEFINE_UNQUOTED(CDDA_DEVICE,"$withval", [Path to default cdaudio device.]))

AC_ARG_WITH(cdda-dir, 
  [  --with-cdda-dir=path    Path to default cdaudio directory.],
  AC_DEFINE_UNQUOTED(CDDA_DIRECTORY,"$withval", [Path to default cdaudio directory.]))

prefix_save=$prefix
AC_PREFIX_PROGRAM(xmms)

dnl work around a bug in AC_PREFIX_PROGRAM in autoconf 2.53-2.57
prefix_new=`echo $prefix | sed 's/^\(.\).*$/\1/'`
if test "x$prefix_new" != "x/"; then
    prefix=$prefix_save
fi

dnl Various compiler setup.
AC_PROG_CC
AC_ISC_POSIX
dnl AC_PROG_CXX
AC_C_BIGENDIAN
AC_C_INLINE
AC_C_CONST

dnl Set assembler and assembler flags for automake > 1.4
ifdef([AM_PROG_AS], [AM_PROG_AS])


dnl Checks for programs.
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

AM_DISABLE_STATIC
AM_PROG_LIBTOOL

AC_CHECK_HEADER(pthread.h,,AC_MSG_ERROR([*** POSIX thread support not installed - please install first ***]))

AM_PATH_GLIB(1.2.2,,AC_MSG_ERROR([*** GLIB >= 1.2.2 not installed - please install first ***]))
AM_PATH_GTK(1.2.2,,AC_MSG_ERROR([*** GTK+ >= 1.2.2 not installed - please install first ***]),gthread)
AC_PATH_PROG(XMMS_PATH,xmms,no)

LIBS_save=$LIBS
LIBS="$LIBS $GTK_LIBS"
SM_LIBS=""
AC_CHECK_LIB(SM, SmcOpenConnection,[
AC_DEFINE(WITH_SM, , [Define if building with support for X11R6 session management])
SM_LIBS="-lSM -lICE"])
AC_SUBST(SM_LIBS)
LIBS=$LIBS_save

AC_PATH_X
AM_ICONV

CFLAGS_save=$CFLAGS
LIBS_save=$LIBS
CFLAGS="$CFLAGS $GTK_CFLAGS"
LIBS="$LIBS $GTK_LIBS"
AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,[
    AC_DEFINE(XF86VIDMODE,1,[XF86VidMode extension is present])
        VM_LIBS="-lXxf86vm"],,
    -L$x_libraries -lXext)

CFLAGS=$CFLAGS_save
LIBS=$LIBS_save
AC_SUBST(VM_LIBS)

PTHREAD_LIBS=error
AC_MSG_CHECKING(for old style FreeBSD -pthread flag)
AC_EGREP_CPP(yes,
	[#if (defined(__FreeBSD_cc_version) && __FreeBSD_cc_version <= 500001) || defined(__OpenBSD__)
	  yes
	#endif
	], AC_MSG_RESULT(yes)
	CFLAGS="$CFLAGS -D_THREAD_SAFE" PTHREAD_LIBS="-pthread",
	AC_MSG_RESULT(no))
if test "x$PTHREAD_LIBS" = xerror; then
	AC_CHECK_LIB(pthread, pthread_attr_init,
		PTHREAD_LIBS="-lpthread")
fi
if test "x$PTHREAD_LIBS" = xerror; then
        AC_CHECK_LIB(pthreads, pthread_attr_init,
		PTHREAD_LIBS="-lpthreads")
fi
if test "x$PTHREAD_LIBS" = xerror; then
        AC_CHECK_LIB(c_r, pthread_attr_init,
		PTHREAD_LIBS="-lc_r")
fi
if test "x$PTHREAD_LIBS" = xerror; then
	AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
fi
if test "x$PTHREAD_LIBS" = xerror; then
	AC_MSG_ERROR(*** Unable to locate working posix thread library ***)
fi
AC_SUBST(PTHREAD_LIBS)

dnl *** OpenGL
AC_ARG_ENABLE( opengl,
[  --disable-opengl        Disable OpenGL plugin(s) [default=enabled]],,
		enable_opengl="yes")

if test "x$enable_opengl" = xyes; then
	LIBS_save=$LIBS
	LIBS="$LIBS $GTK_LIBS"
	OPENGL_LIBS=error
	AC_CHECK_LIB(GL, glBegin, OPENGL_LIBS="-lGL")

	if test "x$OPENGL_LIBS" = xerror; then
		AC_CHECK_LIB(MesaGL, glBegin,OPENGL_LIBS="-lMesaGL")
	fi

	CPPFLAGS_save=$CPPFLAGS
	CPPFLAGS="$GTK_CFLAGS $CPPFLAGS"
	have_opengl_headers=yes
	AC_CHECK_HEADERS(GL/gl.h GL/glx.h,,have_opengl_headers=no)

	if test "x$OPENGL_LIBS" = xerror || test "x$have_opengl_headers" = xno; then
		have_opengl=no
	else
		have_opengl=yes
	fi

	CPPFLAGS=$CPPFLAGS_save
	LIBS=$LIBS_save
else
	AC_MSG_RESULT([*** Disabling OpenGL plugins per user request ***])
	have_opengl=no
fi

AC_SUBST(OPENGL_LIBS)

AM_CONDITIONAL(HAVE_OPENGL, test "x$have_opengl" = xyes)


dnl *** zlib
LIBS_save=$LIBS
Z_LIBS=""
AC_CHECK_LIB(z, inflate, [Z_LIBS="-lz"
                          AC_DEFINE(HAVE_LIBZ,,[Define if zlib is available])])
AC_SUBST(Z_LIBS)
LIBS=$LIBS_save

dnl *** esound
AC_ARG_ENABLE( esd,
[  --disable-esd           Disable esound output plugin [default=enabled]],,
		enable_esd="yes")

if test "x$enable_esd" = xyes; then
	AM_PATH_ESD(0.2.8, 
	   [have_esd=yes 
	    AC_CHECK_LIB(esd, esd_get_latency, 
	       AC_DEFINE(HAVE_ESD_GET_LATENCY,,
		  [Define if libesd has the esd_get_latency function]))], 
	   have_esd=no)
else
	AC_MSG_RESULT([*** esound plugin disabled per user request ***])
	have_esd=no
fi

AM_CONDITIONAL(HAVE_ESD,test "x$have_esd" = xyes)

dnl *** mikmod
AC_ARG_ENABLE( mikmod,
[  --disable-mikmod        Disable mikmod input plugin [default=enabled]],,
		enable_mikmod="yes")

if test "x$enable_mikmod" = xyes; then
	AM_PATH_LIBMIKMOD(3.1.5,have_mikmod=yes, have_mikmod=no)
else
	AC_MSG_RESULT([*** mikmod plugin disabled per user request ***])
	have_mikmod=no
fi
AM_CONDITIONAL(HAVE_MIKMOD,test "x$have_mikmod" = xyes)

dnl *** Ogg Vorbis
AC_ARG_ENABLE( vorbis,
[  --disable-vorbis        Disable Ogg Vorbis input plugin [default=enabled]],,
		enable_vorbis="yes")

if test "x$enable_vorbis" = xyes; then
	XIPH_PATH_OGG(have_ogg=yes, have_ogg=no)
	XIPH_PATH_VORBIS(have_vorbis=yes, have_vorbis=no)
	if test "x$have_vorbis" = xyes; then
	  AC_MSG_CHECKING(if Vorbis is sufficiently new)
	  CFLAGS_save=$CFLAGS
	  LIBS_save=$LIBS
	  CFLAGS="$CFLAGS $VORBIS_CFLAGS $OGG_CFLAGS"
	  LIBS="$LIBS $VORBIS_LIBS $OGG_LIBS"
	  AC_TRY_COMPILE(
		[#include <vorbis/vorbisfile.h>],
		[OggVorbis_File vf;
		 float **pcm;
		 ov_read_float(&vf, &pcm, 1024, 0);],
		[AC_MSG_RESULT(yes)],
		[AC_MSG_RESULT([no (need atleast 1.0)])
		 have_vorbis=no])
	  CFLAGS=$CFLAGS_save
	  LIBS=$LIBS_save
	fi
	have_oggvorbis=no
	if test "x$have_ogg" = xyes
	then
	  if test "x$have_vorbis" = xyes
	  then
	    have_oggvorbis=yes
	  fi
	fi
else
	AC_MSG_RESULT([*** Ogg Vorbis plugin disabled per user request ***])
	have_oggvorbis=no
fi
AM_CONDITIONAL(HAVE_OGGVORBIS,test $have_oggvorbis = yes)

dnl *** Thread-safe xlib check
CFLAGS_save=$CFLAGS
LIBS_save=$LIBS
CFLAGS="$CFLAGS $GTK_CFLAGS"
LIBS="$LIBS $GTK_LIBS"
AC_CACHE_CHECK(for thread-safe Xlib, xmms_cv_lib_xlibs_threadsafe,
[AC_TRY_RUN([
#include <X11/Xlib.h>
int main()
{
   exit(!(XInitThreads()));
}],
xmms_cv_lib_xlibs_threadsafe=yes,
xmms_cv_lib_xlibs_threadsafe=no,
xmms_cv_lib_xlibs_threadsafe=yes)])
CFLAGS=$CFLAGS_save
LIBS=$LIBS_save

dnl This is just a copy of po/LINGUAS and is here to avoid breaking
dnl compatibility with automake 1.4

ALL_LINGUAS="af az be bg bs ca cs cy da de el en eo es et eu fi fr ga gl hr hu id it ja ka ko lt lv mk ms nn nl no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv tg th tr uk uz vi wa zh_CN zh_TW"

AM_GNU_GETTEXT

localedir=${datadir}/locale
AC_SUBST(localedir)

dnl If {type}_PLUGINS is defined, it should be a comma or space separated
dnl list of plugins that should be built, e.g.,
dnl INPUT_PLUGINS="mpg123,cdaudio cdin".  If variable is not defined, all
dnl buildable plugins are compiled.  This stuff makes life easier for
dnl automated builds that want to disable certain plugins.

for class in EFFECT GENERAL INPUT OUTPUT VISUALIZATION; do
    value=`eval echo "\\$${class}_PLUGINS"`
    if test "x${value}" = x; then
       eval ${class}_PLUGINS="\$\(ALL_PLUGINS\)"
    else
       value=`echo ${value} | sed -e 's/,/ /g'`
       eval ${class}_PLUGINS="\${value}"
    fi
done

AC_SUBST(EFFECT_PLUGINS)
AC_SUBST(GENERAL_PLUGINS)
AC_SUBST(INPUT_PLUGINS)
AC_SUBST(OUTPUT_PLUGINS)
AC_SUBST(VISUALIZATION_PLUGINS)


dnl x86 SIMD(3DNow!/MMX) instructions support
dnl ========================
AC_ARG_ENABLE(simd,
	[  --enable-simd           build with x86 SIMD(3DNow!/MMX) instructions support (default=no)],
			USE_SIMD=$enableval, USE_SIMD=no)
if test "x$USE_SIMD" = xyes; then
  AC_DEFINE(USE_SIMD, , [Define if building with ia32 SIMD support])
fi
AM_CONDITIONAL(USE_SIMD,test "x$USE_SIMD" = xyes)
AC_SUBST(USE_SIMD_TRUE)
dnl ========================

dnl IPv6 support
AC_ARG_ENABLE(ipv6,
	[  --enable-ipv6           enable IPv6 support (default=no)],
			enable_ipv6=$enableval, enable_ipv6=no)
if test "x$enable_ipv6" = xyes; then
    AC_DEFINE(USE_IPV6, , [Define if building with ipv6 support])
fi
AM_CONDITIONAL(USE_IPV6,test "x$enable_ipv6" = xyes)
AC_SUBST(USE_IPV6)


AC_CACHE_CHECK(for socklen_t, xmms_cv_type_socklen_t,
[AC_TRY_COMPILE(
[#include <sys/types.h>
#include <sys/socket.h>],
[socklen_t s;], xmms_cv_type_socklen_t=yes, xmms_cv_type_socklen_t=no)])
if test "x$xmms_cv_type_socklen_t" = "xno"; then
  AC_DEFINE(socklen_t, int, [Define to int if the socklen_t type is missing])
fi