热电耦合.txt

ansys.com上的ansys命令流,主要为热,流体,接触分析方面的内容

首先建议看 VM215

再看看 VM173

VM215的apdl

/COM,ANSYS MEDIA REL. 8.0 (9-17-2003) REF. VERIF. MANUAL: REL. 8.0
/VERIFY,VM215
/PREP7
/TITLE,VM215, CONDUCTING SPHERE
ET,1,157              
R,1,0.2               ! THICKNESS = 0.2
MP,RSVX,,7            ! DEFINE ELECTRICAL RESISTIVITIES PROPERTY 
MP,KXX,,3             ! DEFINE THERMAL CONDUCTIVITIES PROPERTY
CSYS,2                ! SPHERICAL COORDINATE SYSTEM
N,1,10                ! 10 UNIT RADIUS SPHERE
N,21,10,,80           ! 10 DEGREE HOLE AT THE TOP
FILL,,, ,,, ,,0.1     ! SHIFT ELEMENTS TOWARD HOLE
NGEN,2,30,1,21,1,,3   ! ANALYSE A 3 DEGREE SECTOR
E,1,2,32,31           ! DEFINE ELEMENT
EGEN,20,1,-1          ! USE 20 ELEMENTS
CP,1,VOLT,1,31
CP,2,TEMP,1,31
CP,3,VOLT,21,51
CP,4,TEMP,21,51
FINISH
/SOLU
OUTPR,,1
D,21,ALL              ! SET ALL VOLTAGES AND TEMPERATURES AT THE HOLE TO ZERO
D,1,VOLT,100          ! SET VOLTAGE AT THE EQUATOR TO 100
SOLVE
FINISH
/POST1
PRRSOL,AMPS           ! PRINTS THE CONSTRAINED NODE REACTION AT CURRENT FLOW
PRRSOL,HEAT           ! PRINTS THE CONSTRAINED NODE REACTION AT HEAT FLOW
NSEL,S,NODE,,21,51,30
FSUM
*GET,I21,FSUM,0,ITEM,AMPS
*GET,H21,FSUM,0,ITEM,HEAT
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'I AMPS ','Q WATT'
LABEL(1,2) = 'NODE 21','NODE 21'
*VFILL,VALUE(1,1),DATA,0.0614,6.14058
*VFILL,VALUE(1,2),DATA,I21,H21
*VFILL,VALUE(1,3),DATA,(I21/0.0614),(H21/6.14058)
/COM
/OUT,vm215,vrt
/COM,------------------- VM215 RESULTS COMPARISON --------------------------
/COM,
/COM,      SHELL157    |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A9,A8,'     ',F7.5,'     ',F7.5,'     ',1F5.3)
/COM,------------------------------------------------------------------------
/OUT
FINISH
*LIST,vm215,vrt

对后VM215处理部分的注释

/POST1 
PRRSOL,AMPS ! 显示节点反力——电流 

PRRSOL,HEAT ! 显示节点反力——热流 
NSEL,S,NODE,,21,51,30 ! 仅选中21、51两个节点 
FSUM ! 合成单元的节点反力（AMPS,HEAT）结果 
*GET,I21,FSUM,0,ITEM,AMPS ! 节点21的电流给变量 I21 
*GET,H21,FSUM,0,ITEM,HEAT ! 节点21的热流给变量 H21 
*DIM,LABEL,CHAR,2,2 ! 定义字符串数组LABLE 
*DIM,VALUE,,2,3 ! 定义2x3数组VALUE 
LABEL(1,1) = 'I AMPS ','Q WATT' ! 这五句给这两个数组赋初值 
LABEL(1,2) = 'NODE 21','NODE 21' 
*VFILL,VALUE(1,1),DATA,0.0614,6.14058 
*VFILL,VALUE(1,2),DATA,I21,H21 
*VFILL,VALUE(1,3),DATA,(I21/0.0614),(H21/6.14058) 
/COM ! 为了好看，像用FORTRAN一样打出结果 
/OUT,vm215,vrt ! 输出到vm215.vrt文件 
/COM,------------------- VM215 RESULTS COMPARISON -------------------------- 
/COM, 
/COM, SHELL157 | TARGET | ANSYS | RATIO 
/COM, 
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3) 
(1X,A9,A8,' ',F7.5,' ',F7.5,' ',F5.3) 
/COM,------------------------------------------------------------------------ 
/OUT 
FINISH 
*LIST,vm215,vrt ! 显示vm215.vrt的内容


