移动温度载荷计算方法.txt

ansys.com上的ansys命令流,主要为热,流体,接触分析方面的内容

/com, units: SI, m - degree C - W - kg -sec - J 
! 
! Bi=h*dx/K = 60*0.002/51.9 = 0.0023 < 1 
! F0 = ( Kdt ) / (rho*C*dx^2) 
! assume F0= beta = 0.4 
! dt = (beta*rho*C*dx^2)/K = 0.1179 (sec) 
! 
/title,transient analysis 2 (moving heat flux) 
/filnam,transient-2 
! 
/triad,rbot 
! 
/prep7 
! 
wpstyle,,,,,,,,1 
wpstyle,0.01,0.01,0,0.1,0.003,0,1,,5 
! 
blc4,0,0.1,0.1,-0.1 !0.1*0.1 m 
cyl4,0.03,0.05,0.01 
asba, 1, 2 !drill a hole 
! 
blc4,0.1,0.1,-0.01,-0.1 
! 
flst,2,2,5,orde,2 
fitem,2,1 
fitem,2,3 
aovlap,p51x 
! 
wpstyle,,,,,,,,0 
aplot 
! 
et,1,plane55 
!* 
keyopt,1,1,0 
keyopt,1,3,0 !2d plane problem 
keyopt,1,4,0 
keyopt,1,8,0 
keyopt,1,9,0 
! 
!aisi 1045 steel 
! 
uimp,1,dens, , ,7870 , !kg/m3 
uimp,1,kxx, , , 51.9 , !w/m-c 
uimp,1,c, , , 486, !w-s / kg-c 
! 
type,1 
mat,1 
! 
esize,0.002, !element size = 0.002 m 
! 
mshkey,1 
amesh,1 
! 
mshkey,0 
amesh,2 
! 
!boundary conditions 
! 
/psf,hflu, ,2,0 
! 
!convection 
! 
flst,2,1,4,orde,1 
fitem,2,4 
sfl,p51x,conv,50, ,25, 
! 
finish 
! 
/solu 
! 
antype,trans 
trnopt,full 
nropt,auto, , 
eqslv, 
! 
solcontrol,on 
autots,on 
! 
kbc,1 !step 
outres,all,all, 
! 
!load step 1, initial conditions 25 c 
! 
time,0.001 
deltim,0.001,0.001,0.001 
timint,off !time integration = off 
tunif,25, 
solve 
! 
!load step 2..... , apply moving heat flux 
! 
timint,on !time integration = on 
! 
j=1 
! 
*do,i,200,80,-5 
! 
time,j 
deltim,0.11,0.11,0.11, 
! 
sfedele,i+5,2,hflux !delete heat flux of previous step 
! 
sfe,i,2,hflux, ,5/0.002/0.002, , , !apply heat flux, face 2 , 5 w 
! 
eplot 
! 
solve 
j=j+1 
*enddo 
! 
finish 
! 
/post1 
/eface,1 
set,last 
! 
plnsol,temp, ,0, 
finish