weld ansysis by element birth and death.txt

我做的一些ansys的练习,命令流,对学习ansys很有帮助

/BATCH
/title,weld ansysis by "element birth and death"
/prep7
/unit,si
et,1,13,4
et,2,13,4
MPTEMP,,,,,,,,  
MPTEMP,1,20 
MPTEMP,2,500
MPTEMP,3,800
MPTEMP,4,1200   
MPTEMP,5,1500   
MPDATA,EX,1,,2.09e11
MPDATA,EX,1,,1.72e11
MPDATA,EX,1,,1.33e11
MPDATA,EX,1,,0.84e11
MPDATA,EX,1,,0.45e11
MPDATA,PRXY,1,,0.3  
MPDATA,PRXY,1,,0.3  
MPDATA,PRXY,1,,0.3  
MPDATA,PRXY,1,,0.3  
MPDATA,PRXY,1,,0.3 
MPTEMP,,,,,,,,  
MPTEMP,1,20 
MPTEMP,2,500
MPTEMP,3,800
MPTEMP,4,1200   
MPTEMP,5,1500   
MPDATA,EX,2,,2.16e11
MPDATA,EX,2,,1.78e11
MPDATA,EX,2,,1.42e11
MPDATA,EX,2,,1.04e11
MPDATA,EX,2,,0.68e11
MPDATA,PRXY,2,,0.29 
MPDATA,PRXY,2,,0.29 
MPDATA,PRXY,2,,0.29 
MPDATA,PRXY,2,,0.29 
MPDATA,PRXY,2,,0.29 
MPTEMP,,,,,,,,  
MPTEMP,1,20 
MPTEMP,2,500
MPTEMP,3,800
MPTEMP,4,1200   
MPTEMP,5,1500   
MPDATA,EX,3,,2.12e11
MPDATA,EX,3,,1.75e11
MPDATA,EX,3,,1.39e11
MPDATA,EX,3,,1.07e11
MPDATA,EX,3,,0.83e11
MPDATA,PRXY,3,,0.3  
MPDATA,PRXY,3,,0.3  
MPDATA,PRXY,3,,0.3  
MPDATA,PRXY,3,,0.3  
MPDATA,PRXY,3,,0.3 
TB,BKIN,1,5
TBTEMP,20,1   
TBDATA,1,0.315e9,2.09e10
TBTEMP,500,2  
TBDATA,1,0.212e9,1.72e10
TBTEMP,800,3  
TBDATA,1,0.153e9,1.33e10
TBTEMP,1200,4 
TBDATA,1,0.093e9,0.84e10
TBTEMP,1500,5 
TBDATA,1,0.033e9,0.45e10
TB,BKIN,2,5
TBTEMP,20,1   
TBDATA,1,0.314e9,2.16e10
TBTEMP,500,2  
TBDATA,1,0.203e9,1.78e10
TBTEMP,800,3  
TBDATA,1,0.153e9,1.42e10
TBTEMP,1200,4 
TBDATA,1,0.063e9,0.104e10
TBTEMP,1500,5 
TBDATA,1,0.013e9,0.68e10
TB,BKIN,3,5
TBTEMP,20,1   
TBDATA,1,0.33e9,2.12e10
TBTEMP,500,2  
TBDATA,1,0.213e9,1.75e10
TBTEMP,800,3  
TBDATA,1,0.153e9,1.39e10
TBTEMP,1200,4 
TBDATA,1,0.073e9,0.107e10
TBTEMP,1500,5 
TBDATA,1,0.013e9,0.83e10
mp,dens,1,7850
mp,dens,2,7770
mp,dens,3,7860
mp,alpx,1,1.23e-5
mp,alpx,2,1.38e-5
mp,alpx,3,1.48e-5
mp,kxx,1,33
mp,kxx,2,32
mp,kxx,3,34
mp,c,1,561
mp,c,2,683
mp,c,3,983
mp,murx,1,1
mp,murx,2,1
mp,murx,3,1
mp,reft,1,20
mp,reft,2,1500
mp,reft,3,20

*afun,deg
csys,0
width=1
height=0.3
ar=0.14*tan(30)
ex=0.01*tan(60)
df=ar+ex
cf=df/cos(60)

k,1,0,0,0
k,2,width/2-0.01-ar,0,0
k,3,width/2+0.01+ar,0,0
k,4,width,0,0
k,5,width/2-0.01,height/2-0.01,0
k,6,width/2+0.01,height/2-0.01,0
k,7,width/2-0.01,height/2+0.01,0
k,8,width/2+0.01,height/2+0.01,0
k,9,0,height,0
k,10,width/2-0.01-ar,height,0
k,11,width/2+0.01+ar,height,0
k,12,width,height,0

n,1,width/2+0.01+ar,height,0
n,2,width,height,0
n,3,width/2+0.01+ar,0,0

larc,10,11,7,cf
larc,2,3,5,cf
a,1,2,5,7,10,9
a,10,7,5,2,3,6,8,11
a,3,4,12,11,8,6

/triad,off
/plots,info,0
/devices,vector,1

esize,0.03
type,2
mat,2
amesh,2
esize,0.03
type,1
mat,1
amesh,1
mat,3
amesh,3
nummrg,all,,,,low
numcmp,all
eplot
/image,save,vmesh,bmp
/devices,vector,0
finish



