frmmajor.frm

VB+access学生信息管理系统,基本完成了学生信息的添加,修改,打印,查询功能.大家互相学习吧.

         BeginProperty Column00 
         EndProperty
         BeginProperty Column01 
         EndProperty
      EndProperty
   End
End
Attribute VB_Name = "frmMajor"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Dim cn As New ADODB.Connection  '连接对象
Dim DataEdited As Boolean  '数据已编辑标志
Dim bFirstStart As Boolean '窗体首次启动的标志

Private Sub Form_Load()
Dim msql$, mrs As ADODB.Recordset
    '窗体中心定位
    Call CenterPos(StudentMIS, Me)
    Call SetAdc
    DataEdited = False
    bFirstStart = True
    '填充学院组合框
    msql$ = "select * from institute order by institute_id asc"
    Set mrs = ExecuteSQL(msql)
    Call ADDComboListRS(xyComb, mrs, True, "institute_name", "institute_id")
End Sub

'窗体调整尺寸事件
Private Sub Form_Resize()
On Error Resume Next
Const gl As Integer = 50 '间隙常数
    SSPanel1.Left = gl
    SSPanel1.Width = Me.ScaleWidth - 2 * gl
    SSPanel2.Left = (Me.ScaleWidth - SSPanel2.Width) / 2
    DataGrid1.Left = gl
    DataGrid1.Width = Me.ScaleWidth - 2 * gl
    DataGrid1.Height = Me.ScaleHeight - DataGrid1.Top - StatBar.Height - 2 * gl
    '只有第一次调整窗体尺寸时才执行以下代码
    If bFirstStart Then
        DataGrid1.Refresh
        Adodc1.Refresh
        Set cn = Adodc1.Recordset.ActiveConnection '获取当前记录集的连接对象
        cn.BeginTrans '开始事务
        bFirstStart = False
    End If
End Sub

'DataGrid内部错误处理
Private Sub DataGrid1_Error(ByVal DataError As Integer, Response As Integer)
    If DataError = 7007 Then
        MsgBox "所输字符数超过允许输入字符最大个数，参见状态栏提示！", _
               vbCritical, "错误提示"
        Response = 0
    ElseIf DataError = 7008 Then
        Adodc1.Recordset.AddNew
        Response = 0
    End If
End Sub

'设置ADO数据控件的连接属性和记录源属性
Private Sub SetAdc()
    Adodc1.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" _
                             & StudentDBfile & ";Persist Security Info=False"
    Adodc1.RecordSource = "select institute_id as 学院代码,major_id as 专业代码," & _
                          "major_name as 专业名称" _
                          & " from major order by institute_id asc,major_id asc"
End Sub

Private Sub Adodc1_FieldChangeComplete(ByVal cFields As Long, Fields As Variant, _
            ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, _
            ByVal pRecordset As ADODB.Recordset)
'字段改变完成后触发的事件
    DataEdited = True
End Sub

Private Sub Adodc1_RecordChangeComplete(ByVal adReason As ADODB.EventReasonEnum, _
            ByVal cRecords As Long, ByVal pError As ADODB.Error, _
            adStatus As ADODB.EventStatusEnum, ByVal pRecordset As ADODB.Recordset)
'记录改变完成后触发的事件
    Select Case adReason
    Case adRsnDelete, adRsnUpdate, adRsnAddNew
        DataEdited = True
    End Select
End Sub

Private Sub Adodc1_RecordsetChangeComplete(ByVal adReason As ADODB.EventReasonEnum, _
            ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, _
            ByVal pRecordset As ADODB.Recordset)
'记录集改变完成后触发的事件
    Select Case adReason
    Case adRsnAddNew, adRsnDelete, adRsnAddNew
        DataEdited = True
    End Select
End Sub

'当前单元位置改变事件
Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
Dim dbrow As Long, s1$, s2$, s3$
'确定记录指针
On Error Resume Next
With Adodc1.Recordset
    If .RecordCount = 0 Then
      dbrow = .RecordCount
    Else
      dbrow = .AbsolutePosition
    End If
    s1 = "当前记录位置：" & dbrow
    s2 = "记录总数：" & Adodc1.Recordset.RecordCount
    s3 = "提示：" & Adodc1.Recordset.Fields(DataGrid1.Col).Name & "最多只允许输入" & _
         Adodc1.Recordset.Fields(DataGrid1.Col).DefinedSize & "位字符！"
    StatBar.Panels(1).Text = s1
    StatBar.Panels(2).Text = s2
    StatBar.Panels(3).Text = s3
