📄 investigate.asp.txt
字号:
<%@ language=VBScript%>
<HTML>
<HEAD><TITLE>简单民意调查</TITLE></HEAD>
<BODY bgcolor=LightYellow>
<CENTER>
<%
' 声明对象、变量
Dim strData, strTempFile
Dim PosA, PosB, PosC, PosD
Dim NumAL, NumBL, NumCL, NumDL
Dim NumA, NumB, NumC, NumD
Dim objFSO, objInFile, objOutFile
' 获取记录投票结果文件Result.txt所在的物理路径
strTempFile = Server.MapPath("Result.txt")
' 建立文件系统对象
Set objFSO = CreateObject("Scripting.FileSystemObject")
' 以文本形式打开投票结果文件
Set objInFile = objFSO.OpenTextFile(strTempFile)
' 将Result.txt的第一行（即遇到第一个回车换行符前的文本数据）读入
strData = objInFile.ReadLine
' 关闭输入文件
objInFile.Close
' 从第一行文本中分解出NumA, NumB, NumC, NumD对应的字符串并转化为数值型量
PosA = Instr(strData, "A") + 1 ' NumA的起始位置
PosB = Instr(strData, "B") + 1 ' NumB的起始位置
PosC = Instr(strData, "C") + 1 ' NumC的起始位置
PosD = Instr(strData, "D") + 1 ' NumD的起始位置
NumAL = PosB - PosA -1 ' NumA的长度
NumBL = PosC - PosB -1 ' NumB的长度
NumCL = PosD - PosC -1 ' NumC的长度
NumDL = Len(strData) - PosD + 1 ' NumD的长度
NumA = Clng(Mid(strData, PosA, NumAL))
NumB = Clng(Mid(strData, PosB, NumBL))
NumC = Clng(Mid(strData, PosC, NumCL))
NumD = Clng(Mid(strData, PosD, NumDL))
' 根据Investigate.htm中获取的选择增加相应的变量
Select Case Request.Form("Editor")
Case "A":
NumA = NumA + 1
Case "B":
NumB = NumB + 1
Case "C":
NumC = NumC + 1
Case "D":
NumD = NumD + 1
End Select
' 重新生成存储字符串
strData = "A" & Cstr(NumA) & "B" & Cstr(NumB) & "C" & Cstr(NumC) & "D" & Cstr(NumD)
' 新建存储投票结果文件，写入投票结果字符串，覆盖原有文件Result.txt
set objOutFile = objFSO.CreateTextFile(strTempFile)
objOutFile.WriteLine(strData)
' 关闭文件Result.txt
objOutFile.Close
' 释放内存变量
set objOutFile = Nothing
set objInFile = Nothing
set objFSO = Nothing
%>
<BR>谢谢你的参与,调查结果为:
<TABLE>
<TR><TD>JavaScript:</TD><TD><% = NumA%></TD></TR>
<TR><TD>VBScript:</TD><TD><% = NumB%></TD></TR>
<TR><TD>PerlScript:</TD><TD><% = NumC%></TD></TR>
<TR><TD>其它:</TD><TD><% = NumD%></TD></TR>
</TABLE>
</CENTER>
</BODY>
</HTML>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -