configure.in

在Linux下实现magnification功能

dnl Process this file with autoconf to produce a configure script.

dnl required versions of other tools.
m4_define([req_ver_glib],	[1.3.11])
m4_define([req_ver_gtk],	[2.1.0])
m4_define([req_ver_libbonobo],	[1.107.0])
m4_define([req_ver_libspi],	[0.12.1])
m4_define([req_ver_orbit],	[2.3.100])

AC_INIT(magnifier/magnifier.c)

dnl libtool versioning from libgnome

GNOME_MAG_MAJOR_VERSION=0
GNOME_MAG_MINOR_VERSION=14
GNOME_MAG_INTERFACE_AGE=10
dnl below should change if the interface has additions, changes, removals.
GNOME_MAG_CURRENT=`expr $GNOME_MAG_MINOR_VERSION - $GNOME_MAG_INTERFACE_AGE`

dnl increment any time the source you release changes; set to
dnl 0 if you increment CURRENT
GNOME_MAG_REVISION=3

GNOME_MAG_MICRO_VERSION=$GNOME_MAG_REVISION

dnl increment if any interfaces have been added; set to 0
dnl  if any interfaces have been removed. removals has
dnl  precedence over adding, so set to 0 if both happened.
GNOME_MAG_AGE=2

AC_SUBST(GNOME_MAG_CURRENT)
AC_SUBST(GNOME_MAG_REVISION)
AC_SUBST(GNOME_MAG_AGE)
LT_VERSION_INFO='-version-info ${GNOME_MAG_CURRENT}:${GNOME_MAG_REVISION}:${GNOME_MAG_AGE}'
AC_SUBST(LT_VERSION_INFO)

AM_CONFIG_HEADER(config.h)
GNOME_MAG_VERSION="$GNOME_MAG_MAJOR_VERSION.$GNOME_MAG_MINOR_VERSION.$GNOME_MAG_MICRO_VERSION"
AM_INIT_AUTOMAKE(gnome-mag, $GNOME_MAG_VERSION)
AM_MAINTAINER_MODE

IT_PROG_INTLTOOL([0.35.0])

AC_PROG_CC
AC_LIBTOOL_WIN32_DLL
AC_PROG_INSTALL
AC_ISC_POSIX

GNOME_COMPILE_WARNINGS(maximum)

AM_DISABLE_STATIC
AM_PROG_LIBTOOL

GETTEXT_PACKAGE=gnome-mag
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [The gettext package])

AM_GLIB_GNU_GETTEXT

AC_MSG_CHECKING([for Win32])
case "$host" in
  *-*-mingw*)
    gnome_mag_native_win32=yes
    ;;
  *)
    gnome_mag_native_win32=no
    ;;
esac
AC_MSG_RESULT([$gnome_mag_native_win32])
AM_CONDITIONAL(OS_WIN32, test "$gnome_mag_native_win32" = "yes")

if test "$gnome_mag_native_win32" = "yes"; then
  AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
fi
AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)

dnl Cache $ACLOCAL_FLAGS
AC_CACHE_CHECK([for aclocal flags], ac_cv_atk_aclocal_flags,[
   ac_cv_atk_aclocal_flags="$ACLOCAL_FLAGS"
])
ACLOCAL="$ACLOCAL $ac_cv_atk_aclocal_flags"

AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds	   disable all source autogeneration rules],,enable_rebuilds=yes)

AC_ARG_ENABLE(debug, [  --enable-debug=[no/yes] turn on debugging [default=no]],,enable_debug=no)
if test "$enable_debug" = "yes"; then
  GNOME_MAG_DEBUG_CFLAGS="-DG_ENABLE_DEBUG"
else
  GNOME_MAG_DEBUG_CFLAGS="-DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED -DGNOME_DISABLE_DEPRECATED"
fi
AC_SUBST(GNOME_MAG_DEBUG_CFLAGS)

changequote(,)dnl
if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \ ]-Wall[\ \	]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac
fi
changequote([,])dnl

AC_PATH_XTRA

dnl test for X libraries
if test x$no_x = xyes ; then
  AC_MSG_ERROR([X development libraries not found])
else
  X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
fi

