module1.bas

这个是锁屏器(鼠标锁)可以设置启动计算机时启动..达到保护计算机安全

Attribute VB_Name = "Mission"
Option Explicit

Public Const WM_LBUTTONDOWN = &H201     '鼠标左键按下消息的代码

Public Const WM_RBUTTONUP = &H205       '鼠标右键松开消息的代码

Private Const NIM_ADD = &H0            '表示要往任务栏中加入图标

Private Const NIM_DELETE = &H2         '删除图标

Private Const NIF_ICON = &H2           '允许图标显示

Private Const NIF_MESSAGE = &H1        '允许图标消息转发

Private Const NIF_TIP = &H4            '允许图标显示图标提示字符串

Private Type NOTIFYICONDATA            '通知任务栏图标状态
        
  cbSize As Long                       '本结构的长度
        
  hWnd As Long                         '往任务栏安装图标的应用程序的窗体句柄,系统根据此发送消息给相应的应用程序
        
  uid As Long                          '图标的唯一标识,由安装图标的应用程序确定
        
  uFlags As Long                       '图标将接受或表示什么样的行为
         
  uCallbackMessage As Long             '发给应用程序的回调消息,应当避免同系统预定义的消息相同,应大于WM_USER
        
  hIcon As Long                        '图标句柄,即欲在任务栏中显示的图标
        
  szTip As String * 64                '如果图标被允许显示TIP的话,那么当鼠标停留在任务栏图标上一段时间,将显示该串
        
End Type

Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long '图标操作

Public Function Icon_Add(iHwnd As Long, stips As String, hIcon As Long, IconId As Long) As Long

  Dim IconVa As NOTIFYICONDATA
  
  With IconVa
  
    .hWnd = iHwnd
    
    .szTip = stips + Chr$(0)
    
    .hIcon = hIcon
    
    .uid = IconId
    
    .uCallbackMessage = WM_LBUTTONDOWN
    
    .cbSize = Len(IconVa)
    
    .uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
 
  End With
  
  Icon_Add = Shell_NotifyIcon(NIM_ADD, IconVa)

End Function

Public Function Icon_Del(iHwnd As Long, lIndex As Long) As Long

 Dim IconVa As NOTIFYICONDATA
 
 Dim l As Long
 
 With IconVa
 
  .hWnd = iHwnd
  
  .uid = lIndex
  
  .cbSize = Len(IconVa)
  
 End With
 
 Icon_Del = Shell_NotifyIcon(NIM_DELETE, IconVa)
 
End Function