/SOLU
ANTYPE,4
TRNOPT,FULL
NSEL,ALL
neqit,100
*GET,minx,NODE,,MNLOC,X
NSEL,S,LOC,X,minx
D,ALL,UX,0
*GET,miny,NODE,,MNLOC,Y
NSEL,S,LOC,Y,miny
D,ALL,UY,0

NSEL,ALL
*GET,minx,NODE,,MNLOC,X
NSEL,S,LOC,X,minx
D,ALL,TEMP,20
NSEL,ALL
*GET,maxx,NODE,,MXLOC,X
NSEL,S,LOC,X,maxx
D,ALL,TEMP,20

*SET,nna,2
ESEL,ALL
*GET,emax,ELEM,,NUM,MAX
ASEL,S,AREA,,nna
ESLA
*GET,nse,ELEM,,COUNT
*DIM,ne,,nse
*DIM,n1,,nse
*DIM,n2,,nse
*DIM,nex,,nse
*DIM,ney,,nse
*DIM,neorder,,nse

ii=0
*DO,i,1,emax
*IF,ESEL(i),EQ,1,THEN
ii=ii+1
ne(ii)=i
*ENDIF
*ENDDO

*DO,i,1,nse
*GET,ney(i),ELEM,ne(i),CENT,Y
*GET,nex(i),ELEM,ne(i),CENT,X
*ENDDO

d=0
*DO,i,1,nse
*IF,ney(i),GE,height/2,THEN
d=d+1
n2(d)=ne(i)
*ENDIF
*ENDDO

c=0
*DO,i,1,nse
*IF,ney(i),LT,height/2,THEN
c=c+1
n1(c)=ne(i)
*ENDIF
*ENDDO

ESEL,NONE
*DO,i,1,d
*IF,n2(i),NE,0,THEN
ESEL,A,ELEM,,n2(i)
*ENDIF
*ENDDO
EPLOT

mine=0
*DIM,ne2,,d
*DIM,nex2,,d
*DIM,ney2,,d
*DO,i1,1,d
ESEL,U,ELEM,,mine
*GET,nse2,ELEM,,COUNT
ii=0
*DO,i,1,emax
*IF,ESEL(i),EQ,1,THEN
ii=ii+1
ne2(ii)=i
*ENDIF
*ENDDO
*DO,i,1,nse2
*GET,ney2(i),ELEM,ne2(i),CENT,Y
*GET,nex2(i),ELEM,ne2(i),CENT,X
*ENDDO

miny=1e20
minx=1e20

*DO,i,1,nse2
*IF,ney2(i),LT,miny,THEN
miny=ney2(i)
minx=nex2(i)
mine=ne2(i)
*ELSE
*IF,ney2(i),EQ,miny,THEN
*IF,nex2(i),LT,minx,THEN
miny=ney2(i)
minx=nex2(i)
mine=ne2(i)
*ENDIF
*ENDIF
*ENDIF
*ENDDO
neorder(i1)=mine
*ENDDO

maxe=0
ESEL,NONE
*DO,i,1,c
*IF,n1(i),NE,0,THEN
ESEL,A,ELEM,,n1(i)
*ENDIF
*ENDDO
EPLOT

*DIM,ne1,,c
*DIM,nex1,,c
*DIM,ney1,,c

*DO,i1,1,c
ESEL,U,ELEM,,maxe
*GET,nse3,ELEM,,COUNT
ii=0
*DO,i,1,emax
*IF,ESEL(i),EQ,1,THEN
ii=ii+1
ne1(ii)=i
*ENDIF
*ENDDO

*DO,i,1,nse3
*GET,ney1(i),ELEM,ne1(i),CENT,Y
*GET,nex1(i),ELEM,ne1(i),CENT,X
*ENDDO

maxy=-1e10
maxx=-1e10
*DO,i,1,nse3
*IF,ney1(i),GT,maxy,THEN
maxy=ney1(i)
maxx=nex1(i)
maxe=ne1(i)
*ELSE
*IF,ney1(i),EQ,maxy,THEN
*IF,nex1(i),LT,maxx,THEN
maxy=ney1(i)
maxx=nex1(i)
maxe=ne1(i)
*ENDIF
*ENDIF
*ENDIF
*ENDDO
neorder(i1+d)=maxe
*ENDDO

max_tem=1500
dt1=1e-3
dt=5
t=0
ESEL,ALL
EPLOT
/AUTO,1
/REPLOT
*DO,i,1,nse
EKILL,neorder(i)
ESEL,S,LIVE
EPLOT
*ENDDO
ALLSEL,ALL
OUTRES,ALL,ALL
IC,ALL,TEMP,20
KBC,1
TIMINT,0,STRUCT
TIMINT,1,THERM
TIMINT,0,MAG
TINTP,0.005,,,1,0.5,0.2

nsub1=2
nsub2=40
*DO,i,1,nse
EALIVE,neorder(i)
ESEL,S,LIVE
EPLOT
ESEL,ALL
t=t+dt1
TIME,t
NSUBST,1
*DO,j,1,4
D,NELEM(neorder(i),j),TEMP,max_tem
*ENDDO
SOLVE
t=t+dt1
TIME,t
SOLVE
*DO,j,1,4
DDELE,NELEM(neorder(i),j),TEMP
*ENDDO
t=t+dt-2*dt1
TIME,t
NSUBST,nsub1
SOLVE
*ENDDO
t=t+50000
TIME,t
NSUBST,nsub2
SOLVE
FINISH