genericirpmanagementsystem.idl

来自「UCS (Ultra Corba Simulator) is one more 」· IDL 代码 · 共 89 行

//File: GenericIRPManagementSystem.idl
#ifndef _GENERIC_IRP_MANAGEMENT_SYSTEM_IDL_
#define _GENERIC_IRP_MANAGEMENT_SYSTEM_IDL_

#include <GenericIRPManagementConstDefs.idl>

// This statement must appear after all include statements
#pragma prefix "3gppsa5.org"

module GenericIRPManagementSystem
{
   exception GetInterfaceIRPNotificationProfile { string reason; };
   exception GetInterfaceIRPOperationProfile { string reason; };
   exception GetIRPVersions { string reason; };

   /*
   Exception thrown when an unsupported optional parameter
   is passed with information.
   The parameter shall be the actual unsupported parameter name.
   */
   exception ParameterNotSupported {
      GenericIRPManagementConstDefs::ParameterName parameter; };

   /*
   Exception thrown when an invalid parameter value is passed.
   The parameter shall be the actual parameter name.
   */
   exception InvalidParameter {
      GenericIRPManagementConstDefs::ParameterName parameter; };

   /*
   Exception thrown when a valid but unsupported parameter value is passed.
   The parameter shall be the actual parameter name.
   */
   exception ValueNotSupported {
      GenericIRPManagementConstDefs::ParameterName parameter; };

   /*
   Exception thrown when an unsupported optional method is called.
   */
   exception OperationNotSupported {};

   interface GenericIRPManagement
   {
      /*
      Return the list of all supported Interface IRP versions
      Each IRPVersion is defined by the rule in the definition
      "IRP document version number string" or "IRPVersion"
      (see subclause 3.1).
      */
      GenericIRPManagementConstDefs::VersionNumberSet get_irp_versions
      (
      )
      raises (GetIRPVersions);

      /*
      Return the list of all supported methods and their supported
      parameters for this Interface IRPVersion.
      */
      GenericIRPManagementConstDefs::MethodList
         get_interface_irp_operation_profile
      (
         in GenericIRPManagementConstDefs::VersionNumber this_irp_version
      )
      raises (GetInterfaceIRPOperationProfile,
              OperationNotSupported,
              InvalidParameter,
              ValueNotSupported);

      /*
      Return the list of all supported notifications and their supported
      parameters for this Interface IRPVersion.
      */
      typedef GenericIRPManagementConstDefs::NotificationList NotificationList;

      NotificationList get_interface_irp_notification_profile
      (
         in GenericIRPManagementConstDefs::VersionNumber this_irp_version
      )
      raises (GetInterfaceIRPNotificationProfile,
              OperationNotSupported,
              InvalidParameter,
              ValueNotSupported);
    };

};

#endif // _GENERIC_IRP_MANAGEMENT_SYSTEM_IDL_