hxclientplayer.mm

linux下的一款播放器

/* ***** BEGIN LICENSE BLOCK *****
 * Source last modified: $Id: HXClientPlayer.mm,v 1.16.2.4 2004/07/09 01:49:35 hubbe Exp $
 * 
 * Portions Copyright (c) 1995-2004 RealNetworks, Inc. All Rights Reserved.
 * 
 * The contents of this file, and the files included with this file,
 * are subject to the current version of the RealNetworks Public
 * Source License (the "RPSL") available at
 * http://www.helixcommunity.org/content/rpsl unless you have licensed
 * the file under the current version of the RealNetworks Community
 * Source License (the "RCSL") available at
 * http://www.helixcommunity.org/content/rcsl, in which case the RCSL
 * will apply. You may also obtain the license terms directly from
 * RealNetworks.  You may not use this file except in compliance with
 * the RPSL or, if you have a valid RCSL with RealNetworks applicable
 * to this file, the RCSL.  Please see the applicable RPSL or RCSL for
 * the rights, obligations and limitations governing use of the
 * contents of the file.
 * 
 * Alternatively, the contents of this file may be used under the
 * terms of the GNU General Public License Version 2 or later (the
 * "GPL") in which case the provisions of the GPL are applicable
 * instead of those above. If you wish to allow use of your version of
 * this file only under the terms of the GPL, and not to allow others
 * to use your version of this file under the terms of either the RPSL
 * or RCSL, indicate your decision by deleting the provisions above
 * and replace them with the notice and other provisions required by
 * the GPL. If you do not delete the provisions above, a recipient may
 * use your version of this file under the terms of any one of the
 * RPSL, the RCSL or the GPL.
 * 
 * This file is part of the Helix DNA Technology. RealNetworks is the
 * developer of the Original Code and owns the copyrights in the
 * portions it created.
 * 
 * This file, and the files included with this file, is distributed
 * and made available on an 'AS IS' basis, WITHOUT WARRANTY OF ANY
 * KIND, EITHER EXPRESS OR IMPLIED, AND REALNETWORKS HEREBY DISCLAIMS
 * ALL SUCH WARRANTIES, INCLUDING WITHOUT LIMITATION, ANY WARRANTIES
 * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE, QUIET
 * ENJOYMENT OR NON-INFRINGEMENT.
 * 
 * Technology Compatibility Kit Test Suite(s) Location:
 *    http://www.helixcommunity.org/content/tck
 * 
 * Contributor(s):
 * 
 * ***** END LICENSE BLOCK ***** */

#import "HXClientEngine.h"
#import "HXClientPlayer.h"
#import "CHXClientPlayer.h"
#import "HXClientConstants.h"
#import "HXStringUtils.h"
#import "CHXClientDebug.h"

#if defined(HELIX_FEATURE_REGISTRY) && defined(HELIX_FEATURE_STATS)
#import "CHXStatisticObserverBridge.h"
#endif

#ifdef HELIX_FEATURE_VIDEO
#import "HXClientView.h"
#endif

#include "enter_hx_headers.h"
#include "hxwintyp.h"
#include "hxcore.h"
#include "exit_hx_headers.h"

extern HXClientCallbacks gPlayerToObserverCallbacks;

@implementation HXClientPlayer

- (id)init
{
	[self doesNotRecognizeSelector:@selector(init)];
	return nil;
}

- (IHXClientPlayerPtr)createClientForCorePlayer:(void *)pIHXPlayer
									 withEngine:(void *)pIHXClientEngine
									   inWindow:(SHXClientWindow *)pWindow
								   withObserver:(id)observer
								 usingCallbacks:(HXClientCallbacks*)pClientCallbacks
{
	IHXClientPlayerPtr pIClientPlayer = CHXClientPlayer::Create( ( IHXClientEngine* ) pIHXClientEngine, ( IHXPlayer* ) pIHXPlayer, ( HXxWindow* ) pWindow, observer, pClientCallbacks );
	CHXASSERT( pIClientPlayer );
	return pIClientPlayer;
}