End With
End Sub

Public Sub DeleteData()
'删除当前记录
    '当前单元在最后一行，但没有 AddNew 操作，被挂起情况下退出该过程
    If DataGrid1.AddNewMode = dbgAddNewCurrent Or Adodc1.Recordset.RecordCount = 0 Then
        Exit Sub
    End If
    Adodc1.Recordset.Bookmark = DataGrid1.Bookmark
    Adodc1.Recordset.Delete
    '设置修改标志
    DataEdited = True
    DataGrid1.Refresh
End Sub

Public Sub SaveData()
'保存全部修改
On Error GoTo errhandler:
    If Adodc1.Recordset.RecordCount > 0 Then Adodc1.Recordset.MoveFirst
    Adodc1.Recordset.UpdateBatch
    cn.CommitTrans '提交事务
    DataEdited = False
    DataGrid1.Refresh
    Adodc1.Refresh
    Set cn = Adodc1.Recordset.ActiveConnection '获取当前记录集的连接对象
    cn.BeginTrans '开始一个新事务
    Exit Sub
errhandler:
    '显示与数据库操作规则有关的错误信息
    Call ShowDbRuleErrInf("学院代码和专业代码的组合值")
End Sub

Public Sub CancelData()
'还原全部修改
On Error GoTo errhandler:
    If Adodc1.Recordset.RecordCount > 0 Then Adodc1.Recordset.MoveFirst
    Adodc1.Recordset.CancelBatch
    cn.RollbackTrans  '回滚事务
    DataEdited = False
    DataGrid1.Refresh
    Adodc1.Refresh
    Set cn = Adodc1.Recordset.ActiveConnection '获取当前记录集的连接对象
    cn.BeginTrans '开始一个新事务
    Exit Sub
errhandler:
    '显示与数据库操作规则有关的错误信息
    Call ShowDbRuleErrInf("学院代码和专业代码的组合值")
End Sub

Public Sub ClearData()
'删空当前记录集
    Call DBRecordset_Delete(Adodc1.Recordset)
    DataGrid1.Refresh
    '设置修改标志
    DataEdited = True
End Sub

'学院组合框单击
Private Sub xyComb_Click()
Dim msql$, sArray() As String
    If bFirstStart Then Exit Sub
    Call SaveData
    sArray = Split(xyComb.Text)
    If sArray(0) = "全部" Then
        Adodc1.RecordSource = "select institute_id as 学院代码,major_id as 专业代码," _
                          & "major_name as 专业名称" _
                          & " from major order by institute_id asc,major_id asc"
    Else
        msql = "where institute_id='" & Trim(sArray(1)) & "'"
        Adodc1.RecordSource = "select institute_id as 学院代码,major_id as 专业代码," _
                          & "major_name as 专业名称" _
                          & " from major " & msql & " order by institute_id asc,major_id asc"
    End If
    '重新初始化状态栏显示信息
    StatBar.Panels(1).Text = "当前记录位置：0"
    StatBar.Panels(2).Text = "记录总数：0"
    StatBar.Panels(3).Text = ""
    '打开更新后的记录集
    Adodc1.Refresh
    Set cn = Adodc1.Recordset.ActiveConnection '获取当前记录集的连接对象
    cn.BeginTrans '开始一个新事务
End Sub

'窗体卸载前查询事件
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
Dim s$, b%
    If DataEdited = True Then
        s$ = "数据已修改，是否保存？"
        b = MsgBox(s$, vbYesNoCancel + vbQuestion, "操作提示")
        Select Case b
        Case vbYes            '保存修改
            Call SaveData
        Case vbNo             '取消修改
            Call CancelData
        Case vbCancel
            Cancel = True     '不关闭窗体
            Exit Sub
        End Select
    End If
    '"操作"菜单、按钮禁用
    Call InitMenuAndToolbars(False)
End Sub