VM173的apdl

/COM,ANSYS MEDIA REL. 8.0 (9-17-2003) REF. VERIF. MANUAL: REL. 8.0
/VERIFY,VM173
/PREP7
/TITLE, VM173, CENTERLINE TEMPERATURE OF AN ELECTRICAL WIRE
C***      HEAT, MASS AND MOMENTUM TRANS., ROHSENOW AND CHOI, 2ND. PR., PAGE 106,
C***      EX. 6.5, USING SOLID5 ELEMENTS
ET,1,SOLID5,1                    ! SOLID5, TEMP,VOLT,MAG DOF OPTION
MP,KXX,1,13                      ! THERMAL CONDUCTIVITY
MP,RSVX,1,8.983782E-8            ! ELECTRICAL RESISTIVITY
CSYS,1
N,1,1E-10,-5                     ! MOVE AWAY FROM ORIGIN FOR THETA SPEC.
N,6,.03125,-5
FILL
NGEN,2,10,1,6,1,,10              ! MODEL 10 DEG. SECTOR
NGEN,2,20,1,16,1,,,-(1/12)       ! ARBITRARY Z-LENGTH OF 1 INCH
NUMMRG,NODE                      ! MERGE COINCIDENT NODES AT ORIGIN
E,2,12,1,1,22,32,21,21           ! GENERATE ELEMENTS
E,2,3,13,12,22,23,33,32
EGEN,4,1,2
CP,1,TEMP,1,21                   ! COUPLING TO ENSURE AXIAL SYMMETRY
CP,2,TEMP,2,12,22,32             ! COUPLING TO ENSURE CIRCUMFERENTIAL SYMMETRY
CPSGEN,5,1,2
NSEL,S,LOC,Z,0
D,ALL,VOLT,0                     ! SET VOLTAGES
NSEL,INVE
D,ALL,VOLT,-(.1/12)              ! .1 VOLT/FT OVER 1 IN LENGTH
NSEL,S,LOC,X,.03125
SF,ALL,CONV,5,70
NSEL,ALL
FINISH
/SOLU    
SOLVE
FINISH
/POST1
NSEL,S,LOC,X,0
PRNSOL,TEMP                      ! RESULTS AT CENTERLINE
*GET,T,NODE,1,TEMP
NSEL,S,LOC,X,.03125
PRNSOL,TEMP                      ! RESULTS AT OUTER RADIUS
*GET,TEMP,NODE,6,TEMP        ! GET TEMPERATURE AT SURFACE NODE
PI=2*ASIN(1)
LENG=2*(0.375/12)*SIN(PI/36) ! LENGTH ALONG 10 DEG ON OUTER FACE
AREA=LENG*36                 ! COMPUTE AREA OF OUTER FACE (360 DEG)
HRATE=AREA*5.0*(TEMP-70)     ! TOTAL HEAT DISSIPATION RATE
*status,parm                      ! SHOW PARAMETER STATUS
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'T(CL) ','T(S) ','Q '
LABEL(1,2) = 'DEG F','DEG F','BTU/hr/ft'
*VFILL,VALUE(1,1),DATA,419.9,417.9,341.5
*VFILL,VALUE(1,2),DATA,T,TEMP,HRATE
*VFILL,VALUE(1,3),DATA,ABS(T/419.9),ABS(TEMP/417.9),ABS(HRATE/341.5)
/COM
/OUT,vm173,vrt
/COM,------------------- VM173 RESULTS COMPARISON -------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.1,'  ',F10.1,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT

FINISH
*LIST,vm173,vrt