tnmsmultilayersubnetwork.idl

UCS (Ultra Corba Simulator) is one more powerful corba client/servant simulator tool than other simi

#ifndef tnmsMultiLayerSubnetwork_idl
#define tnmsMultiLayerSubnetwork_idl

// ************************************
// *                                  *
// * tnmsMultiLayerSubnetwork.idl     *
// *                                  *
// ************************************

//Include list
#include "multiLayerSubnetwork.idl"

#pragma prefix ""

module multiLayerSubnetwork
{
  /**
   * <p>The MultiLayerSubnetworkVariantTSMgr_I is a proprietary extension to the MultiLayerSubnetworkMgr_I 
   * used to provide SNC modification operations when in nodal network view.</p>
   * <p>A handle to this interface is gained via the
   * <a href=_emsSession.EmsSession_I.html#emsSession::EmsSession_I::getManager>
   * getManager</a> operation in Manager.</p>
   **/

  interface MultiLayerSubnetworkVariantTSMgr_I  : MultiLayerSubnetworkMgr_I
  {
    /**
     * <p>This operation adds a protection to an existing SNC.</p>
     * Preconditions for this operation are: 
     * <ul>
     * <li> the SNC has the following characteristics: 
     *      sncType = simple, resilienceMode = lowResilience, direction = bidirectional or unidirectional.</li>
     * <li> the TP identified by protectedTPName is used by the SNC with SNCName.</li>
     * <li> the SNC (CC) determined by SNCName is a flexible CC.</li>
     * <li> the TP determined by TPName is not used by other SNCs.</li>
     * <li> the ME supports add_drop SNCs (CCs).</li>
     * </ul>
     * If the operation is performed successfully, the SNC will get the characteristics: 
     * sncType = add_drop, resilienceMode = not applicable.
     * protectedTPName, TPName identifies the protecting segment to be added. 
     * The TP identified by protectedTPName has to belong to the already existing SNC. 
     * This TP will become the bridge/selector of the add_drop SNC. 
     * <br>
     * Note, that some NEs support add_drop CCs, although they do not support the addition 
     * of a protecting segment to the existing CC. 
     * In this case the existing CC is deleted first; then the add_drop CC is created. 
     * For these NEs a traffic interruption will happen.
     * <br>
     * @parm globaldefs::NamingAttributes_T SNCName:
     *       name of the SNC for which the protection is added 
     * @parm globaldefs::NamingAttributes_T protectedTPName:
     * @parm globaldefs::NamingAttributes_T TPName:
     *
     * @raises globaldefs::ProcessingFailureException<dir>
     * EXCPT_INTERNAL_ERROR - Raised in case of non-specific EMS internal failure<br>
     * EXCPT_INVALID_INPUT - Raised if SNC references an object which is not an SNC<br>
     * EXCPT_TP_IN_USE - Raised if the TP identified by TPName is used by other SNCs<br>
     * EXCPT_TP_INVALID_ENDPOINT - Raised if the TP identified by protectedTPName is not used by the SNC identified by SNCName<br>
     * EXCPT_ENTITY_NOT_FOUND - Raised if input SNC references an object which does not exist<br>
     * EXCPT_UNABLE_TO_COMPLY - Raised if preconditions are violated not covered by specific exceptions<br>
     * EXCPT_NE_COMM_LOSS - Raised when communications to managedElement is lost<br>
     * </dir>
     **/
    void addSNCP(
                 in globaldefs::NamingAttributes_T SNCName,
                 in globaldefs::NamingAttributes_T protectedTPName,
                 in globaldefs::NamingAttributes_T TPName
                 )
      raises(globaldefs::ProcessingFailureException);

    /**
     * <p> This operation removes a protection from an existing SNC.</p>
     * Preconditions for this operation are: 
     * <ul>
     * <li> the SNC has the following characteristics: 
     * sncType = add_drop, resilienceMode = not applicable, direction = bidirectional or unidirectional.</li>
     * <li> the TP identified by TPName is used by the SNC with SNCName, but is not the bridge/selector of this SNC.</li>
     * <li> the SNC (CC) determined by SNCName is a flexible CC.</li>
     * </ul>
     * If the operation is performed successfully, the SNC will get the characteristics: 
     * sncType = simple, resilienceMode = lowResilience. 
     * The protecting segment from the bridge/selector TP to the TP identified by TPName has been removed from the SNC.
     * <br>
     * Note, that some NEs do not support the removal of the protecting segment from the existing add_drop CC. 
     * In this case the existing add_drop CC is deleted first; then the simple CC is created. 
     * For these NEs a traffic interruption will happen.
     * <br>
     * @parm globaldefs::NamingAttributes_T SNCName:
     *       name of the SNC for which the protection is removed.
     * @parm globaldefs::NamingAttributes_T TPName:
     * 
     * @raises globaldefs::ProcessingFailureException<dir>
     * EXCPT_INTERNAL_ERROR - Raised in case of non-specific EMS internal failure<br>
     * EXCPT_INVALID_INPUT - Raised if SNC references an object which is not an SNC<br>
     * EXCPT_TP_INVALID_ENDPOINT - Raised if the TP identified by TPName is not the bridge/selector of the SNC with SNCName, or is not used by this SNC<br>
     * EXCPT_ENTITY_NOT_FOUND - Raised if SNCName references an object which does not exist<br>
     * EXCPT_UNABLE_TO_COMPLY - Raised if preconditions are violated not covered by specific exceptions<br>
     * EXCPT_NE_COMM_LOSS - Raised when communications to managedElement is lost<br>
     * </dir>
     **/
    void removeSNCP(
                    in globaldefs::NamingAttributes_T SNCName,
                    in globaldefs::NamingAttributes_T TPName
                    )
      raises(globaldefs::ProcessingFailureException);
  };

};
  
#endif