dnl path to XFIXES
AC_CHECK_LIB(Xfixes, XFixesCreateRegion, XFIXES_LIBS=-lXfixes)
if test "x$XFIXES_LIBS" = x; then
  save_LIBS="$LIBS"
  for xfixespath in $x_libraries; do
    LIBS="-L$xfixespath -lXfixes -lX11"
    case "$host" in
    *solaris*) XFIXES_RPATH_FLAGS="-R$xfixespath" ;;
    esac
    AC_MSG_CHECKING(for -lXfixes in $xfixespath)
    AC_TRY_LINK([], [XFixesCreateRegion()], [
	AC_MSG_RESULT(yes)
	XFIXES_LIBS="$XFIXES_RPATH_FLAGS -L$xfixespath -lXfixes"
        LIBS="$save_LIBS"
	break],[AC_MSG_RESULT(no)])
  done
  if test "x$XFIXES_LIBS" = x; then
    AC_MSG_WARN(Couldn't find the XFIXES library. Check config.log for details)
    LIBS="$save_LIBS"
  else
    X_LIBS="$X_LIBS $XFIXES_LIBS"
    AC_CHECK_HEADER(X11/extensions/Xfixes.h, have_xfixes=yes,,[#include <X11/Xlib.h>])
    if test "x$have_xfixes" = xyes; then
       AC_DEFINE(HAVE_XFIXES, 1, [The XFIXES extension is present])
    fi
  fi
else
  X_LIBS="$X_LIBS $XFIXES_LIBS"
  AC_CHECK_HEADER(X11/extensions/Xfixes.h, have_xfixes=yes,,[#include <X11/Xlib.h>])
  if test "x$have_xfixes" = xyes; then
     AC_DEFINE(HAVE_XFIXES, 1, [The XFIXES extension is present])
  fi
fi

if test "x$have_xfixes" = xyes; then
dnl path to DAMAGE.
AC_CHECK_LIB(Xdamage, XDamageCreate, XDAMAGE_LIBS=-lXdamage)
if test "x$XDAMAGE_LIBS" = x; then
  save_LIBS="$LIBS"
  for xdamagepath in $x_libraries; do
    LIBS="-L$xdamagepath -lXdamage -lX11"
    case "$host" in
    *solaris*) XDAMAGE_RPATH_FLAGS="-R$xdamagepath" ;;
    esac
    AC_MSG_CHECKING(for -lXdamage in $xdamagepath)
    AC_TRY_LINK([], [XDamageCreate()], [
	AC_MSG_RESULT(yes)
	XDAMAGE_LIBS="$XDAMAGE_RPATH_FLAGS -L$xdamagepath -lXdamage"
        LIBS="$save_LIBS"
	break],[AC_MSG_RESULT(no)])
  done
  if test "x$XDAMAGE_LIBS" = x; then
    AC_MSG_WARN(Couldn't find the DAMAGE library. Check config.log for details)
    LIBS="$save_LIBS"
  else
    X_LIBS="$X_LIBS $XDAMAGE_LIBS"
    AC_CHECK_HEADER(X11/extensions/Xdamage.h, have_xdamage=yes,,[#include <X11/Xlib.h>])
    if test "x$have_xdamage" = xyes; then
       AC_DEFINE(HAVE_DAMAGE, 1, [The DAMAGE extension is present])
    fi
  fi
else
  X_LIBS="$X_LIBS $XDAMAGE_LIBS"
  AC_CHECK_HEADER(X11/extensions/Xdamage.h, have_xdamage=yes,,[#include <X11/Xlib.h>])
  if test "x$have_xdamage" = xyes; then
     AC_DEFINE(HAVE_DAMAGE, 1, [The DAMAGE extension is present])
  fi
fi
fi

if test "x$have_xdamage" = xyes; then
dnl path to XRENDER
AC_CHECK_LIB(Xrender, XRenderCreatePicture, XRENDER_LIBS=-lXrender)
if test "x$XRENDER_LIBS" = x; then
  save_LIBS="$LIBS"
  for xrenderpath in $x_libraries; do
    LIBS="-L$xrenderpath -lXrender -lX11"
    case "$host" in
    *solaris*) XRENDER_RPATH_FLAGS="-R$xrenderpath" ;;
    esac
    AC_MSG_CHECKING(for -lXrender in $xrenderpath)
    AC_CHECK_FUNC(XRenderCreatePicture, [
	AC_MSG_RESULT(yes)
	XRENDER_LIBS="$XRENDER_RPATH_FLAGS -L$xrenderpath -lXrender"
        LIBS="$save_LIBS"
	break],[AC_MSG_RESULT(no)])
  done
  if test "x$XRENDER_LIBS" = x; then
    AC_MSG_WARN(Couldn't find the XRENDER library. Check config.log for details)
    LIBS="$save_LIBS"
  else
    X_LIBS="$X_LIBS $XRENDER_LIBS"
    AC_CHECK_HEADER(X11/extensions/Xrender.h, have_xrender=yes)
  fi
else
  X_LIBS="$X_LIBS $XRENDER_LIBS"
  AC_CHECK_HEADER(X11/extensions/Xrender.h, have_xrender=yes)
fi

if test "x$have_xrender" = xyes; then
dnl path to XEXT
AC_CHECK_LIB(Xext, XShapeCombineRectangles, XEXT_LIBS=-lXext)
if test "x$XEXT_LIBS" = x; then
  save_LIBS="$LIBS"
  for xextpath in $x_libraries; do
    LIBS="-L$xextpath -lXext -lX11"
    case "$host" in
    *solaris*) XEXT_RPATH_FLAGS="-R$xextpath" ;;
    esac
    AC_MSG_CHECKING(for -lXext in $xextpath)
    AC_CHECK_FUNC(XShapeCombineRectangles, [
        AC_MSG_RESULT(yes)
        XEXT_LIBS="$XEXT_RPATH_FLAGS -L$xextpath -lXext"
        LIBS="$save_LIBS"
        break],[AC_MSG_RESULT(no)])
  done
  if test "x$XEXT_LIBS" = x; then
    AC_MSG_WARN(Couldn't find the XShape function in Xext library. Check config.log for details)
    LIBS="$save_LIBS"
  else
    save_LIBS="$LIBS"
    save_CFLAGS="$CFLAGS"
    X_LIBS="$X_LIBS $XEXT_LIBS"
    LIBS="$X_LIBS"
    CFLAGS="-I$x_includes $CFLAGS"
    AC_CHECK_HEADER(X11/extensions/shape.h, have_xshape=yes,, [#include <X11/Xlib.h>])

    if test "x$have_xshape" = x; then
      AC_MSG_WARN(Couldn't find XShape shape.h header. Check config.log for details)
    else
      AC_CHECK_DECL(ShapeInput, [
          AC_DEFINE(HAVE_SHAPEINPUT, 1, [
	      The Shape extension have ShapeInput])],
          [have_xshape=no], 
          [#include <X11/Xlib.h>
           #include <X11/extensions/shape.h>])
    fi
    LIBS="$save_LIBS"
    CFLAGS="$save_CFLAGS"
  fi
else
  save_LIBS="$LIBS"
  save_CFLAGS="$CFLAGS"
  X_LIBS="$X_LIBS $XEXT_LIBS"
  LIBS="$X_LIBS"
  CFLAGS="-I$x_includes $CFLAGS"
  AC_CHECK_HEADER(X11/extensions/shape.h, have_xshape=yes,, [#include <X11/Xlib.h>])
  if test "x$have_xshape" = x; then
    AC_MSG_WARN(Couldn't find XShape shape.h header. Check config.log for details)
  else
    AC_CHECK_DECL(ShapeInput, [
        AC_DEFINE(HAVE_SHAPEINPUT, 1, [
	    The Shape extension have ShapeInput])],
        [have_xshape=no], 
        [#include <X11/Xlib.h>
         #include <X11/extensions/shape.h>])
  fi
  LIBS="$save_LIBS"
  CFLAGS="$save_CFLAGS"
fi

if test "x$have_xshape" = xyes; then
dnl path to XCOMPOSITE
AC_CHECK_LIB(Xcomposite, XCompositeQueryExtension, XCOMPOSITE_LIBS=-lXcomposite)
if test "x$XCOMPOSITE_LIBS" = x; then
  save_LIBS="$LIBS"
  for xcompositepath in $x_libraries; do
    LIBS="-L$xcompositepath -lXcomposite -lX11"
    case "$host" in
    *solaris*) XCOMPOSITE_RPATH_FLAGS="-R$xcompositepath" ;;
    esac
    AC_MSG_CHECKING(for -lXcomposite in $xcompositepath)
    AC_CHECK_FUNC(XCompositeQueryExtension, [
        AC_MSG_RESULT(yes)
        XCOMPOSITE_LIBS="$XCOMPOSITE_RPATH_FLAGS -L$xcompositepath -lXcomposite"
        LIBS="$save_LIBS"
        break],[AC_MSG_RESULT(no)])
  done
  if test "x$XCOMPOSITE_LIBS" = x; then
    AC_MSG_WARN(Couldn't find the XCOMPOSITE library. Check config.log for details)
    LIBS="$save_LIBS"
  else
    save_LIBS="$LIBS"
    X_LIBS="$X_LIBS $XCOMPOSITE_LIBS"
    LIBS="$X_LIBS"
    AC_CHECK_HEADER(X11/extensions/Xcomposite.h, have_composite=yes,,[#include <X11/Xlib.h>])
    if test "x$have_composite" = xyes; then
       AC_DEFINE(HAVE_COMPOSITE, 1, [The XCOMPOSITE extension is present])
       AC_CHECK_FUNC(XCompositeGetOverlayWindow, [
          AC_DEFINE(HAVE_OVERLAY, 1, [The Composite extension has Overlay window])])
    fi
    LIBS="$save_LIBS"
  fi
else
  save_LIBS="$LIBS"
  X_LIBS="$X_LIBS $XCOMPOSITE_LIBS"
  LIBS="$X_LIBS"
  AC_CHECK_HEADER(X11/extensions/Xcomposite.h, have_composite=yes,,[#include <X11/Xlib.h>])
  if test "x$have_composite" = xyes; then
     AC_DEFINE(HAVE_COMPOSITE, 1, [The XCOMPOSITE extension is present])
     AC_CHECK_FUNC(XCompositeGetOverlayWindow, [
        AC_DEFINE(HAVE_OVERLAY, 1, [The Composite extension has Overlay window])])
  fi
  LIBS="$save_LIBS"
fi
fi
fi
fi

AC_SUBST(X_LIBS)


dnl Test for the colorblind lib
AC_CHECK_LIB(colorblind, colorblind_create, COLORBLIND_LIBS=-lcolorblind)
if test "x$COLORBLIND_LIBS" != x; then
   AC_CHECK_HEADER(colorblind.h, have_colorblind=yes)
   AC_DEFINE(HAVE_COLORBLIND, 1, [The Color Blind library is present])
fi

AC_SUBST(COLORBLIND_LIBS)

PKG_CHECK_MODULES(LIBDEPS, [
	ORBit-2.0		>= 2.3.100
	glib-2.0		>= 2.11.1
	gmodule-2.0		>= 1.3.11
	gobject-2.0		>= 1.3.11
	gthread-2.0		>= 1.3.11
])
AC_SUBST(LIBDEPS_LIBS)
AC_SUBST(LIBDEPS_CFLAGS)

PKG_CHECK_MODULES(DEPS, [
	libloginhelper-1.0	>= 1.5.2
	libbonobo-2.0		>= 1.107.0
	ORBit-2.0		>= 2.3.100
	glib-2.0		>= 2.11.1
	gtk+-2.0		>= 2.1.0
	gdk-pixbuf-2.0		>= 2.1.0
	gdk-pixbuf-xlib-2.0	>= 2.1.0
])
AC_SUBST(DEPS_LIBS)
AC_SUBST(DEPS_CFLAGS)

PKG_CHECK_MODULES(TEST, [
	libspi-1.0		>= 1.5.0
	libbonobo-2.0		>= 1.107.0
	ORBit-2.0		>= 2.3.100
	glib-2.0		>= 1.3.11
	gtk+-2.0		>= 2.1.0
	gdk-pixbuf-2.0		>= 2.1.0
	gdk-pixbuf-xlib-2.0	>= 2.1.0
])
AC_SUBST(TEST_LIBS)
AC_SUBST(TEST_CFLAGS)

PKG_CHECK_MODULES(ORBIT, ORBit-2.0 >= 2.3.100)
AC_SUBST(ORBIT_CFLAGS)
AC_SUBST(ORBIT_LIBS)

old_LIBS="$LIBS"
dnl Checks for inet libraries:
AC_SEARCH_LIBS(gethostent, nsl)
AC_SEARCH_LIBS(setsockopt, socket)
AC_SEARCH_LIBS(connect, inet)

INET_LIBS="$LIBS"
AC_SUBST(INET_LIBS)

LIBS="$old_LIBS"


dnl orbit-idl.
ORBIT_IDL="`$PKG_CONFIG --variable=orbit_idl ORBit-2.0`"
AC_SUBST(ORBIT_IDL)

dnl Bonobo and Bonobo-Activation idl files
BONOBO_ACTIVATION_IDL_DIR="`$PKG_CONFIG --variable=idldir bonobo-activation-2.0`"
LIBBONOBO_IDL_DIR="`$PKG_CONFIG --variable=idldir libbonobo-2.0`"
AC_SUBST(BONOBO_ACTIVATION_IDL_DIR)
AC_SUBST(LIBBONOBO_IDL_DIR)

AC_OUTPUT([
Makefile
gnome-mag-1.0.pc
gnome-mag-1.0-uninstalled.pc
po/Makefile.in
idl/Makefile
magnifier/Makefile
cursors/Makefile
cursors/1_32/Makefile
test/Makefile
docs/Makefile
docs/reference/Makefile
docs/man/Makefile
])