- (id)initInWindow:(SHXClientWindow *)pWindow withObserver:(id)observer usingCallbacks:(HXClientCallbacks*)pClientCallbacks
{
	self = [super init];
	if ( self )
	{
		HX_RESULT result = HXR_OUTOFMEMORY;
		clientEngine = [[HXClientEngine sharedClientEngine] retain];
		IHXClientEngine* pICoreEngine = [clientEngine coreEngine];
		if ( pICoreEngine )
		{
			IHXPlayer* pICorePlayer = NULL;
			result = pICoreEngine->CreatePlayer( pICorePlayer );
			if ( SUCCEEDED( result ) )
			{
				m_pIClientPlayer = [self createClientForCorePlayer:pICorePlayer
														withEngine:pICoreEngine
														  inWindow:pWindow
													  withObserver:observer
													usingCallbacks:pClientCallbacks];
				pICorePlayer->Release();
				return self;
			}
		}
		[clientEngine release];
		clientEngine = nil;
		if ( pClientCallbacks->OnErrorOccurred )
		{
			pClientCallbacks->OnErrorOccurred( observer, result, 0, NULL, NULL, NULL ); // XXXSEH: Should we fill in the last 4 arguments?
		}
		[self autorelease];
		self = nil;
	}
	return self;
}

- (id)initInWindow:(SHXClientWindow *)pWindow withObserver:(id)observer
{
	self = [self initInWindow:pWindow withObserver:observer usingCallbacks:&gPlayerToObserverCallbacks];
	if ( self )
	{
	}
	return self;
}

#ifdef HELIX_FEATURE_VIDEO
- (id)initInView:(HXClientView *)view withObserver:(id)observer
{
	CHXASSERT( view ); // @"initInView requires a valid HXClientView*"

	self = [self initInWindow:[view siteWindow] withObserver:observer];
	if ( self )
	{
		[view setClientPlayer:self];
	}
	return self;
}
#endif

- (void)dealloc
{
#if defined(HELIX_FEATURE_REGISTRY) && defined(HELIX_FEATURE_STATS)
	if ( m_pStatisticObserver )
	{
		CHXStatisticObserverBridge* pStatisticObserverBridge = ( CHXStatisticObserverBridge* ) m_pStatisticObserver;
		delete pStatisticObserverBridge;
		m_pStatisticObserver = NULL;
	}
#endif
	HX_RELEASE( m_pIClientPlayer );
	[clientEngine release];
	clientEngine = nil;

	[super dealloc];
}

- (void)openWithURL:(NSURL *)url mimeType:(NSString *)mimeType
{
	if ( m_pIClientPlayer )
	{
		const char* pURL = [[url absoluteString] UTF8String];
		const char* pMimeType = mimeType ? [mimeType UTF8String] : NULL;
		m_pIClientPlayer->OpenURL( pURL, pMimeType );
	}
}

- (BOOL)canViewSource
{
	return m_pIClientPlayer ? ( m_pIClientPlayer->CanViewSource() ? YES : NO ) : NO;
}

- (void)viewSource
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->ViewSource();
	}
}

- (BOOL)canViewRights
{
	return m_pIClientPlayer ? ( m_pIClientPlayer->CanViewRights() ? YES : NO ) : NO;
}

- (void)viewRights
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->ViewRights();
	}
}

