exportopml_frm.pas

自己写的一个 RSS 阅读器

unit ExportOPML_Frm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, JvWizard, JvExControls, JvComponent, StdCtrls,
  JvExStdCtrls, JvHtControls, ComCtrls, Mask, JvExMask, JvToolEdit,
  JvExComCtrls, JvListView,uOpml;

type
  TfmExportOPML = class(TForm)
    JvWizard1: TJvWizard;
    Panel1: TPanel;
    JvWizardInteriorPage1: TJvWizardInteriorPage;
    JvWizardInteriorPage2: TJvWizardInteriorPage;
    JvWizardInteriorPage3: TJvWizardInteriorPage;
    Image1: TImage;
    JvHTLabel1: TJvHTLabel;
    JvHTLabel2: TJvHTLabel;
    JvFilenameEdit1: TJvFilenameEdit;
    JvHTLabel3: TJvHTLabel;
    OpmlListView: TJvListView;
    procedure FormCreate(Sender: TObject);
    procedure JvWizardInteriorPage1NextButtonClick(Sender: TObject;
      var Stop: Boolean);
    procedure OpmlListViewAdvancedCustomDrawItem(Sender: TCustomListView;
      Item: TListItem; State: TCustomDrawState; Stage: TCustomDrawStage;
      var DefaultDraw: Boolean);
    procedure JvWizardInteriorPage2NextButtonClick(Sender: TObject;
      var Stop: Boolean);
    procedure JvWizardInteriorPage3FinishButtonClick(Sender: TObject;
      var Stop: Boolean);
  private
    ExpOPML:TOpmlType;
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmExportOPML: TfmExportOPML;

procedure ExportOPML;

implementation

uses uMain,uHTMLMessage;

{$R *.dfm}

procedure ExportOPML;
var ExpOpml:TfmExportOPML;
begin
  ExpOpml := TfmExportOPML.Create(nil);
  try
    ExpOpml.ShowModal;
  finally // wrap up
    ExpOpml.Free;
  end;    // try/finally
end;

procedure TfmExportOPML.FormCreate(Sender: TObject);
begin
  Image1.Picture.Bitmap.Handle := LoadBitmap(HInstance,'NEWFEEDSIDE');
end;

procedure TfmExportOPML.JvWizardInteriorPage1NextButtonClick(
  Sender: TObject; var Stop: Boolean);
var i:Integer;
begin
  for i := 0 to Mainwindow.FeedList.Count -1 - 1 do    // Iterate
  with Mainwindow.FeedList do
  begin
    if Item[i].Outline.Type_<>'folder' then
    with OpmlListView.Items.Add do
    begin
        Checked := true;
        SubItems.Add(Item[i].Outline.Title);
        SubItems.Add(Item[i].Outline.XmlUrl);
        SubItems.Add(Item[i].Outline.Description);
        SubItems.Add(Item[i].Outline.HtmlUrl);
    end;
  end;    // for
end;

procedure TfmExportOPML.OpmlListViewAdvancedCustomDrawItem(
  Sender: TCustomListView; Item: TListItem; State: TCustomDrawState;
  Stage: TCustomDrawStage; var DefaultDraw: Boolean);
begin
  case Item.Index mod 2 = 0 of    //
    true : Sender.Canvas.Brush.Color := clWhite;
    false: Sender.Canvas.Brush.Color := RGB(245,245,245);
  end;    // case
  if item.Checked then
    Sender.Canvas.Brush.Color := RGB(196,196,255);
end;

procedure TfmExportOPML.JvWizardInteriorPage2NextButtonClick(
  Sender: TObject; var Stop: Boolean);
var i,chkCount:Integer;
begin
  chkCount := 0;
  for i := 0 to OpmlListView.Items.Count - 1 do    // Iterate
  begin
    if OpmlListView.Items.Item[i].Checked then
      Inc(chkCount);
  end;    // for
  if chkCount=0 then
  begin
    Stop := True;
    HTMLMessage('Error','Please select at least one channle.',False);
    Exit;
  end;

  Stop := not JvFilenameEdit1.Dialog.Execute;
  if not Stop then
    JvFilenameEdit1.FileName := JvFilenameEdit1.Dialog.FileName;
end;

procedure TfmExportOPML.JvWizardInteriorPage3FinishButtonClick(
  Sender: TObject; var Stop: Boolean);
var resStream:TResourceStream;
  i:Integer;
begin

  resStream:=TResourceStream.Create(HInstance, 'OPMLXML', 'XML');
  try
    resStream.SaveToFile(JvFilenameEdit1.FileName);
  finally
    resStream.Free;
  end;
  ExpOPML := Loadopml(JvFilenameEdit1.FileName);
  for i := 0 to OpmlListView.Items.Count - 1 do    // Iterate
  if OpmlListView.Items.Item[i].Checked then
    with ExpOPML.Body.Items.Add('outline'),OpmlListView.Items.Item[i] do
    begin
      Title := SubItems.Strings[0];
      XmlUrl := SubItems.Strings[1];
      Description :=SubItems.Strings[2];
      HtmlUrl :=SubItems.Strings[3];
    end;    // for
  ExpOPML.Save(JvFilenameEdit1.FileName);
end;

end.