testmanagementirpsystem.idl

UCS (Ultra Corba Simulator) is one more powerful corba client/servant simulator tool than other simi

// File: TestManagementIRPSystem.idl

#ifndef _TESTMANAGEMENTIRPSYSTEM_IDL_
#define _TESTMANAGEMENTIRPSYSTEM_IDL_

#include "TestManagementIRPConstDefs.idl"
#include "ManagedGenericIRPSystem.idl"

// This statement must appear after all include statements
#pragma prefix "3gppsa5.org"

/* ## Module: TestManagementIRPSystem
This module contains the specification of all methods of TestManagement IRP Agent.
================================================================
*/
module TestManagementIRPSystem
{
   /*
   System may fail to complete an operation.  System can provide reason
   to qualify the failed reason.  The semantics carried in reason
   is outside the scope of this IRP.
   */
   exception GetTestManagementIRPVersions { string reason; };
   exception GetTestManagementIRPOperationsProfile { string reason; };
   exception GetTestManagementIRPNotificationProfile { string reason; };
   exception InitiateTests { string reason; };
   exception TerminateTests { string reason; };
   exception MonitorTest { string reason; };  


   interface TestManagementIRP
   {
      /*
      Return the list of all supported TestManagement IRP versions.
      */
      ManagedGenericIRPConstDefs::VersionNumberSet
      get_Test_Management_IRP_versions (
      )
      raises (GetTestManagementIRPVersions);


      /*
      Return the list of all supported operations and their supported
      parameters for a specific TestManagement IRP version.
      */
      ManagedGenericIRPConstDefs::MethodList
      get_Test_Management_IRP_operations_profile (
         in ManagedGenericIRPConstDefs::VersionNumber 
             test_management_irp_version
      )
      raises (GetTestManagementIRPOperationsProfile,
              ManagedGenericIRPSystem::OperationNotSupported,
              ManagedGenericIRPSystem::InvalidParameter);

      /*
      Return the list of all supported notifications and their supported
      parameters for a specific TestManagement IRP version.
      */
      ManagedGenericIRPConstDefs::MethodList 
      get_Test_Management_IRP_notification_profile (
         in ManagedGenericIRPConstDefs::VersionNumber
            test_management_irp_version
      )
      raises (GetTestManagementIRPNotificationProfile,
              ManagedGenericIRPSystem::OperationNotSupported,
              ManagedGenericIRPSystem::InvalidParameter);


      /*
      Request to initiate tests.
      */
      TestManagementIRPConstDefs::InitiateTestsResponse
      initiate_tests (
         in TestManagementIRPConstDefs::TestInvocationInitiator
            test_invocation_initiator,
         in TestManagementIRPConstDefs::ToBeInitiatedTestSeq 
            to_be_initiated_test_seq
      )
      raises (InitiateTests,
              ManagedGenericIRPSystem::InvalidParameter);


      /*
      Request to terminate tests.
      */
      TestManagementIRPConstDefs::TerminateTestsResponse
      terminate_tests (
         in TestManagementIRPConstDefs::ToBeTerminatedTestSeq
             to_be_terminated_test_seq
      )
      raises (TerminateTests,
              ManagedGenericIRPSystem::InvalidParameter);


      /*
      Request test info (to monitor a test).
      */
      ManagedGenericIRPConstDefs::Signal monitor_test (
         in TestManagementIRPConstDefs::ToBeMonitoredTO
             to_be_monitored_TO,
         out TestManagementIRPConstDefs::TOAttributes tO_attributes
      )
      raises (MonitorTest, 
              ManagedGenericIRPSystem::InvalidParameter);




   };
};

#endif // _TESTMANAGEMENTIRPSYSTEM_IDL_