- (BOOL)authenticateForUser:(NSString *)username withPassword:(NSString *)password
{
	if ( m_pIClientPlayer )
	{
		if ( !username ) return ( 0 != SUCCEEDED( m_pIClientPlayer->Authenticate( false, NULL, NULL ) ) ) ? YES : NO;

		const char* pUsername = NULL;
		char* pUsernameBuffer = NULL;
		CFStringRef usernameText = ( CFStringRef ) username;
		pUsername = CFStringGetCStringPtr( usernameText, kCFStringEncodingUTF8 );
		if ( !pUsername )
		{
			CFIndex bufferSize = 1 + CFStringGetMaximumSizeForEncoding( CFStringGetLength( usernameText ), kCFStringEncodingUTF8 );
			pUsernameBuffer = new char[ bufferSize ];
			if ( pUsernameBuffer &&
					CFStringGetCString( usernameText, pUsernameBuffer, bufferSize, kCFStringEncodingUTF8 ) )
			{
				pUsername = pUsernameBuffer;
			}
		}
		const char* pPassword = NULL;
		char* pPasswordBuffer = NULL;
		if ( password )
		{
			CFStringRef passwordText = ( CFStringRef ) password;
			pPassword = CFStringGetCStringPtr( passwordText, kCFStringEncodingUTF8 );
			if ( !pPassword )
			{
				CFIndex bufferSize = 1 + CFStringGetMaximumSizeForEncoding( CFStringGetLength( passwordText ), kCFStringEncodingUTF8 );
				pPasswordBuffer = new char[ bufferSize ];
				if ( pPasswordBuffer &&
					 CFStringGetCString( passwordText, pPasswordBuffer, bufferSize, kCFStringEncodingUTF8 ) )
				{
					pPassword = pPasswordBuffer;
				}
			}
		}
		BOOL outHasAuthenticated = ( 0 != SUCCEEDED( m_pIClientPlayer->Authenticate( true, pUsername, pPassword ) ) ) ? YES : NO;

		delete [] pPasswordBuffer;
		delete [] pUsernameBuffer;
		
		return outHasAuthenticated;
	}
	return NO;
}

- (int)contentState
{
	return m_pIClientPlayer ? m_pIClientPlayer->GetContentState() : kContentStateNotLoaded;
}

- (BOOL)setStatus:(NSString *)status
{
	if ( m_pIClientPlayer )
	{
		if ( !status || ( [status length] <= 0 ) )
		{
			return m_pIClientPlayer->SetStatus( NULL ) ? YES : NO;
		}
		CFStringRef statusText = ( CFStringRef ) status;
		const char* pStatusText = CFStringGetCStringPtr( statusText, kCFStringEncodingUTF8 );
		if ( pStatusText )
		{
			return m_pIClientPlayer->SetStatus( pStatusText ) ? YES : NO;
		}
		CFIndex bufferSize = 1 + CFStringGetMaximumSizeForEncoding( CFStringGetLength( statusText ), kCFStringEncodingUTF8 );
		char* pConvertedStatusText = new char[ bufferSize ];
		if ( !pConvertedStatusText ) return NO;
		
		BOOL outDidSetStatus = NO;
		if ( CFStringGetCString( statusText, pConvertedStatusText, bufferSize, kCFStringEncodingUTF8 ) )
		{
			outDidSetStatus = m_pIClientPlayer->SetStatus( pConvertedStatusText ) ? YES : NO;
		}
		delete [] pConvertedStatusText;
		return outDidSetStatus;
	}
	return NO;
}

- (void)play
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->Play();
	}
}

- (void)pause
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->Pause();
	}
}

- (void)stop
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->Stop();
	}
}

- (BOOL)startSeeking
{
	return m_pIClientPlayer ? ( m_pIClientPlayer->StartSeeking() ? YES : NO ) : NO;
}

- (void)stopSeeking
{
	if ( m_pIClientPlayer )
	{
		m_pIClientPlayer->StopSeeking();
	}
}

- (BOOL)setPosition:(UInt32)position
{
	return m_pIClientPlayer ? ( ( 0 != SUCCEEDED( m_pIClientPlayer->SetPosition( position ) ) ) ? YES : NO ) : NO;
}

- (UInt32)position
{
	return m_pIClientPlayer ? m_pIClientPlayer->GetPosition() : 0;
}

- (UInt32)length
{
	return m_pIClientPlayer ? m_pIClientPlayer->GetLength() : 0;
}

- (BOOL)isLive
{
	return m_pIClientPlayer ? ( m_pIClientPlayer->IsLive() ? YES : NO ) : NO;
}

- (NSString *)title
{
	if ( m_pIClientPlayer )
	{
		const char* pTitle = m_pIClientPlayer->GetTitle();