idhashmessagedigest.pas

photo.163.com 相册下载器 多线程下载

{ $HDR$}
{**********************************************************************}
{ Unit archived using Team Coherence                                   }
{ Team Coherence is Copyright 2002 by Quality Software Components      }
{                                                                      }
{ For further information / comments, visit our WEB site at            }
{ http://www.TeamCoherence.com                                         }
{**********************************************************************}
{}
{ $Log:  11605: IdHashMessageDigest.pas
{
{   Rev 1.3    24/01/2004 19:21:36  CCostelloe
{ Cleaned up warnings
}
{
{   Rev 1.2    1/15/2004 2:32:50 AM  JPMugaas
{ Attempt to add MD5 coder support for partial streams.  THis is needed for the
{ XMD5 command in the FTP Server.
}
{
{   Rev 1.1    2003-10-12 22:36:40  HHellstr鰉
{ Reimplemented, optimized and tested for both Win32 and dotNET.
}
{
{   Rev 1.0    11/13/2002 07:53:40 AM  JPMugaas
}
{

  Implementation of the MD2, MD4 and MD5 Message-Digest Algorithm
  as specified in RFC 1319 (1115), 1320 (1186), 1321

  Author: Henrick Hellstr鰉 <[e-mail]>

  Original Intellectual Property Statement:
    Author: Pete Mee
    Port to Indy 8.1 Doychin Bondzhev ([e-mail])
    Copyright: (c) Chad Z. Hower and The Winshoes Working Group.
}

unit IdHashMessageDigest;

interface

uses
  Classes,
  IdHash;

type
  T16x4LongWordRecord = array[0..15] of LongWord;
  T4x4x4LongWordRecord = array[0..3] of T4x4LongWordRecord;

  T512BitRecord = array [0..63] of byte;
  T384BitRecord = array [0..47] of byte;
  T128BitRecord = array [0..15] of byte;


  TIdHashMessageDigest = class(TIdHash128);

  TIdHashMessageDigest2 = class(TIdHashMessageDigest)
  protected
    FX: T384BitRecord;
    FCBuffer: T128BitRecord;
    FCheckSum: T128BitRecord;

    procedure MDCoder;
    procedure Reset;
  public
    function HashValue(AStream: TStream): T4x4LongWordRecord; override;
    function HashValue( AStream: TStream; const ABeginPos, AEndPos: Int64) : T4x4LongWordRecord; overload;
  end;

  TIdHashMessageDigest4 = class(TIdHashMessageDigest)
  protected
    FState: T4x4LongWordRecord;
    FCBuffer: T512BitRecord;

    procedure MDCoder; virtual;
  public
    function HashValue(AStream: TStream): T4x4LongWordRecord; override;
    function HashValue( AStream: TStream; const ABeginPos, AEndPos: Int64) : T4x4LongWordRecord; overload;
  end;

  TIdHashMessageDigest5 = class(TIdHashMessageDigest4)
  protected
    procedure MDCoder; override;
  public

  end;

implementation

{ TIdHashMessageDigest2 }

const
  MD2_PI_SUBST : array [0..255] of byte = (
     41,  46,  67, 201, 162, 216, 124,   1,  61,  54,  84, 161, 236, 240,
      6,  19,  98, 167,   5, 243, 192, 199, 115, 140, 152, 147,  43, 217,
    188,  76, 130, 202,  30, 155,  87,  60, 253, 212, 224,  22, 103,  66,
    111,  24, 138,  23, 229,  18, 190,  78, 196, 214, 218, 158, 222,  73,
    160, 251, 245, 142, 187,  47, 238, 122, 169, 104, 121, 145,  21, 178,
      7,  63, 148, 194,  16, 137,  11,  34,  95,  33, 128, 127,  93, 154,
     90, 144,  50,  39,  53,  62, 204, 231, 191, 247, 151,   3, 255,  25,
     48, 179, 72, 165,  181, 209, 215,  94, 146,  42, 172,  86, 170, 198,
     79, 184,  56, 210, 150, 164, 125, 182, 118, 252, 107, 226, 156, 116,
      4, 241,  69, 157, 112,  89, 100, 113, 135,  32, 134,  91, 207, 101,
    230,  45, 168,   2,  27,  96,  37, 173, 174, 176, 185, 246,  28,  70,
     97, 105,  52,  64, 126, 15,   85,  71, 163,  35, 221,  81, 175,  58,
    195,  92, 249, 206, 186, 197, 234,  38,  44,  83,  13, 110, 133,  40,
    132,   9, 211, 223, 205, 244, 65,  129,  77,  82, 106, 220,  55, 200,
    108, 193, 171, 250,  36, 225, 123,   8,  12, 189, 177,  74, 120, 136,
    149, 139, 227,  99, 232, 109, 233, 203, 213, 254,  59,   0,  29,  57,
    242, 239, 183,  14, 102,  88, 208, 228, 166, 119, 114, 248, 235, 117,
     75,  10,  49,  68,  80, 180, 143, 237,  31,  26, 219, 153, 141,  51,
     159,  17, 131, 20);

procedure TIdHashMessageDigest2.MDCoder;
const
  NumRounds = 18;
var
  x: Byte;
  i, j: Integer;
  T: Word;
  LCheckSumScore: Byte;
begin
  // Move the next 16 bytes into the second 16 bytes of X.
  for i := 0 to 15 do
  begin
    x := FCBuffer[i];
    FX[i + 16] := x;
    FX[i + 32] := x xor FX[i];
  end;

  { Do 18 rounds. }
  T := 0;
  for i := 0 to NumRounds - 1 do
  begin
    for j := 0 to 47 do
    begin
      T := FX[j] xor MD2_PI_SUBST[T];
      FX[j] := T and $FF;
    end;
    T := (T + i) and $FF;
  end;

  LCheckSumScore := FChecksum[15];
  for i := 0 to 15 do
  begin
    x := FCBuffer[i] xor LCheckSumScore;
    LCheckSumScore := FChecksum[i] xor MD2_PI_SUBST[x];
    FChecksum[i] := LCheckSumScore;
  end;
end;

// Clear Buffer and Checksum arrays
procedure TIdHashMessageDigest2.Reset;
var
  I: Integer;
begin
  for I := 0 to 15 do
  begin
    FCheckSum[I] := 0;
    FCBuffer[I] := 0;
    FX[I] := 0;
    FX[I+16] := 0;
    FX[I+32] := 0;
  end;
end;

function TIdHashMessageDigest2.HashValue(AStream: TStream): T4x4LongWordRecord;
Var
  LStartPos: Integer;
  LSize: Int64;
  Pad: Byte;
  I: Integer;
begin
  Reset;

  LStartPos := AStream.Position;
  LSize := AStream.Size - LStartPos;

  // Code the entire file in complete 16-byte chunks.
  while LSize - AStream.Position >= 16 do
  begin
    AStream.Read(FCBuffer, 16);
    MDCoder;
  end;

  LStartPos := AStream.Read(FCBuffer, 16);
  Pad := 16 - LStartPos;
  // Step 1
  for I := LStartPos to 15 do
    FCBuffer[I] := Pad;
  MDCoder;
  // Step 2
  for I := 0 to 15 do
    FCBuffer[I] := FCheckSum[I];
  MDCoder;

  for I := 0 to 3 do
    Result[I] := FX[I*4] +
                 (FX[I*4+1] shl 8) +
                 (FX[I*4+2] shl 16) +
                 (FX[I*4+3] shl 24);
end;

function TIdHashMessageDigest2.HashValue(AStream: TStream; const ABeginPos,
  AEndPos: Int64): T4x4LongWordRecord;
Var
  LStartPos: Integer;
  LSize: Int64;
  Pad: Byte;
  I: Integer;
begin
  Reset;
  AStream.Position := ABeginPos;
  LStartPos := AStream.Position;
  LSize := AStream.Size - LStartPos;
  if AEndPos < AStream.Size  then
  begin
    if AEndPos > 0 then
    begin
      LSize := AEndPos - LStartPos;
    end;
  end;
  // Code the entire file in complete 16-byte chunks.
  while LSize - AStream.Position >= 16 do
  begin
    AStream.Read(FCBuffer, 16);
    MDCoder;
  end;

  LStartPos := AStream.Read(FCBuffer, 16);
  Pad := 16 - LStartPos;
  // Step 1
  for I := LStartPos to 15 do
    FCBuffer[I] := Pad;
  MDCoder;
  // Step 2
  for I := 0 to 15 do
    FCBuffer[I] := FCheckSum[I];
  MDCoder;

  for I := 0 to 3 do
    Result[I] := FX[I*4] +
                 (FX[I*4+1] shl 8) +
                 (FX[I*4+2] shl 16) +
                 (FX[I*4+3] shl 24);
end;

{ TIdHashMessageDigest4 }

const
  MD4_INIT_VALUES: T4x4LongWordRecord = (
    $67452301, $EFCDAB89, $98BADCFE, $10325476);

{$Q-} // Arithmetic operations performed modulo $100000000
{ TODO : Remove ROL and add IdGlobal to the uses clause, when it is ready for dotNET. }
function ROL(AVal: LongWord; AShift: Byte): LongWord;
begin
   Result := (AVal shl AShift) or (AVal shr (32 - AShift));
end;

procedure TIdHashMessageDigest4.MDCoder;
var
  A, B, C, D, i : LongWord;
  buff : T16x4LongWordRecord; // 64-byte buffer
begin
  A := FState[0];
  B := FState[1];
  C := FState[2];
  D := FState[3];

  for i := 0 to 15 do
    buff[i] := FCBuffer[i*4+0] +
               (FCBuffer[i*4+1] shl 8) +
               (FCBuffer[i*4+2] shl 16) +
               (FCBuffer[i*4+3] shl 24);

  // Round 1
  { Note:
      (x and y) or ( (not x) and z)
    is equivalent to
      (((z xor y) and x) xor z)
    -HHellstr鰉 }
  for i := 0 to 3 do
  begin