📄 10_4.asp

📁 ASP 网页数据库短训教程源码
💻 ASP
字号:
<HTML>
  <BODY>
    <form name=frm1>
<%
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    if IsEmpty(Request("af")) and IsEmpty(Session("af")) then		' 是否有源文件夹列表框
      set Session("af")=objFSO.GetFolder(Server.MapPath(".\"))		'   提交的数据
      Set objFolder = Session("af")
    elseif not IsEmpty(Request("af")) then
      set Session("af")=objFSO.GetFolder(Request("af"))
      Set objFolder = Session("af")
    end if
    Set objFolder = Session("af")
    Set Session("af") = objFolder
    ff=objFolder.parentfolder.path
    if IsEmpty(Request("af1")) and IsEmpty(Session("af1")) then		' 是否有目标文件夹列表框
      set Session("af1")=objFSO.GetFolder(Server.MapPath(".\"))		'   提交的数据
      Set objFolder1 = Session("af1")
    elseif not IsEmpty(Request("af1")) then
      set Session("af1")=objFSO.GetFolder(Request("af1"))
      Set objFolder1 = Session("af1")
    end if
    Set objFolder1 = Session("af1")
    Set Session("af1") = objFolder1
    ff1=objFolder1.parentfolder.path
    if Request("h1")<>"" then								' 是否有“复制文件”按钮
      rr=Request("h1")									'   提交的数据
      objFSO.CopyFile Request("bf"), objFolder1.path & "\" &rr
    end if
    if Request("h2")="True" then							' 是否有“删除文件”按钮
      objFSO.DeleteFile Request("bf")						'   提交的数据
    end if
    Response.Write "源目录：" & objFolder.Name & "<br>"
    Response.Write "<SELECT size =8 style='width:150px' name=af>"	' 下面开始源文件夹列表框
    if trim(objFolder.parentfolder.Name)<>"" then
      Response.Write  "<OPTION value=" & ff & ">[..]"
    end if
    For Each objSubFolder in objFolder.SubFolders
      Response.Write "<OPTION value=" & objSubFolder.path & ">" & objSubFolder.Name
    Next
    Response.Write "</SELECT> "
    Response.Write "<SELECT size =8 style='width:200px' name=bf>"	' 下面开始源文件列表框
    For Each objFile in objFolder.Files
     Response.Write "<OPTION value=" & objFile.path & ">" & objFile.Name
    Next
    Response.Write "</SELECT><br>"
    Response.Write "<input type=button name=b1 value=复制文件> "
    Response.Write "<input type=Hidden name=h1 value=''> "		' 存放信息的Hidden控件
    Response.Write "<input type=button name=b2 value=删除文件>"
    Response.Write "<input type=Hidden name=h2 value=''> <br>"	' 存放信息的Hidden控件
    Response.Write "目标目录：" & objFolder1.Name & "<br>"
    Response.Write "<SELECT size =4 style='width:150px' name=af1>"	' 下面是目标文件夹列表框
    if trim(objFolder1.parentfolder.Name)<>"" then
      Response.Write  "<OPTION value=" & ff1 & ">[..]"
    end if
    For Each objSubFolder1 in objFolder1.SubFolders
      Response.Write "<OPTION value=" & objSubFolder1.path & ">" & objSubFolder1.Name
    Next
    Response.Write "</SELECT>"
    Set objFolder = Nothing
    Set objFSO = Nothing
%>
    <SCRIPT FOR=af EVENT=onClick LANGUAGE="VBScript">	' 源文件夹列表框的“单击”
      frm1.submit										'   事件过程代码
    </SCRIPT>
    <SCRIPT FOR=af1 EVENT=onClick LANGUAGE="VBScript">	' 目标文件夹列表框的
      frm1.submit										'  “单击”事件过程代码
    </SCRIPT>
    <SCRIPT FOR=b1 EVENT=onClick LANGUAGE="VBScript">	' “复制文件”按钮的
      if trim(frm1.bf.value)<>"" then							'  “单击”事件过程代码
        i=frm1.bf.selectedindex
        frm1.h1.value=frm1.bf.Options(i).Text
        frm1.submit
      else
        msgbox "必须选中文件"
      end if
    </SCRIPT>
    <SCRIPT FOR=b2 EVENT=onClick LANGUAGE="VBScript">	' “删除文件”按钮的
      if trim(frm1.bf.value)<>"" then							'  “单击”事件过程代码
        y=msgbox( "确定要删除文件?",1)
        if y=1 then
          frm1.h2.value="True"
          frm1.submit
        end if
      else
        msgbox "必须选中文件"
      end if
    </SCRIPT>
    </form>
  </BODY>
</HTML>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -