📄 10_5.asp

📁 ASP 网页数据库短训教程源码
💻 ASP
字号:
<HTML>
  <HEAD><TITLE>浏览、修改文件</TITLE></HEAD>
  <BODY>
    <form name=frm1 method=post>
    <TABLE BORDER=0 WIDTH=400>
<%
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    Session("t1")=""										' 初始化文件内容变量
    Session("tn")=""										' 初始化文件名变量
    if IsEmpty(Request("af")) and IsEmpty(Session("af")) then		' 是否首次打开网页
      set Session("af")=objFSO.GetFolder(Server.MapPath(".\"))		' 当前文件夹对象
      Set objFolder = Session("af")
    elseif not IsEmpty(Request("af")) then
      if objFSO.FolderExists(Request("af")) then					' 提交的是文件夹路径
        set Session("af")=objFSO.GetFolder(Request("af"))			' 存放当前文件夹对象
        Set objFolder = Session("af")
      else
        Set objTS = objFSO.OpenTextFile(Request("af"),1)			' 创建TextStream对象
        do while not objTS.atendofstream
          aline= aline & objTS.ReadLine & chr(13)				' 读出文件内容
        Loop
        Session("t1")=aline								' 存放文件内容
        tn=objFSO.getfilename(Request("af"))
        Session("tn")=tn									' 存放文件名
        Session("TS")=Request("af")							' 存放文件路径
      end if
    end if
    if Request("h1")="True" then							' 若是“确定修改”
      Set objTS = objFSO.OpenTextFile(Session("TS"),2)			' 创建TextStream对象
      objTS.write(Request("t1"))							' 写入文件内容
    end if
    Set objFolder = Session("af")							' 当前文件夹对象
    Set Session("af") = objFolder
    Response.Write "<tr><td>当前目录：" & objFolder.Name
    Response.Write "<td>当前文件：" & Session("tn")
    ff=objFolder.parentfolder.path							' 父文件夹路径
    Response.Write "<tr><td><SELECT size =10 style='width:200px' name=af>"
    if trim(objFolder.parentfolder.Name)<>"" then
      Response.Write "<OPTION value="& ff & ">[..]"			' 列表框中父文件夹标志
    end if
    For Each objSubFolder in objFolder.SubFolders				' 列表框中子文件夹列表
      Response.Write "<OPTION value=" & objSubFolder.path & ">[" & objSubFolder.Name & "]"
    Next
    For Each objFile in objFolder.Files						' 列表框中文件列表
      Response.Write "<OPTION value=" & objFile.path & ">" & objFile.Name
    Next
    Response.Write "</SELECT>"
    Response.Write "<td><TEXTAREA name=t1 rows=9 cols=45 wrap=off>"
    Response.Write Session("t1")							' 显示文件内容
    Response.Write "</TEXTAREA>"
    Response.Write "</TABLE>"
    Set objFolder = Nothing
    Set objFSO = Nothing
  '  objTS.close
%>
    <SCRIPT FOR=af EVENT=onClick LANGUAGE=VBScript>
      frm1.submit
    </SCRIPT>
    <INPUT type=button name=b1 value=确认修改>
    <INPUT type=Hidden name=h1 value=''>
    <SCRIPT FOR=b1 EVENT=onClick LANGUAGE="VBScript">
      if trim(frm1.t1.value)<>"" then
        y=msgbox( "确定要保存修改过的文件?",1)
        if y=1 then										' 若确定修改
          frm1.h1.value="True"							' 将信息存放于Hidden中
          frm1.submit									' 提交表单
        end if
      end if
    </SCRIPT>
    </form>
  </BODY>
</HTML>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -